Ako tražite Excel funkciju za dobivanje dana u tjednu od datuma, došli ste na pravu stranicu. Ovaj vodič će vas naučiti kako koristiti formulu WEEKDAY u programu Excel za pretvaranje datuma u naziv dana u tjednu, filtriranje, označavanje i brojanje vikenda ili radnih dana i još mnogo toga.

Postoje razne funkcije za rad s datumima u Excelu. Funkcija dana u tjednu (WEEKDAY) posebno je korisna za planiranje i raspoređivanje, na primjer za određivanje vremenskog okvira projekta i automatsko uklanjanje vikenda iz ukupnog broja. Dakle, prođimo kroz primjere jedan po jedan i vidimo kako vam mogu pomoći da se nosite s raznim zadacima vezanim uz datume u Excelu.

WEEKDAY - Excel funkcija za dan tjedan

Excelova funkcija WEEKDAY koristi se za vraćanje dana u tjednu od zadanog datuma.

Rezultat je cijeli broj, u rasponu od 1 (nedjelja) do 7 (subota) prema zadanim postavkama . Ako vaša poslovna logika zahtijeva drugačije nabrajanje, možete konfigurirati formulu za početak brojanja s bilo kojim drugim danom u tjednu.

Funkcija WEEKDAY dostupna je u svim verzijama programa Excel 365 do 2000.

Sintaksa funkcije WEEKDAY je sljedeća:

Gdje:

Serijski_broj (obavezno) - datum koji želite pretvoriti na broj radnog dana. Može se dostaviti kao serijski broj koji predstavlja datum, kao tekstualni niz u formatukoju Excel razumije, kao referencu na ćeliju koja sadrži datum ili pomoću funkcije DATE.

Vrsta_povrata (neobavezno) - određuje koji dan u tjednu koristiti kao prvi dan . Ako je izostavljeno, zadano je tjedan ned-sub.

Ovdje je popis svih podržanih vrijednosti return_type :

Napomena. Vrijednosti return_type od 11 do 17 uvedene su u Excel 2010 i stoga se ne mogu koristiti u ranijim verzijama.

Osnovna formula WEEKDAY u Excelu

Za početak, pogledajmo kako da biste koristili formulu WEEKDAY u njenom najjednostavnijem obliku da biste dobili broj dana od datuma.

Na primjer, da biste dobili dan u tjednu od datuma u C4 sa zadanim nedjelja - subota tjedan, formula je:

=WEEKDAY(C4)

Ako imate serijski brojkoji predstavlja datum (npr. donosi ga funkcija DATEVALUE), taj broj možete unijeti izravno u formulu:

=WEEKDAY(45658)

Također, možete upisati datum kao tekstualni niz unutar navodnika izravno u formuli. Samo pazite da koristite format datuma koji Excel očekuje i može protumačiti:

=WEEKDAY("1/1/2025")

Ili navedite izvorni datum na 100% pouzdan način pomoću funkcije DATE:

=WEEKDAY(DATE(2025, 1,1))

Za korištenje mapiranja dana koje nije zadano ned-sub, unesite odgovarajući broj u drugi argument. Na primjer, za početak brojanja dana od ponedjeljka, formula je:

=WEEKDAY(C4, 2)

Na slici ispod, sve formule vraćaju dan u tjednu koji odgovara 1. siječnja 2025., što je pohranjen kao broj 45658 interno u Excelu. Ovisno o vrijednosti postavljenoj u drugom argumentu, formule izlaze različite rezultate.

Na prvi pogled može se činiti da brojevi koje vraća funkcija WEEKDAY imaju vrlo malo praktičnog smisla. Ali pogledajmo to iz drugog kuta i razgovarajmo o nekim formulama koje rješavaju zadatke iz stvarnog života.

Kako pretvoriti datum programa Excel u naziv dana u tjednu

Prema dizajnu, funkcija Excel WEEKDAY vraća dan u tjednu kao broj. Da biste broj dana u tjednu pretvorili u naziv dana, upotrijebite funkciju TEXT.

Da biste dobili pune nazive dana , koristite kod formata "dddd":

Za povratak skraćenoimena dana , kod formata je "ddd":

