Kennslan sýnir hvernig þú getur nýtt þér nýju SEQUENCE aðgerðina til að búa fljótt til lista yfir dagsetningar í Excel og nota sjálfvirka útfyllingareiginleikann til að fylla dálk með dagsetningum, vinnudögum, mánuðum eða árum.

Þangað til nýlega hefur aðeins verið ein auðveld leið til að búa til dagsetningar í Excel - sjálfvirk útfylling. Kynning á nýju kviku fylki SEQUENCE aðgerðinni hefur gert það mögulegt að búa til röð dagsetninga með formúlu líka. Þessi kennsla fer ítarlega yfir báðar aðferðirnar svo þú getir valið þá sem hentar þér best.

Hvernig á að fylla út dagsetningaröð í Excel

Hvenær þú þarft að fylla dálk með dagsetningum í Excel, fljótlegasta leiðin er að nota sjálfvirka útfyllingareiginleikann.

Sjálfvirkt fylla út dagsetningaröð í Excel

Að fylla dálk eða línu með dagsetningum sem hækka um um einn dagur er mjög auðvelt:

1. Sláðu inn upphafsdagsetningu í fyrsta reit.
2. Veldu reitinn með upphafsdagsetningu og dragðu fyllihandfangið (lítill grænn ferningur neðst -hægra horn) niður eða til hægri.

Excel mun strax búa til röð dagsetninga á sama sniði og fyrsta dagsetningin sem þú slóst inn handvirkt.

Fylltu dálk með virkum dögum, mánuðum eða árum

Til að búa til röð af vinnudögum, mánuðum eða árum skaltu gera eitt af eftirfarandi:

• Fylltu dálk með dagsetningar í röð eins og lýst er hér að ofan. Eftir það skaltu smella á Valkostir fyrir sjálfvirka útfyllingu og veljavalinn valmöguleika, segðu Fylla mánuðir :

  

• Eða þú getur slegið inn fyrstu dagsetninguna þína, hægrismellt á fyllingarhandfangið, haldið inni og dregið í gegnum eins marga reiti eftir þörfum. Þegar þú sleppir músarhnappnum mun samhengisvalmynd sprettigla upp sem gerir þér kleift að velja nauðsynlegan valkost, Fill Years í okkar tilfelli:

  

Fylltu út röð dagsetninga sem hækkar um N daga

Til að búa til sjálfkrafa röð daga, virka daga, mánaða eða ára með sérstöku skrefi þarftu að gera þetta:

1. Sláðu inn upphafsdagsetningu í fyrsta reitinn.
2. Veldu þann reit, hægrismelltu á fyllingarhandfangið, dragðu það í gegnum eins marga reiti og þarf og slepptu síðan.
3. Í sprettivalmyndinni skaltu velja Sería (síðasta atriðið).
4. Í Röð valmyndinni skaltu velja Dagsetningareining áhugaverða og stilltu Skrefagildið .
5. Smelltu á OK.

Fyrir fleiri dæmi, vinsamlegast sjáðu Hvernig á að setja inn og sjálfvirka útfyllingu dagsetningar í Excel.

Hvernig á að búa til dagsetningarröð í Excel með formúlu

Í einu af fyrri námskeiðunum skoðuðum við hvernig á að nota nýja dynamic fylki SEQUENCE aðgerðina til að búa til talnaröð. Vegna þess að innbyrðis í Excel dagsetningar eru geymdar sem raðnúmer, getur aðgerðin auðveldlega framleitt dagsetningarröð líka. Allt sem þú þarft að gera er að stilla rökin rétt eins og útskýrt er í eftirfarandi dæmum.

Athugið. Allar formúlurnar sem fjallað er um hér virka aðeins ínýjustu útgáfur af Excel 365 sem styðja kraftmikla fylki. Í pre-dynamic Excel 2019, Excel 2016 og Excel 2013, vinsamlegast notaðu sjálfvirka útfyllingareiginleikann eins og sýnt er í fyrri hluta þessa kennsluefnis.

Búðu til röð dagsetninga í Excel

Til að búa til röð dagsetninga í Excel, settu upp eftirfarandi rök fyrir RÖÐA fallinu:

• Raðir - the fjöldi lína til að fylla með dagsetningum.
• Dálkar - fjöldi dálka til að fylla með dagsetningum.
• Start - upphafsdagsetningin í sniði sem Excel getur skilið, eins og "8/1/2020" eða "1-Aug-2020". Til að forðast mistök geturðu gefið upp dagsetninguna með því að nota DATE aðgerðina eins og DATE(2020, 8, 1).
• Skref - hækkunin fyrir hverja síðari dagsetningu í röð.

Til dæmis, til að búa til lista yfir 10 dagsetningar sem byrja á 1. ágúst 2020 og hækka um 1 dag, er formúlan:

=SEQUENCE(10, 1, "8/1/2020", 1)

eða

=SEQUENCE(10, 1, DATE(2020, 8, 1), 1)

