Ky tutorial shpjegon bazat e referencave të strukturuara në Excel dhe ndan disa truke për përdorimin e tyre në formulat e jetës reale.

Një nga veçoritë më të dobishme të tabelave të Excel janë referencat e strukturuara. Kur sapo keni hasur në një sintaksë të veçantë për referencën e tabelave, mund të duket e mërzitshme dhe konfuze, por pasi të eksperimentoni pak, me siguri do të shihni se sa e dobishme dhe e lezetshme është kjo veçori.

Excel referencë e strukturuar

Një referencë e strukturuar , ose referencë e tabelës , është një mënyrë e veçantë për referencën e tabelave dhe pjesëve të tyre që përdor një kombinim të emrave të tabelave dhe kolonave në vend të adresave të qelizave .

Kjo sintaksë e veçantë kërkohet sepse tabelat e Excel (në krahasim me diapazonin) janë shumë të fuqishme dhe elastike dhe referencat normale të qelizave nuk mund të rregullohen në mënyrë dinamike ndërsa të dhënat shtohen ose hiqen nga një tabelë.

Për për shembull, për të përmbledhur vlerat në qelizat B2:B5, ju përdorni funksionin SUM me një referencë të zakonshme të diapazonit:

=SUM(B2:B5)

Për të mbledhur numrat në kolonën "Shitje" të Tabelës 1, ju përdorni një referencë të strukturuar:

=SUM(Table1[Sales])

Karakteristikat kryesore të referencave të strukturuara

Krahasuar me referencat standarde të qelizave, referencat e tabelave kanë një numër e veçorive të avancuara.

Krijohet lehtësisht

Për të shtuar referenca të strukturuara në formulën tuaj, thjesht zgjidhni qelizat e tabelës që dëshironi t'i referoheni. Njohuria e një sintakse të veçantë nuk ështëmënyra:

• Referencat e shumë kolonave janë absolute dhe nuk ndryshojnë kur formulat kopjohen.
• Një kolonë Referencat janë relative dhe ndryshojnë kur zvarriten nëpër kolona. Kur kopjohen/ngjiten nëpërmjet një komande ose shkurtoresh përkatëse (Ctrl+C dhe Ctrl+V), ato nuk ndryshojnë.

Në situatat kur keni nevojë për një kombinim të referencave të tabelës relative dhe absolute, ekziston nuk ka asnjë mënyrë për të kopjuar formulën dhe për të mbajtur të sakta referencat e tabelës. Zvarritja e formulës do t'i ndryshojë referencat në kolona të vetme dhe shkurtoret e kopjimit/ngjitjes do t'i bëjnë të gjitha referencat statike. Por ka disa truke të thjeshta për t'u larguar!

Referencë e strukturuar absolute për një kolonë të vetme

Për ta bërë një referencë të vetme kolone absolute, përsërisni emrin e kolonës për ta kthyer zyrtarisht në një referencë diapazoni .

Referenca relative e kolonës (e parazgjedhur)

table[column]

Referenca absolute e kolonës

table[[column]:[column]]

Për të bërë një referencë absolute për rreshti aktual , vendosni identifikuesin e kolonës me simbolin @:

table[@[column]:[column]]

Për të parë se si funksionojnë në praktikë referencat e tabelës relative dhe absolute, ju lutemi merrni parasysh shembullin e mëposhtëm.

Duke supozuar se doni të shtoni numrat e shitjeve për një produkt specifik për 3 muaj. Për këtë, ne futim emrin e produktit të synuar në disa qeliza (F2 në rastin tonë) dhe përdorim funksionin SUMIF për të marrë totalin e shitjeve Jan :

=SUMIF(Sales[Item], $F$2, Sales[Jan])

Tëproblemi është se kur e tërheqim formulën djathtas për të llogaritur totalet për dy muajt e tjerë, referenca [Artikulli] ndryshon dhe formula prishet:

Për të rregulluar kjo, bëjeni referencën [Item] absolute, por mbajeni [Jan] relative:

=SUMIF(Sales[[Item]:[Item]], $F$2, Sales[Jan])

