ટ્યુટોરીયલ બતાવે છે કે કેસ-સંવેદનશીલ અને ચોક્કસ મેચ માટે Excel માં ટેક્સ્ટ સ્ટ્રીંગની સરખામણી કેવી રીતે કરવી. તમે બે કોષોની તેમની કિંમતો, સ્ટ્રિંગ લંબાઈ અથવા ચોક્કસ અક્ષરની ઘટનાઓની સંખ્યા, તેમજ બહુવિધ કોષોની તુલના કેવી રીતે કરવી તે દ્વારા તમે સંખ્યાબંધ સૂત્રો શીખી શકશો.

જ્યારે એક્સેલનો ઉપયોગ ડેટા વિશ્લેષણ, ચોકસાઈ એ સૌથી મહત્વપૂર્ણ ચિંતા છે. ખોટી માહિતી ચૂકી ગયેલી સમયમર્યાદા, ખોટા નિર્ણયો, ખોટા નિર્ણયો અને આવક ગુમાવવા તરફ દોરી જાય છે.

જ્યારે એક્સેલ ફોર્મ્યુલા હંમેશા સંપૂર્ણ રીતે સાચા હોય છે, ત્યારે તેમના પરિણામો ખોટા હોઈ શકે છે કારણ કે અમુક ખામીયુક્ત ડેટા સિસ્ટમમાં ઘૂસી જાય છે. આ કિસ્સામાં, એકમાત્ર ઉપાય એ છે કે ચોકસાઈ માટે ડેટા તપાસો. મેન્યુઅલી બે કોષોની સરખામણી કરવી એ કોઈ મોટી વાત નથી, પરંતુ સેંકડો અને હજારો ટેક્સ્ટ સ્ટ્રિંગ્સ વચ્ચેના તફાવતને શોધવાનું અશક્ય છે.

આ ટ્યુટોરીયલ તમને કોષના કંટાળાજનક અને ભૂલ-સંભવિત કાર્યને કેવી રીતે સ્વચાલિત કરવું તે શીખવશે. સરખામણી કરો અને દરેક ચોક્કસ કેસમાં કયા ફોર્મ્યુલાનો ઉપયોગ કરવો શ્રેષ્ઠ છે.

એક્સેલમાં બે કોષોની તુલના કેવી રીતે કરવી

એક્સેલમાં સ્ટ્રીંગ્સની તુલના કરવાની બે અલગ અલગ રીતો છે. તમે કેસ-સંવેદનશીલ અથવા કેસ-સંવેદનશીલ સરખામણી શોધો છો.

2 કોષોની તુલના કરવા માટે કેસ-સંવેદનશીલ સૂત્ર

એક્સેલમાં બે કોષોને અવગણતા કેસની તુલના કરવા માટે, આના જેવા સરળ સૂત્રનો ઉપયોગ કરો:<3

=A1=B1

જ્યાં A1 અને B1 એ કોષો છે જેની તમે સરખામણી કરી રહ્યાં છો. સૂત્રનું પરિણામ બુલિયન મૂલ્યો TRUE છેઅને FALSE.

જો તમે મેળ અને તફાવતો માટે તમારા પોતાના ટેક્સ્ટને આઉટપુટ કરવા માંગતા હો, તો ઉપરોક્ત નિવેદનને IF ફંક્શનના લોજિકલ ટેસ્ટમાં એમ્બેડ કરો. ઉદાહરણ તરીકે:

=IF(A1=B1, "Equal", "Not equal")

જેમ તમે નીચે સ્ક્રીનશોટમાં જુઓ છો, બંને ફોર્મ્યુલા ટેક્સ્ટ સ્ટ્રીંગ્સ, તારીખો અને સંખ્યાઓની સમાન રીતે સરખાવે છે:

કેટલીક પરિસ્થિતિઓમાં, માત્ર બે કોષોના ટેક્સ્ટ મૂલ્યોની તુલના કરવી જ નહીં, પણ અક્ષર કેસની તુલના કરવી પણ મહત્વપૂર્ણ હોઈ શકે છે. કેસ-સંવેદનશીલ ટેક્સ્ટ સરખામણી Excel EXACT ફંક્શનનો ઉપયોગ કરીને કરી શકાય છે:

જ્યાં text1 અને text2 એ બે કોષો છે જે તમે સરખામણી કરી રહ્યાં છો.

તમારા શબ્દમાળાઓ કોષ A2 અને B2 માં છે એમ ધારી રહ્યા છીએ, સૂત્ર નીચે પ્રમાણે જાય છે:

=EXACT(A2, B2)