Að öðrum kosti geturðu slegið inn fjölda dagsetninga (B1), upphafsdagsetningu (B2) og skref (B3) í fyrirfram skilgreindum hólfum og vísað til þeirra hólfa í formúlunni þinni. Þar sem við erum að búa til lista er dálknúmerið (1) harðkóða:

=SEQUENCE(B1, 1, B2, B3)

Sláðu inn formúluna hér að neðan í efsta reitinn (A6 í okkar tilfelli), ýttu á Enter takkann og niðurstöðurnar renna sjálfkrafa yfir tilgreindan fjölda lína og dálka.

Athugið. Með sjálfgefnu Almennt sniði munu niðurstöðurnar birtast sem raðnúmer. Til að láta þær birtast á réttan hátt, vertu viss um að nota dagsetningarsniðið á allar hólfa á lekasviðinu.

Búðu til röð af vinnudögum í Excel

Til að fá aðeins röð af virkum dögum skaltu vefja SEQUENCE í WORKDAY eða WORKDAY.INTL fallið á þennan hátt:

Þar sem WORKDAY fallið bætir fjölda daga sem tilgreindir eru í seinni viðfangsefninu við upphafsdagsetninguna, drögum við 1 frá henni til að hafa upphafsdagsetninguna sjálfa með í niðurstöður.

Til dæmis, til að búa til röð vinnudaga sem byrjar á dagsetningunni í B2, er formúlan:

=WORKDAY(B2-1, SEQUENCE(B1))

Þar sem B1 er röðarstærðin.

Ábendingar og athugasemdir:

• Ef upphafsdagur er laugardagur eða sunnudagur mun þáttaröðin hefjast næsta virka dag.
• Excel WORKDAY aðgerðin gerir ráð fyrir að laugardagur og sunnudagur séu helgar. Til að stilla sérsniðnar helgar og frídaga skaltu nota WORKDAY.INTL aðgerðina í staðinn.

Búa til mánaðaröð í Excel

Til að búa til röð dagsetninga sem hækkuð er um einn mánuð geturðu notað þessi almenna formúla:

Í þessu tilviki setur þú markárið í 1. rifrildi og dag í 3. rök. Fyrir 2. röksemdafærsluna skilar RÖÐFÆRÐ fallið raðtölum frá 1 til 12. Byggt á ofangreindum færibreytum framleiðir DATE fallið röð afdagsetningar eins og sýnt er í vinstri hluta skjámyndarinnar hér að neðan:

=DATE(2020, SEQUENCE(12), 1)

Til að birta aðeins mánaðarnöfnin skaltu stilla eitt af sérsniðnu dagsetningarsniðunum hér að neðan fyrir lekabilið :

• mmm - stutt form eins og Jan , Feb , Mar osfrv.
• mmmm - fullt form eins og janúar , febrúar , mars osfrv.

Þar af leiðandi munu aðeins mánaðarnöfnin birtast í hólfum, en undirliggjandi gildi verða samt fullar dagsetningar. Í báðum seríunum á skjámyndinni hér að neðan skaltu taka eftir sjálfgefna hægri röðun sem er dæmigerð fyrir tölur og dagsetningar í Excel:

Til að búa til dagsetningarröð sem hækkar um einn mánuð og byrjar á ákveðinni dagsetningu , notaðu RÖÐUNAR fallið ásamt EDATE:

EDATE aðgerðin skilar dagsetningu sem er tilgreindur fjöldi mánaða fyrir eða eftir upphafsdag. Og SEQUENCE aðgerðin framleiðir fylki af 12 tölum (eða eins mörgum og þú tilgreinir) til að þvinga EDATE til að halda áfram í eins mánaðar skrefum. Athugaðu að byrjun röksemdin er stillt á 0, þannig að upphafsdagsetningin verði tekin með í niðurstöðunum.

Með upphafsdagsetningu í B1 tekur formúlan þessa mynd:

=EDATE(B1, SEQUENCE(12, 1, 0))

Athugið. Eftir að formúlu hefur verið lokið, vinsamlega mundu að nota viðeigandi dagsetningarsnið á niðurstöðurnar til að þær birti rétt.

Búa til ársröð í Excel

Til að búa tilröð dagsetninga aukið eftir ár, notaðu þessa almennu formúlu:

Þar sem n er fjöldi dagsetninga sem þú vilt búa til.

Í þessu tilviki, DATE(ár, month, day) fall smíðar dagsetningu á þennan hátt:

• Ár er skilað af SEQUENCE fallinu sem er stillt til að búa til n línur með 1 dálkafylki af tölum, sem byrjar á ársgildi frá upphafsdagur .
• Gildi mánaðar og dags eru dregin beint frá upphafsdegi.

Til dæmis, ef þú slærð inn upphafsdagsetningu í B1, mun eftirfarandi formúla gefa út röð af 10 dagsetningum í eins árs þrepum:

=DATE(SEQUENCE(10, 1, YEAR(B1)), MONTH(B1), DAY(B1))