Tani, mund ta tërhiqni formulën e modifikuar në kolona të tjera dhe funksionon në mënyrë të përsosur:

Referenca e strukturuar relative për disa kolona

Në tabelat e Excel, referencat e strukturuara për disa kolona janë absolute për nga natyra e tyre dhe mbeten të pandryshuara kur kopjohen në qeliza të tjera.

0>Për mua, kjo sjellje është shumë e arsyeshme. Por nëse ju duhet të bëni një referencë të strukturuar të diapazonit, vendosni prefiks çdo specifikues të kolonës me emrin e tabelës dhe hiqni kllapat e jashtme katrore siç tregohet më poshtë.

Referenca e diapazonit absolut (parazgjedhja)

table[[column1]:[column2]]

Referenca e intervalit relativ

table[column1]:table[column2]

Për t'iu referuar rreshtit aktual brenda tabelës , përdorni simbolin @:

[@column1]:[@column2]

Për shembull, formula e mëposhtme me një referencë të strukturuar absolute mbledh numrat në rreshtin aktual të kolonave Jan dhe Shkurt . Kur kopjohet në një kolonë tjetër, ajo do të vazhdojë të përmbledhë Jan dhe Shkurt .

=SUM(Sales[@[Jan]:[Feb]])

Në rast se dëshironi që referenca të ndryshojë bazuar në një pozicioni relativ i kolonës ku formula është kopjuar, bëjeni atë relative :

=SUM(Sales[@Jan]:Sales[@Feb])

Ju lutemi vini re transformimin e formulës në kolonën F (emri i tabelës është lënë jashtë sepse formula është brenda tabelës):

Kështu i bëni referencat e tabelës në Excel. Për të parë më nga afër shembujt e diskutuar në këtë tutorial, mos ngurroni të shkarkoni modelin e librit tonë të punës në Referencën e Strukturuar të Excel. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë javën e ardhshme.

Elastike dhe e përditësuar automatikisht

Kur riemërtoni një kolonë, referencat përditësohen automatikisht me emrin e ri dhe një formulë nuk prishet. Për më tepër, ndërsa shtoni rreshta të rinj në tabelë, ato përfshihen menjëherë në referencat ekzistuese dhe formulat llogarisin grupin e plotë të të dhënave.

Pra, çfarëdo manipulimi që bëni me tabelat tuaja në Excel, ju nuk e bëni nuk duhet të shqetësoheni për përditësimin e referencave të strukturuara.

Mund të përdoret brenda dhe jashtë një tabele

Referencat e strukturuara mund të përdoren në formula si brenda ashtu edhe jashtë një tabele Excel, gjë që bën gjetjen e tabelave në librat e mëdhenj të punës më të lehtë.

Plotësimi automatik i formulave (kolonat e llogaritura)

Për të kryer të njëjtën llogaritje në çdo rresht tabele, mjafton të futësh një formulë në vetëm një qelizë. Të gjitha qelizat e tjera në atë kolonë plotësohen automatikisht.

Si të krijoni një referencë të strukturuar në Excel

Bërja e një referimi të strukturuar në Excel është shumë e lehtë dhe intuitive.

Nëse ju janë duke punuar me një gamë, së pari konvertojeni atë në një tabelë Excel. Për këtë, zgjidhni të gjitha të dhënat dhe shtypni Ctrl + T. Për më shumë informacion, ju lutemi shihni Si të krijoni një tabelë në Excel.

Për të krijuar një referencë të strukturuar, kjo është ajo që duhet të bëni:

1. Filloni të shkruani një formulë si zakonisht, duke filluar me shenjën e barazisë (=).
2. Kur bëhet fjalë për referencën e parë, zgjidhni qelizën ose gamën përkatëse tëqelizat në tabelën tuaj. Excel do të marrë emrin(et) e kolonës dhe do të krijojë një referencë të përshtatshme të strukturuar për ju automatikisht.
3. Shkruani kllapat mbyllëse dhe shtypni Enter. Nëse formula krijohet brenda tabelës, Excel automatikisht mbush të gjithë kolonën me të njëjtën formulë.