પરિણામે, તમને કેસ સહિત ટેક્સ્ટ સ્ટ્રીંગ્સ બરાબર મેચ કરવા માટે TRUE મળે છે દરેક અક્ષરના, અન્યથા FALSE.

જો તમે ઇચ્છો છો કે ચોક્કસ ફંક્શન કેટલાક અન્ય પરિણામો આપે, તો તેને IF ફોર્મ્યુલામાં એમ્બેડ કરો અને value_if_true અને value_if_false<માટે તમારું પોતાનું લખાણ લખો 2> દલીલો:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

નીચેનો સ્ક્રીનશોટ એક્સેલમાં કેસ-સંવેદનશીલ સ્ટ્રિંગ સરખામણીના પરિણામો બતાવે છે:

કેવી રીતે એક્સેલમાં બહુવિધ કોષોની તુલના કરો

સળંગ 2 થી વધુ કોષોની તુલના કરવા માટે, ઉપરના ઉદાહરણોમાં AND ઓપરેટર સાથે સંયોજનમાં ચર્ચા કરેલ સૂત્રોનો ઉપયોગ કરો. સંપૂર્ણ વિગતો નીચે આપેલ છે.

સરખામણી કરવા માટે કેસ-સંવેદનશીલ ફોર્મ્યુલા2 થી વધુ કોષો

તમે પરિણામો કેવી રીતે પ્રદર્શિત કરવા માંગો છો તેના આધારે, નીચેનામાંથી એક ફોર્મ્યુલાનો ઉપયોગ કરો:

=AND(A2=B2, A2=C2)

અથવા

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

અને સૂત્ર TRUE આપે છે જો બધા કોષોમાં સમાન મૂલ્ય હોય, તો FALSE જો કોઈ મૂલ્ય અલગ હોય. IF સૂત્ર તમે તેમાં લખેલા લેબલોને આઉટપુટ કરે છે, આ ઉદાહરણમાં " સમાન " અને " સમાન નથી ".

નીચેના સ્ક્રીનશોટમાં દર્શાવ્યા પ્રમાણે, ફોર્મ્યુલા કોઈપણ ડેટા પ્રકારો - ટેક્સ્ટ, તારીખો અને આંકડાકીય મૂલ્યો સાથે સંપૂર્ણ રીતે કાર્ય કરે છે:

કેટલાક કોષોમાં ટેક્સ્ટની તુલના કરવા માટે કેસ-સંવેદનશીલ ફોર્મ્યુલા

બહુવિધ સ્ટ્રિંગ્સની તુલના કરવા માટે એકબીજા સાથે બરાબર મેળ ખાય છે કે કેમ તે જોવા માટે, નીચેના સૂત્રોનો ઉપયોગ કરો:

=AND(EXACT(A2,B2), EXACT(A2, C2))

અથવા

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

અગાઉના ઉદાહરણની જેમ, પ્રથમ ફોર્મ્યુલા સાચા અને ખોટા મૂલ્યો વિતરિત કરે છે, જ્યારે બીજો મેળ અને તફાવતો માટે તમારા પોતાના પાઠો દર્શાવે છે:

સેમ્પલ સેલ સાથે સેલની શ્રેણીની તુલના કરો

નીચેના ઉદાહરણો બતાવે છે કે તમે કેવી રીતે ચકાસી શકો છો કે આપેલ શ્રેણીના તમામ કોષોમાં નમૂના કોષમાં સમાન ટેક્સ્ટ છે.

સેમ્પલ ટેક્સ્ટ સાથે સેલની તુલના કરવા માટે કેસ-અસંવેદનશીલ ફોર્મ્યુલા

જો અક્ષર કેસ ખરેખર વાંધો નથી, તમે નમૂના સાથે કોષોની તુલના કરવા માટે નીચેના સૂત્રનો ઉપયોગ કરી શકો છો:

IF ફંક્શનના લોજિકલ ટેસ્ટમાં, તમે બે નંબરોની સરખામણી કરો છો:

• કોષોની કુલ સંખ્યાનિર્દિષ્ટ શ્રેણીમાં (સ્તંભોની સંખ્યા દ્વારા ગુણાકાર કરેલ પંક્તિઓની સંખ્યા), અને
• સેમ્પલ સેલમાં સમાન મૂલ્ય ધરાવતા કોષોની સંખ્યા (COUNTIF કાર્ય દ્વારા પરત કરવામાં આવે છે).

સેમ્પલ ટેક્સ્ટ C2 માં છે અને સરખામણી કરવા માટેની સ્ટ્રિંગ્સ A2:B6 રેન્જમાં છે એમ ધારી રહ્યા છીએ, ફોર્મ્યુલા નીચે મુજબ છે:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