Eftir þegar þær eru sniðnar sem dagsetningar munu niðurstöðurnar líta út sem hér segir:

Búa til tímaröð í Excel

Vegna þess að tímar eru geymdir í Excel sem aukastafir sem tákna brot dagsins getur RÖÐA fallið unnið með tíma beint.

A að því gefnu að upphafstíminn sé í B1 geturðu notað eina af eftirfarandi formúlum til að búa til röð 10 sinnum. Munurinn er aðeins í skref röksemdinni. Þar sem það eru 24 klukkustundir í sólarhring, notaðu 1/24 til að auka um klukkustund, 1/48 til að auka um 30 mínútur, og svo framvegis.

30 mínútur á milli:

=SEQUENCE(10, 1, B1, 1/48)

1 klst á milli:

=SEQUENCE(10, 1, B1, 1/24)

2 klst á milli:

=SEQUENCE(10, 1, B1, 1/12)

Skjámyndin hér að neðan sýnirniðurstöður:

Ef þú vilt ekki nenna að reikna skrefið handvirkt geturðu skilgreint það með því að nota TÍMA aðgerðina:

Fyrir þetta dæmi munum við slá inn allar breyturnar í aðskildum hólfum eins og sýnt er á skjámyndinni hér að neðan . Og svo geturðu notað formúluna hér að neðan til að búa til tímaröð með hvaða þrepa sem þú tilgreinir í hólfum E2 (klst.), E3 (mínútur) og E4 (sekúndur):

=SEQUENCE(B2, B3, B4, TIME(E2, E3, E4))

Hvernig á að búa til mánaðarlegt dagatal í Excel

Í þessu síðasta dæmi, munum við nota RAÐAR aðgerðina ásamt DATEVALUE og WEEKDAY til að búa til mánaðarlegt dagatal sem mun uppfæra sjálfkrafa miðað við árið og mánuðinn sem þú tilgreinir.

Formúlan í A5 er sem hér segir:

=SEQUENCE(6, 7, DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1, 1)

Hvernig þessi formúla virkar:

Þú notar raðfallið til að búa til 6 raðir (hámarksfjöldi vikna í mánuði) með 7 dálkum (fjöldi daga í viku) dagsetningar hækkuð um 1 dag. Þess vegna vekja raðir , dálkar og skref engar spurningar.

Erfiðasti hlutinn í byrjun röksemdinni . Við getum ekki byrjað dagatalið okkar með 1. degi miðunarmánaðar vegna þess að við vitum ekki hvaða vikudagur það er. Svo, við notum eftirfarandi formúlu til að finna fyrsta sunnudag fyrir 1. dag tilgreinds mánaðar ogár:

DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

Fyrsta DATEVALUE fallið skilar raðnúmeri sem, í innra Excel kerfinu, táknar 1. dag mánaðar í B2 og árið í B1. Í okkar tilviki er það 44044 sem samsvarar 1. ágúst 2020. Á þessum tímapunkti höfum við:

44044 - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

WEKDAY fallið skilar vikudegi sem samsvarar fyrsta degi markmiðsins mánuði sem tala frá 1 (sunnudagur) til 7 (laugardagur). Í okkar tilviki er það 7 vegna þess að 1. ágúst 2020 er laugardagur. Og formúlan okkar minnkar í:

44044 - 7 + 1

44044 - 7 er 4403, sem samsvarar laugardaginn 25. júlí 2020. Þar sem við þurfum sunnudaginn bætum við +1 leiðréttingunni við.

Þannig fáum við einfalda formúlu sem gefur út fylki af raðnúmerum sem byrja á 4404:

=SEQUENCE(6, 7, 4404, 1)

Sniðið niðurstöðurnar sem dagsetningar og þú munt fá dagatal sýnt í skjáskotið hér að ofan. Til dæmis geturðu notað eitt af eftirfarandi dagsetningarsniðum:

• d-mmm-yy til að birta dagsetningar eins og 1-20. ágúst
• mmm d til að sýna mánuð og dag eins og 20. ágúst
• d til að sýna aðeins daginn

Bíddu, en við stefnum að því að búa til mánaðarlegt dagatal. Af hverju birtast sumar dagsetningar fyrri og næsta mánaðar? Til að fela þessar óviðkomandi dagsetningar skaltu setja upp skilyrt sniðsreglu með formúlunni hér að neðan og nota hvíta leturgerðina litinn:

=MONTH(A5)MONTH(DATEVALUE($B$2 & "1"))

Þar sem A5 er reitinn lengst til vinstri á dagatalið þitt og B2 er markmiðiðmánuði.

Fyrir ítarleg skref, vinsamlegast sjáðu Hvernig á að búa til formúlubundna skilyrta sniðsreglu í Excel.

Þannig geturðu búið til röð dagsetningar í Excel. Ég þakka þér fyrir lesturinn og vonast til að sjá þig á blogginu okkar í næstu viku!

Æfingabók til niðurhals

Dagsetningarröð í Excel - formúludæmi (.xlsx skrá)