"Spojit" obvykle znamená spojit něco do řady nebo řetězce. Tato operace se používá vždy, když potřebujete spojit text z více buněk Tabulky Google. V tomto článku jsou shromážděna nejoblíbenější a nejjednodušší řešení, která vám pomohou vyřešit hádanku spojování.

Ať už je váš soubor dat jakkoli velký, můžete se setkat s úkolem spojit více buněk v tabulkách Google dohromady. A nepochybuji o tom, že budete chtít nejen zachovat všechny hodnoty, aby se neztratily, ale také přidat nějaké čárky, mezery nebo jiné znaky, případně tyto záznamy oddělit jiným textem.

Tabulkové procesory nabízejí pro tento úkol několik nástrojů.

Funkce CONCAT v tabulkách Google

Funkce CONCAT je zjednodušenou verzí funkce CONCATENATE z Tabulky Google:

Chcete-li pomocí této funkce spojit buňky, musíte vypsat požadované hodnoty:

• hodnota1 - záznam, ke kterému má být připojena hodnota2.
• hodnota2 - hodnotu, ke které se má připojit.

Chcete-li získat jeden řetězec ze 2 textových nebo číselných jednotek, vzorec bude vypadat následovně, přičemž každý záznam bude v uvozovkách:

=CONCAT("2019:", "Lví král")

Ve skutečnosti jsou vaše data již pravděpodobně v buňkách. Na tyto buňky se můžete přímo odkazovat, místo abyste každé číslo nebo text zadávali jako argument. Vzorec pro skutečná data tedy bude vypadat takto:

=CONCAT(A2,B2)

Tip: Chcete-li vzorec zkopírovat do celého sloupce, vyberte buňku se vzorcem a dvakrát klikněte na malý čtvereček v pravém dolním rohu buňky. Vzorec se automaticky doplní do celého sloupce až na konec tabulky.

Jak vidíte, funkce je velmi jednoduchá, ale má zásadní význam. slabá místa :

• sloučí v tabulkách Google pouze dvě buňky najednou.
• nemůže spojovat sloupce, řádky nebo jiné velké rozsahy dat, bere pouze jednotlivé buňky. Pokud se pokusíte spojit více buněk, buď se zobrazí chyba, nebo se spojí pouze první dvě hodnoty, jako je tomu v tomto případě:

  =CONCAT(A2:A11,B2:B11)

  

Alternativa CONCAT: spojovací operátor ampersand (&)

Ve vzorcích existuje mnoho různých operátorů pro různé účely. Výjimkou není ani spojování. Použitím znaku ampersand (&) ve vzorcích místo funkce CONCAT získáte stejný výsledek:

=A2&B2

Málokdo však ví, že tento operátor spojování je mnohem flexibilnější. Tady je popis toho, co umí:

1. Sloučení více než dvou hodnot najednou:

   =A2&B2&C2

   

2. Buňky v tabulkách Google můžete nejen slučovat, ale také je oddělovat různými znaky:

   =A2&" "&B2&"; "&C2

   

Pokud ani po těchto možnostech nedosáhnete požadovaného výsledku, můžete vyzkoušet ještě jednu funkci.

Jak používat CONCATENATE v Tabulkách Google

Domnívám se, že funkce CONCATENATE v tabulkách Google je první, kterou je třeba použít, pokud jde o připojení několika záznamů k sobě.

KONCATENACE textových řetězců a čísel v Tabulkách Google

Vzor vzorce se skládá z následujících argumentů:

• string1 je první řetězec, ke kterému chcete připojit další hodnoty. Tento argument je povinný.
• string2, ... označuje všechny ostatní řetězce, které chcete připojit. Tento argument je nepovinný.

Poznámka: Výsledný záznam se bude skládat z řetězců v pořadí, v jakém se vyskytují ve vzorci.

Pokud vzorec přizpůsobím svým údajům, dostanu tento výsledek:

=CONCATENATE(A2,B2,C2)

Nebo, protože funkce akceptuje rozsahy:

=CONCATENATE(A2:D2)

Ihned si můžete všimnout první výhody funkce CONCATENATE v tabulkách Google: snadno spojí dvě buňky s textem i čísly.

Tabulky Google: spojování řetězců s oddělovači

Spojení buněk v tabulkách Google je polovina práce. Aby však výsledek vypadal hezky a čitelně, měli byste přidat několik dalších znaků.