Na primjer, za pretvaranje datuma u A3 u naziv dana u tjednu , formula je:

=TEXT(WEEKDAY(A3), "dddd")

Ili

=TEXT(WEEKDAY(A3), "ddd")

Drugo moguće rješenje je korištenje WEEKDAY zajedno s funkcijom CHOOSE.

Na primjer, da biste dobili skraćeni naziv dana u tjednu iz datuma u A3, formula je sljedeća:

=CHOOSE(WEEKDAY(A3),"Sun","Mon","Tus","Wed","Thu","Fri","Sat")

Ovdje WEEKDAY vraća serijski broj od 1 (ned.) do 7 (sub. ) i CHOOSE odabire odgovarajuću vrijednost s popisa. Budući da datum u A3 (srijeda) odgovara 4, CHOOSE ispisuje "Srijeda", što je 4. vrijednost na popisu.

Iako je formula CHOOSE malo teža za konfiguriranje, ona pruža veću fleksibilnost dopuštajući vam ispisivanje imena dana u bilo kojem formatu koji želite. U gornjem primjeru prikazujemo skraćena imena dana. Umjesto toga, možete isporučiti puna imena, prilagođene kratice ili čak imena dana na drugom jeziku.

Savjet. Još jedan jednostavan način pretvaranja datuma u naziv dana u tjednu je primjena prilagođenog formata datuma. Na primjer, format koda "dddd, mmmm d, yyyy" imat će datum prikazan kao " petak, 3. siječnja 2025 " dok će "dddd" prikazati samo " petak " .

Excel WEEKDAY formula za pronalaženje i filtriranje radnih dana i vikenda

Kada imate posla s dugim popisom datuma, možda ćete htjeti znati koji su radni dani, a koji vikendi.

Za identificiranje vikenda i radnih dana u Excelu, izradite IF naredbu s ugniježđenom funkcijom WEEKDAY. Na primjer:

=IF(WEEKDAY(A3, 2)<6, "Workday", "Weekend")

Ova formula ide u ćeliju A3 i kopira se u onoliko ćelija koliko je potrebno.

U formuli WEEKDAY postavljate return_type do 2, što odgovara tjednu pon-ned gdje je ponedjeljak dan 1. Dakle, ako je broj dana u tjednu manji od 6 (od ponedjeljka do petka), formula vraća "Radni dan", inače - "Vikend".

Za filtriranje vikenda ili radnih dana , primijenite Excel filter na svoj skup podataka ( Podaci kartica > Filtar ) i odaberite "Vikend" ili "Radni dan".

Na snimci zaslona u nastavku, radni dani su filtrirani, tako da su vidljivi samo vikendi:

Ako neki regionalni ured vaše organizacije radi po drugačijem rasporedu gdje su dani odmora nisu subota i nedjelja, formulu WEEKDAY možete jednostavno prilagoditi svojim potrebama navođenjem drugačijeg return_type .

Na primjer, za tretiranje subote i ponedjeljak kao vikend, postavite return_type na 12, tako da ćete dobiti tip tjedna "od utorka (1) do ponedjeljka (7)":

=IF(WEEKDAY(A2, 12)<6, "Workday", "Weekend")

Kako istaknuti vikende radne dane iu Excelu

Da biste na prvi pogled uočili vikende i radne dane na svom radnom listu, možete ih automatski osjenčati različitim bojama. U tu svrhu upotrijebite formulu radni dan/vikend o kojoj smo govorili u prethodnom primjeru sExcel uvjetno oblikovanje. Kako se uvjet podrazumijeva, potrebna nam je samo osnovna funkcija WEEKDAY bez IF omotača.

Za označavanje vikenda (subota i nedjelja):

=WEEKDAY($A2, 2)<6

Za označavanje radnih dana (ponedjeljak - petak):

=WEEKDAY($A2, 2)>5

Gdje je A2 gornja lijeva ćelija odabranog raspona.

Za postavite pravilo uvjetnog oblikovanja, koraci su:

