V tomto učebnom texte sa vysvetľujú základy štruktúrovaných odkazov programu Excel a uvádzajú sa niektoré triky na ich používanie v skutočných vzorcoch.

Jednou z najužitočnejších funkcií tabuliek Excelu sú štruktúrované odkazy. Keď ste práve narazili na špeciálnu syntax pre odkazovanie na tabuľky, môže to vyzerať nudne a mätúco, ale po chvíli experimentovania určite zistíte, aká je táto funkcia užitočná a skvelá.

Štruktúrovaný odkaz Excel

A štruktúrovaný odkaz , alebo odkaz na tabuľku , je špeciálny spôsob odkazovania na tabuľky a ich časti, ktorý namiesto adries buniek používa kombináciu názvov tabuliek a stĺpcov.

Táto špeciálna syntax je potrebná, pretože tabuľky programu Excel (oproti rozsahom) sú veľmi výkonné a odolné a bežné odkazy na bunky sa nemôžu dynamicky prispôsobovať pri pridávaní alebo odstraňovaní údajov z tabuľky.

Ak chcete napríklad sčítať hodnoty v bunkách B2:B5, použite funkciu SUM s obvyklým odkazom na rozsah:

=SUM(B2:B5)

Na sčítanie čísel v stĺpci "Predaj" tabuľky 1 použijete štruktúrovaný odkaz:

=SUM(Tabuľka1[Predaj])

Kľúčové vlastnosti štruktúrovaných odkazov

V porovnaní so štandardnými odkazmi na bunky majú odkazy na tabuľky viacero pokročilých funkcií.

Ľahko vytvorené

Ak chcete do vzorca pridať štruktúrované odkazy, stačí vybrať bunky tabuľky, na ktoré chcete odkazovať. Znalosť špeciálnej syntaxe nie je potrebná.

Odolné a automaticky aktualizované

Keď zmeníte názov stĺpca, odkazy sa automaticky aktualizujú novým názvom a vzorec sa nezruší. Okrem toho, keď do tabuľky pridáte nové riadky, okamžite sa zahrnú do existujúcich odkazov a vzorce vypočítajú celý súbor údajov.

Pri akejkoľvek manipulácii s tabuľkami programu Excel sa teda nemusíte starať o aktualizáciu štruktúrovaných odkazov.

Môže sa používať vo vnútri aj mimo stola

Štruktúrované odkazy možno používať vo vzorcoch v tabuľke programu Excel aj mimo nej, čo uľahčuje vyhľadávanie tabuliek vo veľkých zošitoch.

Automatické vypĺňanie vzorcov (vypočítané stĺpce)

Ak chcete vykonať rovnaký výpočet v každom riadku tabuľky, stačí zadať vzorec len do jednej bunky. Všetky ostatné bunky v danom stĺpci sa vyplnia automaticky.

Ako vytvoriť štruktúrovaný odkaz v programe Excel

Vytvorenie štruktúrovaného odkazu v programe Excel je veľmi jednoduché a intuitívne.

Ak pracujete s rozsahom, preveďte ho najprv na tabuľku programu Excel. Na tento účel vyberte všetky údaje a stlačte klávesovú skratku Ctrl + T . Ďalšie informácie nájdete v časti Ako vytvoriť tabuľku v programe Excel.

Ak chcete vytvoriť štruktúrovaný odkaz, musíte urobiť toto:

1. Začnite písať vzorec ako zvyčajne, začínajúc znakom rovnosti (=).
2. Keď príde na rad prvý odkaz, vyberte príslušnú bunku alebo rozsah buniek v tabuľke. Excel automaticky vyberie názov(-y) stĺpcov a vytvorí pre vás príslušný štruktúrovaný odkaz.
3. Zadajte uzatváraciu zátvorku a stlačte kláves Enter. Ak je vzorec vytvorený vnútri tabuľky, Excel automaticky vyplní celý stĺpec rovnakým vzorcom.