Si shembull, le të mbledhim numrat e shitjeve për 3 muaj në çdo rresht të tabelës sonë të mostrës, me emrin Shitjet . Për këtë, shkruajmë =SUM( në E2, zgjedhim B2:D2, shtypim kllapat mbyllëse dhe shtypim Enter:

Si rezultat, e gjithë kolona E është automatike -e mbushur me këtë formulë:

=SUM(Sales[@[Jan]:[Mar]])

Megjithëse formula është e njëjtë, të dhënat llogariten në çdo rresht veç e veç. Për të kuptuar mekanikën e brendshme, ju lutemi hidhini një sy sintaksës së referencës së tabelës .

Nëse po futni një formulë jashtë tabelës dhe ajo formulë kërkon vetëm një varg qelizash, një mënyrë më e shpejtë për të bërë një referencë të strukturuar është kjo:

1. Pas kllapave hapëse, filloni të shkruani emrin e tabelës. Ndërsa shkruani shkronjën e parë, Excel do të shfaqë të gjithë emrat që përputhen. Nëse është e nevojshme, shkruani disa shkronja të tjera për të ngushtuar listën.
2. Përdorni tastet e shigjetave për të zgjedhur emrin e tabelës në listë.
3. Klikoni dy herë mbi emrin e zgjedhur ose shtypni tastin Tab për ta shtuar në formulën tuaj.
4. Shkruani kllapat mbyllëse dhe shtypni Enter.

Për shembull, për të gjetur numrin më të madh në kampionin tonëtabela, fillojmë të shtypim formulën MAX, pas kllapave hapëse shkruani "s", zgjidhni tabelën Shitjet në listë dhe shtypni Tab ose klikoni dy herë mbi emrin.

Si si rezultat, ne kemi këtë formulë:

=MAX(Sales)

Sintaksa e strukturuar e referencës

Siç është përmendur tashmë, nuk keni nevojë të dini sintaksën të referencave të strukturuara për t'i përfshirë ato në formulat tuaja, megjithatë kjo do t'ju ndihmojë të kuptoni se çfarë po bën në të vërtetë secila formulë.

Zakonisht, një referencë e strukturuar përfaqësohet nga një varg që fillon me një emër tabele dhe përfundon me një kolonë specifikues.

Si shembull, le të zbërthejmë formulën e mëposhtme që mbledh totalet e kolonave Jug dhe Veriu në tabelën me emrin Rajonet :

Referenca përfshin tre komponentë:

1. Emri i tabelës
2. Specifikuesi i artikullit
3. kolona specifiers

Për të parë se cilat qeliza janë llogaritur në të vërtetë, zgjidhni qelizën e formulës dhe klikoni kudo në shiritin e formulave. Excel do të nënvizojë qelizat e referuara të tabelës:

Emri i tabelës

Emri i tabelës i referohet vetëm të dhënave të tabelës , pa rreshtin e kokës ose gjithsej rreshtave. Mund të jetë një emër i paracaktuar i tabelës si Tabela1 ose një emër i personalizuar si Rajonet . Për t'i dhënë një emër të personalizuar tabelës suaj, kryeni këto hapa.

Nëse formula juaj ndodhet brenda tabelës të cilës i referohet, emri i tabelës zakonisht hiqet sepsenënkuptohet.

Specifikuesi i kolonës

Specifikuesi i kolonës referon të dhënat në kolonën përkatëse, pa rreshtin e kokës dhe rreshtin total. Një specifikues kolone përfaqësohet nga emri i kolonës i mbyllur në kllapa, p.sh. [Jug].

Për t'iu referuar më shumë se një kolonave të njëpasnjëshme, përdorni operatorin e diapazonit si [[Jug]:[Lindje]].

Specifikuesi i artikullit

Për t'iu referuar për pjesë të veçanta të një tabele, mund të përdorni cilindo nga specifikuesit e mëposhtëm.

Ju lutemi vini re se shenja e paundit (#) përdoret me të gjithë specifikuesit e artikullit, përveç rreshtit aktual. Për t'iu referuar qelizave në të njëjtin rresht ku futni formulën, Excel përdor karakterin @ të ndjekur nga emri i kolonës.

Për shembull, për të shtuar numra në Jug dhe <1 Kolonat>Perëndim të rreshtit aktual, do të përdorni këtë formulë:

=SUM(Regions[@South], Regions[@West])

Nëse emrat e kolonave përmbajnë hapësira, shenja pikësimi ose karaktere të veçanta, një grup shtesë kllapash përreth do të shfaqet emri i kolonës:

=SUM(Regions[@[South sales]], Regions[@[West sales]])

Operatorët e strukturuar të referencës

Operatorët e mëposhtëm ju lejojnë të kombinoni specifikues të ndryshëm dhe të shtoni edhe më shumë fleksibilitet në referencat tuaja të strukturuara.

Operatori i diapazonit ( dy pika)

Ashtu si me referencat e diapazonit normal, ju përdorni një dy pika (:) për t'iu referuar dy ose më shumë kolonave ngjitur në një tabelë.

Për shembull, formula e mëposhtme mbledh numrat në të gjitha kolonat midis Jug dhe Lindje .

=SUM(Regions[[South]:[East]])

Operatori i bashkimit (presje)

Për t'iu referuar jo-ngjajshëm kolona, ​​ndani specifikuesit e kolonave me presje.

Për shembull, ja se si mund të përmblidhni rreshtat e të dhënave në kolonat Jug dhe Perëndim .

=SUM(Regions[South], Regions[West])

Operatori i kryqëzimit (hapësira)

Përdoret për t'iu referuar një qelize në kryqëzimin e një rreshti dhe kolone specifike.

Për shembull, për të kthyer një vlerë në kryqëzimin e rreshtit Total dhe kolonës Perëndim , përdorni këtë referencë:

=Regions[#Totals] Regions[[#All],[West]]

Ju lutemi vini re se specifikuesi [#Të gjithë] është kërkohet në këtë rast sepse specifikuesi i kolonës nuk përfshin rreshtin total. Pa të, formula do të kthente #NULL!.

Rregullat e sintaksës së referencës së tabelës

Për të modifikuar ose bërë referenca të strukturuara manualisht, ndiqni këto udhëzime:

1. Mblidhni specifikuesit në kllapa

Të gjithë specifikuesit e kolonës dhe artikujve të veçantë duhet të futen në [kllapa katrore].

Një specifikues që përmban specifikues të tjerë duhet të jetëmbështjellë me kllapa të jashtme. Për shembull, Rajonet[[Jug]:[Lindje]].

2. Ndani specifikuesit e brendshëm me presje

Nëse një specifikues përmban dy ose më shumë specifikues të brendshëm, ata specifikues të brendshëm duhet të ndahen me presje.

Për shembull, për të kthyer kokën e Jug kolona , ju shkruani një presje midis [#Headers] dhe [South] dhe mbyllni të gjithë këtë ndërtim në një grup shtesë kllapash:

=Regions[[#Headers],[South]]

3. Mos përdorni thonjëza rreth titujve të kolonave

Në referencat e tabelave, titujt e kolonave nuk kërkojnë thonjëza qofshin ato tekst, numra ose data.

4. Përdorni një thonjëza të vetme për disa karaktere të veçanta në titujt e kolonave

Në referencat e strukturuara, disa karaktere si kllapat majtas dhe djathtas, shenja pound (#) dhe thonjëza e vetme (') kanë kuptim të veçantë. Nëse ndonjë nga karakteret e mësipërme përfshihet në një kokë kolone, duhet të përdoret një thonjëza e vetme përpara atij karakteri në një specifikues kolone.

Për shembull, për kokën e kolonës "Artikulli #", specifikuesi është [Artikulli '#].

5. Përdorni hapësirat për t'i bërë referencat e strukturuara më të lexueshme

Për të përmirësuar lexueshmërinë e referencave të tabelës suaj, mund të futni hapësira ndërmjet specifikuesve. Normalisht, konsiderohet një praktikë e mirë përdorimi i hapësirave pas presjeve. Për shembull:

=AVERAGE(Regions[South], Regions[West], Regions[North])

Referencat e tabelës Excel - shembuj formulash

Për të fituar më shumë kuptim rrethreferenca të strukturuara në Excel, le të kalojmë në disa shembuj të formulës. Ne do të përpiqemi t'i mbajmë ato të thjeshta, kuptimplota dhe të dobishme.

Gjeni numrin e rreshtave dhe kolonave në një tabelë Excel

Për të marrë numrin total të kolonave dhe rreshtave, përdorni KOLUMAT dhe RREZAT funksione, të cilat kërkojnë vetëm emrin e tabelës:

Për shembull, për të gjetur numrin e kolonave dhe rreshtave të të dhënave në tabelën me emrin Shitjet , përdorni këto formula:

=COLUMNS(Sales)

=ROWS(Sales)

Për të përfshirë titullin dhe rreshta gjithsej në numërim, përdorni specifikuesin [#ALL]:

=ROWS(Sales[#All])

Pamja e mëposhtme e ekranit tregon të gjitha formulat në veprim:

Numëroni boshllëqet dhe jo boshllëqet në një kolonë

Kur numëroni diçka në një kolonë të caktuar, sigurohuni që ta nxirrni rezultatin jashtë tabelës, përndryshe mund të përfundoni me referenca rrethore dhe rezultate të gabuara.

Për të numëruar boshllëqet në një kolonë, përdorni funksionin COUNTBLANK. Për të numëruar qelizat jo bosh në një kolonë, përdorni funksionin COUNTA.

Për shembull, për të zbuluar se sa qeliza në kolonën Jan janë bosh dhe sa përmbajnë të dhëna, përdorni këto formula:

Banks:

=COUNTBLANK(Sales[Jan])

Jo bosh:

=COUNTA(Sales[Jan])

Për të numëruar qelizat jo bosh në rreshta të dukshme në një tabelë e filtruar, përdorni funksionin SUBTOTAL me funksion_num të caktuar në 103:

=SUBTOTAL(103,Sales[Jan])

Suma në një tabelë Excel

Mënyra më e shpejtë për të mbledhurnumrat në një tabelë Excel është për të aktivizuar opsionin Total Row. Për ta bërë këtë, kliko me të djathtën në çdo qelizë brenda tabelës, drejtohu te Tabela dhe kliko Rreshti Total . Rreshti total do të shfaqet menjëherë në fund të tabelës suaj.

Ndonjëherë Excel mund të supozojë se dëshironi të totalizoni vetëm kolonën e fundit dhe i lë bosh qelizat e tjera në rreshtin Total. Për ta rregulluar këtë, zgjidhni një qelizë bosh në rreshtin Total, klikoni shigjetën që shfaqet pranë qelizës dhe më pas zgjidhni funksionin SUM në listë:

Kjo do të fut një formulë SUBTOTAL që mbledh vlerat vetëm në rreshta të dukshme , duke injoruar rreshtat e filtruar:

=SUBTOTAL(109,[Jan])

Ju lutemi vini re se kjo formulë funksionon vetëm në Totali rreshti . Nëse përpiqeni ta futni manualisht në një rresht të dhënash, kjo do të krijonte një referencë rrethore dhe do të kthente 0 si rezultat. Një formulë SUM me një referencë të strukturuar nuk do të funksionojë as për të njëjtën arsye:

Pra, nëse doni totalet brenda tabelës , ju duhet ose të aktivizoni rreshtin Total ose të përdorni një referencë normale të diapazonit të tillë si:

=SUM(B2:B5)

Jashtë tabelës , formula SUM me një referencë të strukturuar funksionon mirë:

=SUM(Sales[Jan])

Ju lutemi vini re se ndryshe nga SUBTOTAL, funksioni SUM shton vlera në të gjitha rreshtat, të dukshme dhe të fshehura.

Referencat e strukturuara relative dhe absolute në Excel

Si parazgjedhje, referencat e strukturuara të Excel sillen në vijim