Udžbenik objašnjava što je ISNUMBER u Excelu i pruža primjere osnovne i napredne upotrebe.

Koncept funkcije ISNUMBER u Excelu vrlo je jednostavan - samo provjerava je li zadani vrijednost je broj ili nije. Ovdje je važna točka da praktična upotreba funkcije daleko nadilazi njen osnovni koncept, posebno kada se kombinira s drugim funkcijama unutar većih formula.

Funkcija Excel ISNUMBER

Funkcija ISNUMBER u Excelu provjerava sadrži li ćelija brojčanu vrijednost ili ne. Spada u skupinu IS funkcija.

Funkcija je dostupna u svim verzijama programa Excel za Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 i nižim.

Sintaksa ISNUMBER zahtijeva samo jedan argument:

=ISNUMBER(value)

Gdje je vrijednost vrijednost koju želite testirati. Obično je predstavljen referencom ćelije, ali također možete dati stvarnu vrijednost ili ugnijezditi drugu funkciju unutar ISNUMBER da provjerite rezultat.

Ako je vrijednost numerička, funkcija vraća TRUE . Za bilo što drugo (tekstualne vrijednosti, pogreške, praznine) ISNUMBER vraća FALSE.

Kao primjer, testirajmo vrijednosti u ćelijama od A2 do A6, i otkrit ćemo da su prve 3 vrijednosti brojevi, a zadnje dvije su tekst:

2 stvari koje biste trebali znati o funkciji ISNUMBER u Excelu

Ovdje postoji nekoliko zanimljivih točaka:

• Ulazinterni Excel prikaz, datumi i vremena su numeričke vrijednosti, tako da formula ISBROJ vraća TRUE za njih (pogledajte B3 i B4 na gornjoj snimci zaslona).
• Za brojeva pohranjenih kao tekst, funkcija ISNUMBER vraća FALSE (pogledajte ovaj primjer).

Excel ISNUMBER primjeri formula

Primjeri u nastavku pokazuju nekoliko uobičajenih i nekoliko netrivijalnih upotreba od ISNUMBER u Excelu.

Provjerite je li vrijednost broj

Kada imate hrpu vrijednosti u svom radnom listu i želite znati koje su brojevi, ISNUMBER je prava funkcija za korištenje .

U ovom primjeru, prva vrijednost je u A2, pa koristimo donju formulu da je provjerimo, a zatim povlačimo prema dolje formulu do onoliko ćelija koliko je potrebno:

=ISNUMBER(A2)

Obratite pozornost da iako sve vrijednosti izgledaju kao brojevi, formula ISNUMBER je vratila FALSE za ćelije A4 i A5, što znači da su te vrijednosti numerički nizovi , tj. brojevi oblikovani kao tekst. Za to mogu postojati različiti razlozi, na primjer početne nule, apostrof ispred itd. Bez obzira na razlog, Excel ne prepoznaje takve vrijednosti kao brojeve. Dakle, ako se vaše vrijednosti ne izračunaju ispravno, prva stvar za vas je provjeriti jesu li to stvarno brojevi u smislu Excela, a zatim pretvoriti tekst u broj ako je potrebno.

Excel ISNUMBER SEARCH formula

Osim identifikacijskih brojeva, ExcelFunkcija ISNUMBER također može provjeriti sadrži li ćelija određeni tekst kao dio sadržaja. U tu svrhu koristite ISNUMBER zajedno s funkcijom PRETRAŽIVANJE.

U generičkom obliku formula izgleda ovako:

Gdje je podstring tekst koji želite pronaći.

Kao primjer, provjerimo sadrži li niz u A3 određenu boju, recimo crvenu:

=ISNUMBER(SEARCH("red", A3))