પરિણામોને વધુ વપરાશકર્તા બનાવવા માટે- મૈત્રીપૂર્ણ, એટલે કે TRUE અને FALSE ને બદલે "બધા મેચ" અને "બધા મેચ નથી" જેવું કંઈક આઉટપુટ કરો, IF ફંક્શનનો ઉપયોગ કરો જેમ કે આપણે અગાઉના ઉદાહરણોમાં કર્યું છે:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

ઉપરના સ્ક્રીનશૉટમાં બતાવ્યા પ્રમાણે, ફોર્મ્યુલા ટેક્સ્ટ સ્ટ્રિંગ્સની શ્રેણી સાથે સંપૂર્ણ રીતે સામનો કરે છે, પરંતુ તેનો ઉપયોગ નંબરો અને તારીખોની સરખામણી કરવા માટે પણ થઈ શકે છે.

કેસ-સેન્સિટિવ ફોર્મ્યુલાને સ્ટ્રિંગ્સની સરખામણી કરવા માટે નમૂના ટેક્સ્ટ

જો કેરેક્ટર કેસમાં ફરક પડે, તો તમે નીચેના એરે ફોર્મ્યુલાનો ઉપયોગ કરીને સેમ્પલ ટેક્સ્ટ સાથે સ્ટ્રિંગ્સની તુલના કરી શકો છો.

A2:B6 માં રહેલ સ્ત્રોત શ્રેણી અને C2 માં નમૂના ટેક્સ્ટ સાથે, સૂત્ર નીચેનો આકાર લે છે:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

સામાન્ય એક્સેલ ફોર્મ્યુલાથી વિપરીત , એરે ફોર્મ્યુલા Ctrl + Shift + Enter દબાવીને પૂર્ણ થાય છે. જો યોગ્ય રીતે દાખલ કરેલ હોય, તો એક્સેલ એરે ફોર્મ્યુલાને {સર્પાકાર કૌંસ} માં બંધ કરે છે, જેમ કે સ્ક્રીનશૉટમાં બતાવ્યા પ્રમાણે:

સ્ટ્રિંગ દ્વારા બે કોષોની તુલના કેવી રીતે કરવીલંબાઈ

ક્યારેક તમે દરેક પંક્તિમાં ટેક્સ્ટ સ્ટ્રીંગમાં સમાન સંખ્યામાં અક્ષરો છે કે કેમ તે તપાસવા માગી શકો છો. આ કાર્ય માટેનું સૂત્ર ખૂબ જ સરળ છે. પ્રથમ, તમે LEN ફંક્શનનો ઉપયોગ કરીને બે કોષોની સ્ટ્રિંગ લંબાઈ મેળવો છો, અને પછી સંખ્યાઓની તુલના કરો.

માની લો કે સ્ટ્રિંગ્સની સરખામણી કોષો A2 અને B2 માં છે, તો નીચેનામાંથી કોઈપણ ફોર્મ્યુલાનો ઉપયોગ કરો:

=LEN(A2)=LEN(B2)

અથવા

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

જેમ તમે પહેલાથી જ જાણો છો, પ્રથમ ફોર્મ્યુલા બુલિયન મૂલ્યો TRUE અથવા FALSE આપે છે, જ્યારે બીજું સૂત્ર તમારા પોતાના પરિણામો આપે છે:

ઉપરના સ્ક્રીનશોટમાં દર્શાવ્યા મુજબ, ફોર્મ્યુલા ટેક્સ્ટ સ્ટ્રીંગ્સ તેમજ સંખ્યાઓ માટે કામ કરે છે.

ટીપ. જો બે સમાન લાગતી તાર જુદી જુદી લંબાઈ આપે છે, તો સંભવતઃ સમસ્યા એક અથવા બંને કોષોમાં અગ્રેસર અથવા પાછળની જગ્યાઓ માં છે. આ કિસ્સામાં, TRIM ફંક્શનનો ઉપયોગ કરીને વધારાની જગ્યાઓ દૂર કરો. વિગતવાર સમજૂતી અને ફોર્મ્યુલા ઉદાહરણો અહીં મળી શકે છે: Excel માં જગ્યાઓ કેવી રીતે ટ્રિમ કરવી.

વિશિષ્ટ પાત્રની ઘટનાઓ દ્વારા બે કોષોની તુલના કરો