Pokud vzorec ponecháte v původním stavu, vše se jen slepí dohromady: BonnieJacksonCA , BonnieJacksonIN , atd. Ale CONCATENATE v Tabulkách Google přijímá jako argumenty i znaky.

Chcete-li tedy přidat některé oddělovače pro lepší čitelnost, uveďte je ve vzorci ve dvojitých uvozovkách:

=CONCATENATE(A2," ",B2,", ",C2)

Zde chci spojit A2 & B2 s mezerou a oddělit B2 od C2 čárkou a mezerou:

V této funkci můžete použít téměř libovolný znak, ale zalomení řádku vyžaduje jiný přístup.

Tip. V případě, že se v některých sloupcích, které slučujete, vyskytují prázdné buňky, je tu ještě jedna funkce, která by vás mohla zajímat. TEXTJOIN nejenže sloučí buňky v Tabulkách Google, ale ignoruje prázdná místa:

=TEXTJOIN(" ",TRUE,A2:C2)

Funguje to takto:

1. Jako první argument uveďte požadovaný oddělovač - prostor (" ") pro mě.
2. Vložte TRUE jako druhý argument pro přeskočení prázdných buněk nebo FALSE zahrnout je do výsledku.
3. Zadejte rozsah, který chcete sloučit.

Spojování s přerušením řádku v Tabulkách Google

Zatímco u většiny oddělovačů je zřejmé, jak je do funkce zadat, zalomení řádku tam stejným způsobem zadat nelze. Google vám ale naštěstí umožňuje hrát s mnoha různými kartami.

Existuje funkce, která pomáhá získat speciální znaky - jmenuje se CHAR. Víte, každý znak má své místo v tabulce Unicode. Stačí funkci předat pořadové číslo znaku z této tabulky a ta vrátí samotný znak.

Zde je vzorec pro získání zlomu řádku:

=CHAR(10)

Přidejte ji do vzorce pro zřetězení s přerušením řádku v Tabulkách Google:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Kombinace data a času v tabulkách Google

Pokud se pokusíte zkombinovat datum a čas v Tabulkách Google některou z výše uvedených metod, nebude to fungovat. Tabulka vám vrátí čísla:

Chcete-li v tabulkách Google správně kombinovat datum a čas, použijte funkci TEXT:

• kde číslo je libovolné číslo, datum nebo čas, které chcete získat v požadovaném formátu.
• a formát je vzor, který byste chtěli vidět jako výsledek.

Tip: V mém příkladu budu odkazovat na buňky s daty a časy, ale můžete použít jednotky data/času nebo dokonce funkce jako DATE nebo TIME přímo ve vzorci.

1. Pomocí prvního vzorce TEXT změním formát data z 7/9/2019 na 9. července 2019 :

   =TEXT(B2, "D MMM RRRR")

2. Druhý TEXT vrací čas:

   =TEXT(C2, "HH:MM:SS")

3. Pomocí těchto znaků v nástroji CONCATENATE mi Tabulky Google umožňují kombinovat datum a čas v požadovaném formátu s dalšími znaky nebo textem:

   =CONCATENATE(TEXT(B2, "D MMM RRRR"),", ",TEXT(C2, "HH:MM:SS"))

Kombinování sloupců v Tabulkách Google

S mírnými úpravami lze sloučit sloupce v tabulkách Google všemi způsoby, které jsem uvedl.

Příklad 1. CONCAT v tabulkách Google

Chcete-li v Listech Google sloučit celé sloupce pomocí funkce CONCAT, vyberte celý rozsah, který má obsahovat výsledek (v mém případě C2:C11), a zadejte vzorec, který jej obaluje, do pole ARRAYFORMULA:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Poznámka: Můžete použít funkci CONCATENATE, ale ta spojí všechny záznamy v rámci jedné buňky, protože snadno sloučí více buněk a rozsahů dat.

Příklad 2. Operátor konkatenace

Vytvářejte vzorce pole pro kombinování sloupců v tabulkách Google pomocí ampersandu a zároveň přidávejte oddělovače:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Vypadá to dobře, ale musím poukázat na některé zásadní nevýhody.

Pokud máte příliš mnoho sloupců, může se jejich výčet stát nepříjemným, zejména pokud omylem vynecháte/duplikujete/smícháte některé znaky.