1. Odaberite popis datuma (A2:A15 u našem slučaju).
2. Na kartici Početna , u grupi Stilovi kliknite Uvjetno oblikovanje > Novo pravilo .
3. U dijaloškom okviru Novo pravilo oblikovanja okvir odaberite Upotrijebi formulu za određivanje ćelija za formatiranje .
4. U okvir Oblikuj vrijednosti gdje je ova formula istinita unesite gore navedenu formulu za vikende ili radnim danima.
5. Kliknite gumb Format i odaberite željeni format.
6. Kliknite OK dva puta za spremanje promjena i zatvaranje dijaloških prozora.

Za detaljne informacije o svakom koraku pogledajte Kako postaviti uvjetno oblikovanje s formulom.

Rezultat izgleda prilično lijepo, zar ne?

Kako brojati radne dane i vikende u Excelu

Da biste dobili broj radnih dana ili vikenda na popisu datuma, možete koristiti funkciju WEEKDAY u kombinaciji sa SUM. Na primjer:

Za brojanje vikenda , formula u D3 je:

=SUM(--(WEEKDAY(A3:A20, 2)>5))

Za brojanje radnih dana ,formula u D4 ima ovaj oblik:

=SUM(--(WEEKDAY(A3:A20, 2)<6))

U programima Excel 365 i Excel 2021 koji izvorno rukuju nizovima, ovo funkcionira kao redovita formula kao što je prikazano na snimci zaslona u nastavku. U programu Excel 2019 i ranijim verzijama pritisnite Ctrl + Shift + Enter da biste to učinili formulom polja.

Kako funkcioniraju ove formule:

Funkcija WEEKDAY s return_type postavljenom na 2 vraća broj dana od 1 (pon) do 7 (ned ) za svaki datum u rasponu A3:A20. Logički izraz provjerava jesu li vraćeni brojevi veći od 5 (za vikende) ili manji od 6 (za radne dane). Rezultat ove operacije je niz vrijednosti TRUE i FALSE.

Dvostruka negacija (--) prisiljava logičke vrijednosti na 1 i 0. A funkcija SUM ih zbraja. S obzirom da 1 (TRUE) predstavlja dane koji se broje, a 0 (FALSE) dane koje treba zanemariti, dobit ćete željeni rezultat.

Savjet. Za izračun radnih dana između dva datuma koristite funkciju NETWORKDAYS ili NETWORKDAYS.INTL.

Ako je radni dan onda, ako je subota ili nedjelja onda

Na kraju, raspravimo još malo konkretan slučaj koji pokazuje kako odrediti dan u tjednu, i ako je subota ili nedjelja onda učiniti nešto, ako je radni dan onda učiniti nešto drugo.

Pretpostavimo da izračunavate isplate za zaposlenike koji su radili dodatni posao na svoje slobodne dane, pa vam je potrebnoza primjenu različitih stopa plaćanja za radne dane i vikende. To se može učiniti korištenjem sljedeće IF naredbe:

• U argument logical_test ugniježdite funkciju WEEKDAY koja provjerava je li određeni dan radni dan ili vikend.
• U argumentu value_if_true pomnožite broj radnih sati s stopom vikenda (G4).
• U argumentu value_if_false pomnožite broj radnih sati po stopi radnog dana (G3).

Kompletna formula u D3 ima ovaj oblik:

=IF(WEEKDAY(B3, 2)>5, C3*$G$4, C3*$G$3)

Da bi se formula ispravno kopirala u donje ćelije, obavezno zaključajte adrese ćelija za stopu sa znakom $ (kao $G$4).

Funkcija WEEKDAY ne radi

Općenito, postoje dvije uobičajene pogreške koje formula WEEKDAY može vratiti:

#VALUE! pojavljuje se pogreška ako:

• Serial_number ili return_type nije numerički.
• Serial_number je izvan podržani raspon datuma (1900 do 9999).

#NUM! pogreška se javlja kada je return_type izvan dopuštenog raspona (1-3 ili 11-17).

Ovako se koristi funkcija WEEKDAY u Excelu za manipuliranje danima u tjednu. U sljedećem ćemo članku istražiti Excelove funkcije za rad s većim vremenskim jedinicama kao što su tjedni, mjeseci i godine. Ostanite s nama i hvala vam na čitanju!

Radna bilježnica za vježbe za preuzimanje

Formula WEEKDAY u Excelu - primjeri (.xlsxdatoteka)