Ova formula dobro funkcionira za jednu ćeliju. Ali budući da naša ogledna tablica (pogledajte dolje) sadrži tri različite boje, pisanje zasebne formule za svaku od njih bilo bi gubljenje vremena. Umjesto toga, pozivat ćemo se na ćeliju koja sadrži boju od interesa (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Da bi se formula ispravno kopirala prema dolje i udesno, obavezno zaključajte sljedeće koordinate pomoću znak $:

• U substring referenci, zaključajte red (B$2) tako da kopirane formule uvijek biraju podstringove u retku 2. Referenca stupca je relativna jer mi želite da se prilagodi za svaki stupac, tj. kada se formula kopira u C3, referenca podniza promijenit će se u C$2.
• U referenci izvorne ćelije zaključajte stupac ($A3 ) tako da sve formule provjeravaju vrijednosti u stupcu A.

Snimak zaslona u nastavku prikazuje rezultat:

ISNUMBER FIND - osjetljivo na velika i mala slova formula

Kako je funkcija PRETRAŽIVANJE neosjetljiva na velika i mala slova , goreformula ne razlikuje velika i mala slova. Ako tražite formulu koja razlikuje velika i mala slova, upotrijebite funkciju FIND radije nego SEARCH.

Za naš uzorak skupa podataka , formula bi imala ovaj oblik:

=ISNUMBER(FIND(B$2, $A3))

Kako ova formula funkcionira

Logika formule je sasvim očita i lako ju je slijediti:

• Funkcija SEARCH / FIND traži podniz u navedenoj ćeliji. Ako je podniz pronađen, vraća se pozicija prvog znaka. Ako podniz nije pronađen, funkcija proizvodi #VALUE! greška.
• Funkcija ISNUMBER to preuzima od tamo i obrađuje numeričke položaje. Dakle, ako je podniz pronađen i njegova pozicija vraćena kao broj, ISNUMBER ispisuje TRUE. Ako podniz nije pronađen i #VALUE! dogodi se pogreška, ISNUMBER ispisuje FALSE.

IF ISNUMBER formula

Ako želite dobiti formulu koja daje nešto drugo osim TRUE ili FALSE, koristite ISNUMBER zajedno s funkcijom IF.

Primjer 1. Ćelija sadrži koji tekst

Uzimajući prethodni primjer dalje, pretpostavimo da želite označiti boju svake stavke s "x" kao što je prikazano u tablici ispod.

Da biste to učinili, jednostavno zamotajte formulu ISNUMBER SEARCH u naredbu IF:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Ako ISNUMBER vraća TRUE, funkcija IF ispisuje "x" (ili bilo koju drugu vrijednost koju unesete u value_if_true argument). Ako ISNUMBER vrati FALSE, funkcija IF ispisuje prazan niz ("").

Primjer 2. Prvi znak u ćeliji je broj ili tekst

Zamislite da radite s popisom alfanumeričkih nizova i želite znati je li prvi znak niza broj ili slovo.

Za izradu takve formule trebat će vam 4 različite funkcije:

• Funkcija LIJEVO izvlači prvi znak s početka niza, recimo u ćeliji A2:

  LEFT(A2, 1)

• Budući da LIJEVO pripada kategoriji tekstualnih funkcija, njezina rezultat je uvijek tekstualni niz, čak i ako sadrži samo brojeve. Stoga, prije provjere izdvojenog znaka, moramo ga pokušati pretvoriti u broj. Za to upotrijebite funkciju VRIJEDNOST ili dvostruki unarni operator:

  VALUE(LEFT(A2, 1)) ili (--LEFT(A2, 1))

• Funkcija ISNUMBER određuje je li izdvojeni znak numerički ili ne:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Na temelju rezultata ISNUMBER (TRUE ili FALSE), funkcija IF vraća "Broj" odnosno "Slovo".

Pod pretpostavkom da testiramo niz u A2, potpuna formula ima ovaj oblik:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

ili

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

Funkcija ISNUMBER također je korisna za izdvajanje brojeva iz niza. Evo primjera: Uzmite broj s bilo koje pozicije u nizu.

Provjerite nije li vrijednost broj

Iako Microsoft Excel ima posebnu funkciju, ISNONTEXT, za određivanjeako vrijednost ćelije nije tekst, nedostaje analogna funkcija za brojeve.

Jednostavno rješenje je koristiti ISNUMBER u kombinaciji s NOT koji vraća suprotno od logičke vrijednosti. Drugim riječima, kada ISNUMBER vrati TRUE, NE pretvara ga u FALSE, i obrnuto.

Da biste ga vidjeli na djelu, pogledajte rezultate sljedeće formule:

=NOT(ISNUMBER(A2))

Drugi pristup koristi funkcije IF i ISNUMBER zajedno:

=IF(ISNUMBER(A2), "", "Not number")

Ako je A2 numerički, formula ne vraća ništa (prazan niz). Ako A2 nije numerički, formula to kaže unaprijed: "Nije broj".

Ako želite izvesti neke izračune s brojevima, stavite jednadžbu ili formulu u argumentu value_if_true umjesto praznog niza. Na primjer, formula u nastavku pomnožit će brojeve s 10 i dati "Nije broj" za nenumeričke vrijednosti:

=IF(ISNUMBER(A2), A2*10, "Not number")

Provjerite sadrži li raspon bilo koji broj

U situacija kada želite testirati cijeli raspon za brojeve, upotrijebite funkciju ISNUMBER u kombinaciji sa SUMPROIZVOD ovako:

Na primjer, da biste saznali sadrži li raspon A2:A5 neku numeričku vrijednost, formule bi bile sljedeće:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Ako želite ispisati "Da" i "Ne" umjesto TRUE i FALSE, upotrijebite naredbu IF kao"omot" za gornje formule. Na primjer:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Kako ova formula radi

U srcu formule, funkcija ISNUMBER procjenjuje svaku ćeliju navedeni raspon, recimo B2:B5, i vraća TRUE za brojeve, FALSE za bilo što drugo. Budući da raspon sadrži 4 ćelije, polje ima 4 elementa:

{TRUE;FALSE;FALSE;FALSE}

Operacija množenja ili dvostruki unarni (--) pretvara TRUE i FALSE u 1 odnosno 0:

{1;0;0;0}

Funkcija SUMPRODUCT zbraja elemente niza. Ako je rezultat veći od nule, to znači da postoji barem jedan broj u rasponu. Dakle, koristite ">0" da dobijete konačni rezultat TRUE ili FALSE.

ISNUMBER u uvjetnom oblikovanju za označavanje ćelija koje sadrže određeni tekst

Ako želite istaknuti ćelije ili cijele retke koji sadrže određeni tekst, stvorite pravilo uvjetnog oblikovanja temeljeno na formuli ISNUMBER SEARCH (neosjetljivo na velika i mala slova) ili ISNUMBER FIND (osjetljivo na velika i mala slova).

Za ovaj ćemo primjer označiti retke na temelju vrijednost u stupcu A. Točnije, istaknut ćemo stavke koje sadrže riječ "crveno". Evo kako:

1. Odaberite sve retke podataka (A2:C6 u ovom primjeru) ili samo stupac u kojem želite istaknuti ćelije.
2. Na Početnoj , u grupi Stilovi kliknite Novo pravilo > Koristite formulu da odredite koje ćelije oblikovati .
3. Uu okvir Formatiraj vrijednosti gdje je ova formula istinita unesite donju formulu (primijetite da je koordinata stupca zaključana znakom $):

   =ISNUMBER(SEARCH("red", $A2))

4. Kliknite Format gumb i odaberite format koji želite.
5. Kliknite OK dvaput.

Ako nemate iskustva s Excel uvjetnim oblikovanjem, možete pronaći detaljne korake sa snimkama zaslona u ovom vodiču: Kako stvoriti pravilo uvjetnog oblikovanja temeljeno na formuli.

Kao rezultat, sve stavke crvene boje su istaknute:

Umjesto "tvrdog kodiranja" boje u pravilu uvjetnog oblikovanja, možete je upisati u unaprijed definiranu ćeliju, recimo E2, i pozvati se na tu ćeliju u svojoj formuli (pripazite na apsolutnu referencu ćelije $E$2). Osim toga, morate provjeriti nije li ulazna ćelija prazna:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Kao rezultat, dobit ćete fleksibilnije pravilo koje ističe retke na temelju vašeg unosa u E2:

Tako se koristi funkcija ISNUMBER u Excelu. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!

Dostupna preuzimanja

Excel ISNUMBER primjeri formula