Ako príklad uvedieme sčítanie čísel predaja za 3 mesiace v každom riadku našej vzorovej tabuľky s názvom Predaj Na tento účel zadáme =SUM( do E2, vyberieme B2:D2, zadáme uzatváraciu zátvorku a stlačíme Enter:

Výsledkom je, že celý stĺpec E je automaticky vyplnený týmto vzorcom:

=SUM(Predaj[@[január]:[marec]])

Hoci vzorec je rovnaký, údaje sa počítajú v každom riadku samostatne. Ak chcete pochopiť vnútornú mechaniku, pozrite si syntax referenčnej tabuľky.

Ak zadávate vzorec mimo stola a tento vzorec vyžaduje len rozsah buniek, rýchlejší spôsob vytvorenia štruktúrovaného odkazu je tento:

1. Po úvodnej zátvorke začnite písať názov tabuľky. Pri písaní prvého písmena program Excel zobrazí všetky zodpovedajúce názvy. Ak je to potrebné, zadajte niekoľko ďalších písmen, aby ste zúžili zoznam.
2. Pomocou tlačidiel so šípkami vyberte názov tabuľky v zozname.
3. Dvakrát kliknite na vybraný názov alebo stlačte kláves Tab, aby ste ho pridali do vzorca.
4. Zadajte uzatváraciu zátvorku a stlačte kláves Enter.

Ak chceme napríklad nájsť najväčšie číslo v našej vzorovej tabuľke, začneme písať vzorec MAX, za úvodnú zátvorku napíšeme "s", vyberieme Predaj tabuľky v zozname a stlačte tlačidlo Tab alebo dvakrát kliknite na názov.

Výsledkom je tento vzorec:

=MAX(Predaj)

Štruktúrovaná referenčná syntax

Ako už bolo spomenuté, na to, aby ste mohli do vzorcov zahrnúť štruktúrované odkazy, nemusíte poznať ich syntax, pomôže vám to však pochopiť, čo jednotlivé vzorce vlastne robia.

Štruktúrovaný odkaz je zvyčajne reprezentovaný reťazcom, ktorý začína názvom tabuľky a končí špecifikátorom stĺpca.

Ako príklad uvedieme nasledujúci vzorec, ktorý sčíta súčty Južná a Sever stĺpce v tabuľke s názvom Regióny :

Referencia obsahuje tri zložky:

1. Názov tabuľky
2. Špecifikátor položky
3. Špecifikátory stĺpcov

Ak chcete zistiť, ktoré bunky sú skutočne vypočítané, vyberte bunku vzorca a kliknite kdekoľvek na paneli vzorcov. Excel zvýrazní odkazované bunky tabuľky:

Názov tabuľky

Názov tabuľky odkazuje len na tabuľkové údaje , bez riadku záhlavia alebo celkového počtu riadkov. Môže to byť predvolený názov tabuľky, napr. Tabuľka1 alebo vlastný názov, napríklad Regióny . Ak chcete tabuľke priradiť vlastný názov, vykonajte tieto kroky.

Ak sa vzorec nachádza v tabuľke, na ktorú odkazuje, názov tabuľky sa zvyčajne vynecháva, pretože sa implicitne uvádza.

Špecifikátor stĺpca

Špecifikátor stĺpca odkazuje na údaje v príslušnom stĺpci bez riadku záhlavia a celkového riadku. Špecifikátor stĺpca je reprezentovaný názvom stĺpca uzavretým v zátvorkách, napr. [South].

Ak chcete odkazovať na viac ako jeden susediaci stĺpec, použite operátor rozsahu, napríklad [[Juh]:[Východ]].

Špecifikátor položky

Ak chcete odkazovať na konkrétne časti tabuľky, môžete použiť niektorý z nasledujúcich špecifikátorov.

Všimnite si, že znak libry (#) sa používa pri všetkých špecifikátoroch položiek okrem aktuálneho riadku. Na odkazovanie na bunky v tom istom riadku, v ktorom zadávate vzorec, používa Excel znak @, za ktorým nasleduje názov stĺpca.

Ak chcete napríklad sčítať čísla v Južná a Západ stĺpcov aktuálneho riadku, použijete tento vzorec:

=SUM(Regióny[@Juh], Regióny[@Západ])

Ak názvy stĺpcov obsahujú medzery, interpunkčné znamienka alebo špeciálne znaky, okolo názvu stĺpca sa zobrazí ďalšia sada zátvoriek:

=SUM(Regióny[@[Južný predaj]], Regióny[@[Západný predaj]])

Štruktúrované referenčné operátory

Nasledujúce operátory umožňujú kombinovať rôzne špecifikátory a dodať štruktúrovaným odkazom ešte väčšiu flexibilitu.

Operátor rozsahu (dvojbodka)

Rovnako ako pri bežných odkazoch na rozsah, aj tu sa na odkaz na dva alebo viac susedných stĺpcov v tabuľke používa dvojbodka (:).

Napríklad nasledujúci vzorec sčíta čísla vo všetkých stĺpcoch medzi Južná a Východ .

=SUM(Regióny[[Juh]:[Východ]])

Operátor únie (čiarka)

Ak chcete odkazovať na nesúvisiace stĺpce, oddeľte ich špecifikátory čiarkami.

Napríklad takto môžete sčítať riadky údajov v Južná a Západ stĺpce.

=SUM(Regióny[Juh], Regióny[Západ])

Operátor priesečníka (medzera)

Používa sa na označenie bunky v priesečníku určitého riadku a stĺpca.

Napríklad na vrátenie hodnoty v priesečníku Celkom riadok a Západ použite tento odkaz:

=Regióny[#Súčty] Regióny[[#Všetky],[Západ]]

Všimnite si, že špecifikátor [#All] je v tomto prípade potrebný, pretože špecifikátor stĺpca neobsahuje celkový riadok. Bez neho by vzorec vrátil #NULL!.

Pravidlá syntaxe referenčnej tabuľky

Ak chcete upraviť alebo vytvoriť štruktúrované odkazy ručne, postupujte podľa týchto pokynov:

1. Špecifikátory uzavrite do zátvoriek

Všetky špecifikátory stĺpcov a špeciálnych položiek musia byť uzavreté v [hranatých zátvorkách].

Špecifikátor, ktorý obsahuje iné špecifikátory, by mal byť uzavretý vo vonkajších zátvorkách. Napríklad Regióny[[Juh]:[Východ]].

2. Vnútorné špecifikátory oddeľte čiarkami

Ak špecifikátor obsahuje dva alebo viac vnútorných špecifikátorov, tieto vnútorné špecifikátory musia byť oddelené čiarkami.

Napríklad na vrátenie hlavičky Južná stĺpca, napíšete čiarku medzi [#Headers] a [South] a celú túto konštrukciu uzavriete do ďalšej sady zátvoriek:

=Regióny[[#Headers],[Juh]]

3. Nepoužívajte úvodzovky okolo nadpisov stĺpcov

V odkazoch na tabuľky sa v záhlaví stĺpcov nevyžadujú úvodzovky, či už ide o text, čísla alebo dátumy.

4. Pre niektoré špeciálne znaky v záhlaví stĺpcov použite jednoduché úvodzovky

V štruktúrovaných odkazoch majú niektoré znaky, ako sú ľavé a pravé zátvorky, znak libry (#) a jednoduché úvodzovky ('), špeciálny význam. Ak je niektorý z uvedených znakov zahrnutý v záhlaví stĺpca, pred týmto znakom v špecifikátore stĺpca je potrebné použiť jednoduché úvodzovky.

Napríklad pre záhlavie stĺpca "Item #" je špecifikátor [Item '#].

5. Používajte medzery, aby boli štruktúrované odkazy čitateľnejšie

Ak chcete zlepšiť čitateľnosť odkazov na tabuľky, môžete medzi špecifikátory vložiť medzery. Za normálnych okolností sa považuje za dobrú prax používať medzery za čiarkami. Napríklad:

=AVERAGE(Regióny[Juh], Regióny[Západ], Regióny[Sever])

Odkazy na tabuľky programu Excel - príklady vzorcov

Aby ste lepšie pochopili štruktúrované odkazy v programe Excel, preberieme si niekoľko ďalších príkladov vzorcov. Pokúsime sa, aby boli jednoduché, zmysluplné a užitočné.

Zistenie počtu riadkov a stĺpcov v tabuľke programu Excel

Ak chcete získať celkový počet stĺpcov a riadkov, použite funkcie COLUMNS a ROWS, ktoré vyžadujú len názov tabuľky:

Napríklad na zistenie počtu stĺpcov a riadky údajov v tabuľke s názvom Predaj , použite tieto vzorce:

=COLUMNS(Sales)

=ROWS(Predaj)

Zahrnúť záhlavie a celkový počet riadkov v počte, použite špecifikátor [#ALL]:

=ROWS(Sales[#All])

Na nasledujúcom obrázku sú zobrazené všetky vzorce v akcii:

Počítanie prázdnych a neprázdnych miest v stĺpci

Keď niečo počítate v konkrétnom stĺpci, nezabudnite výsledok vypisovať mimo tabuľky, inak by ste mohli skončiť s kruhovými odkazmi a nesprávnymi výsledkami.

Ak chcete spočítať prázdne bunky v stĺpci, použite funkciu COUNTBLANK. Ak chcete spočítať neprázdne bunky v stĺpci, použite funkciu COUNTA.

Ak chcete napríklad zistiť, koľko buniek v Jan stĺpcov sú prázdne a koľko z nich obsahuje údaje, použite tieto vzorce:

Slepé náboje:

=COUNTBLANK(Sales[Jan])

Nevyplnené:

=COUNTA(Sales[Jan])

Počítanie neprázdnych buniek v viditeľné riadky vo filtrovanej tabuľke použite funkciu SUBTOTAL s číslom funkcie_num nastaveným na 103:

=SUBTOTAL(103,Sales[Jan])

Súčet v tabuľke programu Excel

Najrýchlejším spôsobom sčítania čísel v tabuľke programu Excel je zapnutie možnosti Celkový riadok. Ak to chcete urobiť, kliknite pravým tlačidlom myši na ľubovoľnú bunku v tabuľke, prejdite na položku Tabuľka a kliknite na tlačidlo Celkové súčty Riadok . Celkový riadok sa hneď zobrazí na konci tabuľky.

Niekedy môže Excel predpokladať, že chcete sčítať iba posledný stĺpec, a ostatné bunky v riadku Celkom nechá prázdne. Ak to chcete napraviť, vyberte prázdnu bunku v riadku Celkom, kliknite na šípku, ktorá sa zobrazí vedľa bunky, a potom v zozname vyberte funkciu SUM:

Tým sa vloží vzorec SUBTOTAL, ktorý sčíta hodnoty len v viditeľné riadky , pričom ignoruje vyfiltrované riadky:

=SUBTOTAL(109,[Jan])

Upozorňujeme, že tento vzorec funguje len v Celkový riadok Ak by ste sa ho pokúsili manuálne vložiť do riadku s údajmi, vytvoril by sa kruhový odkaz a ako výsledok by sa vrátila hodnota 0. Z rovnakého dôvodu nebude fungovať ani vzorec SUM so štruktúrovaným odkazom:

Ak teda chcete získať súčty vo vnútri stola , musíte buď zapnúť riadok Celkom, alebo použiť normálny referenčný rozsah, ako napr:

=SUM(B2:B5)

Mimo stola , vzorec SUM so štruktúrovaným odkazom funguje bez problémov:

=SUM(Predaj[Jan])

Upozorňujeme, že na rozdiel od funkcie SUBTOTAL funkcia SUM sčíta hodnoty vo všetkých riadkoch, viditeľných aj skrytých.

Relatívne a absolútne štruktúrované odkazy v programe Excel

Štruktúrované odkazy programu Excel sa v predvolenom nastavení správajú nasledovne:

• Viacnásobný stĺpec odkazy sú absolútne a pri kopírovaní vzorcov sa nemenia.
• Jeden stĺpec odkazy sú relatívne a menia sa pri preťahovaní cez stĺpce. Pri kopírovaní/vkladaní pomocou príslušného príkazu alebo klávesových skratiek (Ctrl+C a Ctrl+V) sa nemenia.

V situáciách, keď potrebujete kombináciu relatívnych a absolútnych odkazov na tabuľku, neexistuje spôsob, ako vzorec skopírovať a zachovať správne odkazy na tabuľku. Potiahnutím vzorca sa odkazy zmenia na jednotlivé stĺpce a kopírovaním/vkladaním skratiek sa všetky odkazy stanú statickými. Existuje však niekoľko jednoduchých trikov, ako to obísť!

Absolútny štruktúrovaný odkaz na jeden stĺpec

Ak chcete vytvoriť absolútny odkaz na jeden stĺpec, zopakujte názov stĺpca, aby ste ho formálne zmenili na odkaz na rozsah.

Relatívny odkaz na stĺpec (predvolené)

tabuľka [stĺpec]

Absolútny odkaz na stĺpec

tabuľka[[stĺpec]:[stĺpec]]

Vytvorenie absolútneho odkazu pre aktuálny riadok , pred identifikátor stĺpca vložte symbol @:

tabuľka[@[stĺpec]:[stĺpec]]

Ak chcete vidieť, ako relatívne a absolútne odkazy na tabuľky fungujú v praxi, pozrite si nasledujúci príklad.

Predpokladajme, že chcete sčítať čísla predaja konkrétneho výrobku za 3 mesiace. Na tento účel zadáme názov cieľového výrobku do niektorej bunky (v našom prípade F2) a pomocou funkcie SUMIF získame súčet Jan predaj:

=SUMIF(Sales[Item], $F$2, Sales[Jan])

Problém je v tom, že keď vzorec pretiahneme doprava, aby sme vypočítali súčty za ďalšie dva mesiace, zmení sa odkaz [Položka] a vzorec sa poruší:

Ak to chcete opraviť, urobte odkaz [Item] absolútnym, ale odkaz [Jan] ponechajte relatívny:

=SUMIF(Sales[[Item]:[Item]], $F$2, Sales[Jan])

Teraz môžete upravený vzorec pretiahnuť do iných stĺpcov a bude fungovať bezchybne:

Relatívny štruktúrovaný odkaz na viacero stĺpcov

V tabuľkách programu Excel sú štruktúrované odkazy na niekoľko stĺpcov svojou povahou absolútne a pri kopírovaní do iných buniek zostávajú nezmenené.

Podľa mňa je toto správanie veľmi rozumné. Ak však potrebujete, aby bol štruktúrovaný odkaz na rozsah relatívny, predraďte každý špecifikátor stĺpca názvom tabuľky a odstráňte vonkajšie hranaté zátvorky, ako je uvedené nižšie.

Absolútny referenčný rozsah (predvolené)

table[[column1]:[column2]]

Relatívny referenčný rozsah

tabuľka[stĺpec1]:tabuľka[stĺpec2]

Odkazovať na aktuálny riadok v tabuľke , použite symbol @:

[@column1]:[@column2]

Napríklad nasledujúci vzorec s absolútny štruktúrovaný odkaz sčíta čísla v aktuálnom riadku Jan a Február Pri skopírovaní do iného stĺpca bude stále súčet Jan a Február .

=SUM(Predaj[@[január]:[február]])

V prípade, že chcete, aby sa odkaz menil na základe relatívnej polohy stĺpca, do ktorého sa vzorec kopíruje, vytvorte relatívne :

=SUM(Sales[@Jan]:Sales[@Feb])

Všimnite si transformáciu vzorca v stĺpci F (názov tabuľky je vynechaný, pretože vzorec je vnútri tabuľky):

Takto sa vytvárajú odkazy na tabuľky v programe Excel. Ak sa chcete bližšie pozrieť na príklady rozoberané v tomto návode, neváhajte si stiahnuť náš vzorový zošit na Štruktúrovaný odkaz Excelu. Ďakujem vám za prečítanie a dúfam, že sa na našom blogu uvidíme budúci týždeň.