આ અમારા એક્સેલ કમ્પેર સ્ટ્રીંગ્સ ટ્યુટોરીયલમાં છેલ્લું ઉદાહરણ છે, અને તે ચોક્કસ કાર્ય માટે ઉકેલ દર્શાવે છે. ધારો કે, તમારી પાસે ટેક્સ્ટ સ્ટ્રિંગ્સની 2 કૉલમ છે જેમાં તમારા માટે મહત્વપૂર્ણ અક્ષર છે. તમારો ધ્યેય એ તપાસવાનો છે કે દરેક પંક્તિના બે કોષોમાં આપેલ અક્ષરની સમાન સંખ્યા છે કે કેમ.

વસ્તુઓને વધુ સ્પષ્ટ કરવા માટે, નીચેનાનો વિચાર કરો.ઉદાહરણ. ચાલો કહીએ કે, તમારી પાસે મોકલેલ ઓર્ડરની બે સૂચિ છે (કૉલમ B) અને પ્રાપ્ત (કૉલમ C). દરેક પંક્તિમાં ચોક્કસ આઇટમ માટે ઓર્ડર હોય છે, જેની અનન્ય ઓળખકર્તા તમામ ઓર્ડર ID માં સમાવવામાં આવેલ છે અને કૉલમ A માં સમાન પંક્તિમાં સૂચિબદ્ધ છે (કૃપા કરીને નીચેનો સ્ક્રીનશોટ જુઓ). તમે એ સુનિશ્ચિત કરવા માંગો છો કે દરેક પંક્તિમાં તે ચોક્કસ ID સાથે મોકલેલ અને પ્રાપ્ત થયેલી વસ્તુઓની સમાન સંખ્યા છે.

આ સમસ્યાને ઉકેલવા માટે, નીચેના તર્ક સાથે સૂત્ર લખો.

• પ્રથમ, SUBSTITUTE ફંક્શનનો ઉપયોગ કરીને અનન્ય ઓળખકર્તાને કંઈપણ સાથે બદલો:

  SUBSTITUTE(A1, character_to_count,"")

• પછી, દરેક કોષમાં અનન્ય ઓળખકર્તા કેટલી વાર દેખાય છે તેની ગણતરી કરો. આ માટે, અનન્ય ઓળખકર્તા વગર સ્ટ્રિંગની લંબાઈ મેળવો અને તેને સ્ટ્રિંગની કુલ લંબાઈમાંથી બાદ કરો. આ ભાગ સેલ 1 અને સેલ 2 માટે વ્યક્તિગત રીતે લખવામાં આવશે, ઉદાહરણ તરીકે:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  અને

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• છેલ્લે, તમે આ 2 નંબરોની તુલના કરો. ઉપરોક્ત ભાગો વચ્ચે સમાનતા ચિહ્ન (=) મૂકીને.

LEN( સેલ 2 ) - LEN(SUBSTITUTE( cell 2 , character_to_count , ""))

અમારા ઉદાહરણમાં, અનન્ય ઓળખકર્તા A2 માં છે , અને સરખામણી કરવા માટેની સ્ટ્રિંગ્સ B2 અને C2 કોષોમાં છે. તેથી, સંપૂર્ણ સૂત્ર નીચે મુજબ છે:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

જો કોષો B2 અને C2 A2 માં અક્ષરોની સમાન સંખ્યા ધરાવે છે, તો સૂત્ર TRUE પરત કરે છે,અન્યથા FALSE. તમારા વપરાશકર્તાઓ માટે પરિણામોને વધુ અર્થપૂર્ણ બનાવવા માટે, તમે IF ફંક્શનમાં ફોર્મ્યુલાને એમ્બેડ કરી શકો છો:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

જેમ તમે ઉપરના સ્ક્રીનશોટમાં જોઈ શકો છો. , કેટલીક વધારાની ગૂંચવણો હોવા છતાં સૂત્ર સંપૂર્ણ રીતે કાર્ય કરે છે:

• ગણવા માટેનું પાત્ર (યુનિક આઇડેન્ટિફાયર) ટેક્સ્ટ સ્ટ્રીંગમાં ગમે ત્યાં દેખાઈ શકે છે.
• સ્ટ્રિંગમાં ચલ સંખ્યા હોય છે અક્ષરો અને અર્ધવિરામ, અલ્પવિરામ અથવા સ્પેસ જેવા વિવિધ વિભાજકો.

આ રીતે તમે Excel માં સ્ટ્રિંગ્સની તુલના કરો છો. આ ટ્યુટોરીયલમાં ચર્ચા કરેલ સૂત્રોને નજીકથી જોવા માટે, એક્સેલ કમ્પેર સ્ટ્રીંગ્સ વર્કશીટ ડાઉનલોડ કરવા માટે તમારું સ્વાગત છે. હું વાંચવા બદલ તમારો આભાર અને આશા રાખું છું કે તમને આવતા અઠવાડિયે અમારા બ્લોગ પર મળીશ.