Pokud se později rozhodnete přidat do vzorce další sloupce, budete muset každý existující rozsah ve vzorci upravit ručně.

Další příklad tyto problémy řeší.

Příklad 3. Dotaz v tabulkách Google

Funkce Google Sheets QUERY je také vhodná pro sloučení několika sloupců v Google Sheets. Podívejte se:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Možná si myslíte, že tento podivný vzorec je pro vás nepochopitelný, ale dovolte mi, abych vám ho vyložil ve všech jeho částech:

1. =TRANSPOSE(A2:D10) změní řádky dat na sloupce.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) sloučí záznamy v každém sloupci do horních buněk.

   Tip. Když dám 9^9 do vzorce, ujistím se, že všechny řádky ze všech sloupců budou vytaženy do prvního řádku, jako by to byly záhlaví. Je to 9^9 protože tento výraz zahrnuje všechny možné buňky v tabulce (pamatujete na limit pro 10M buněk?) a snadno se pamatuje :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) vezme tento řádek záhlaví z QUERY a změní jej na sloupec, jako je ten, který mám.

Zde jsou výhody sloučení sloupců v tabulkách Google pomocí QUERY:

• nemusíte vybírat celý sloupec, jako je tomu u vzorců pro pole.
• nemusíte ve vzorci uvádět jednotlivé sloupce, pokud spolu nesousedí. V takovém případě bude vzorec vypadat takto:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

Spojování a přidávání textu podle pozice

Již víte, že pomocí funkce CONCATENATE můžete do řetězců přidávat chybějící text, čísla a znaky.

Tip. Další vzorce najdete v tomto návodu.

Pokud je však spojovaných záznamů příliš mnoho, mohou jakékoli další znaky prodloužit vzorec mnohem více, než jste plánovali. V takových případech je lepší sloučit buňky v tabulkách Google tak, jak jsou, nebo použít jednoduché oddělovače, například mezeru, a text přidat až poté. Pomůže vám náš speciální nástroj.

Funkce Přidat text podle pozice vkládá libovolné znaky a řetězce podle zadané pozice, není třeba používat žádné vzorce. Ukážu vám, jak to funguje.

V předchozím příkladu se QUERY připojil jména a telefonní čísla pro mě. Ale chtěl bych přidat zkratky zemí: (USA/CA) před telefonními čísly začínajícími na +1 a UK před +44 :

Rozdělení buněk v Tabulkách Google

Pokud v Tabulkách Google spojujete buňky, je pravděpodobné, že je budete muset v určitém okamžiku rozdělit zpět. Existují tři způsoby, jak to udělat:

1. Sestavte vzorec pomocí funkce SPLIT v Tabulce Google.
2. Použijte standardní nástroj tabulkového procesoru - Rozdělte text do sloupců.
3. Nebo vyzkoušejte vylepšenou verzi vestavěného nástroje - Rozdělení textu do sloupců pro Tabulky Google:

Umožňuje rozdělit buňky podle libovolného oddělovače nebo dokonce sady oddělovačů, přičemž je považuje za jeden celek a v případě potřeby zahrnuje spojovníky. Nabízí také možnost rozdělit buňky v tabulkách Google podle pozice.

Tip: Existuje možnost extrahovat data z buněk Tabulky Google, nikoliv rozdělit jejich obsah.

Jak sloučit buňky v tabulkách Google bez vzorců

Pokud není zvládnutí různých vzorců součástí vašeho plánu, využijete náš doplněk Sloučit hodnoty. Doplněk rychle spojí záznamy v řádcích, sloupcích nebo celý rozsah buněk. Jeho možnosti jsou naprosto jasné a jediné, co musíte udělat, je vybrat rozsah a rozhodnout, jak má výsledek vypadat.

1. Můžete si vybrat kombinovat sloupce v tabulkách Google - i nesousedící, oddělte je čárkami a mezerami a výsledek umístěte napravo od původních záznamů:

Pokud vás nástroj zaujal, můžete si vše, co umí, prohlédnout na této speciální stránce nebo v tomto krátkém videonávodu:

V tomto videu se dozvíte, jak používat funkci Kombinovat duplicitní řádky:

Doufám, že už jste se rozhodli, který z uvedených způsobů je pro váš případ nejvhodnější. Pokud máte na mysli jiné metody, podělte se s námi o ně v komentářích níže :)