Нягледзячы на ​​тое, што падлік слоў і сімвалаў у Табліцах Google выкарыстоўваецца ў рэдкіх выпадках, некаторыя з нас па-ранейшаму чакаюць убачыць гэтую функцыю прама ў меню. Але ў адрозненне ад Google Docs, для Google Sheets гэта робіць функцыя LEN.

Нягледзячы на ​​тое, што існуе шмат розных спосабаў падліку сімвалаў у электронных табліцах, у сённяшнім паведамленні ў блогу будзе разгледжана функцыя LEN як яе галоўная мэта табліц - ну, падлічыць :) Аднак, яна амаль не выкарыстоўваецца сама па сабе. Ніжэй вы даведаецеся, як правільна выкарыстоўваць Google Sheets LEN і знойдзеце найбольш запатрабаваныя формулы для вылічэння сімвалаў у электронных табліцах.

Функцыя Google Sheets LEN – выкарыстанне і сінтаксіс

The асноўная і адзіная мэта функцыі LEN у Табліцах Google - атрымаць даўжыню радка. Ён настолькі просты, што нават патрабуе толькі 1 аргумента:

• ён можа браць альбо сам тэкст у двукоссе:

  =LEN("Yggdrasil")

• ці спасылка на ячэйку з цікавым тэкстам:

  =LEN(A2)

Паглядзім, ці ёсць асаблівасці выкарыстання функцыі ў электронных табліцах.

Сімвал падлік у Табліцах Google

Я пачну з самай простай аперацыі: выканайце падлік сімвалаў у Табліцах Google самым звычайным спосабам – спасылаючыся на ячэйку з тэкстам з дапамогай функцыі LEN.

I увядзіце формулу ў B2 і скапіруйце яе па ўсім слупку, каб падлічыць сімвалы ў кожным радку:

=LEN(A2)

Заўвага. Функцыя LENвылічвае ўсе сімвалы: літары, лічбы, прабелы, знакі прыпынку і г.д.

Вы можаце падумаць, што падобным чынам можна зрабіць падлік сімвалаў для ўсяго дыяпазону вочак, напрыклад: LEN(A2:A6) . Але, як Як бы дзіўна гэта ні было, гэта не проста так працуе.

Каб сумаваць сімвалы ў некалькіх ячэйках, вы павінны абгарнуць LEN у SUMPRODUCT – функцыю, якая падлічвае лічбы з уведзеных дыяпазонаў. У маім выпадку дыяпазон вяртаецца функцыяй LEN:

=SUMPRODUCT(LEN(A2:A6))

Вядома, замест гэтага можна ўключыць функцыю SUM. Але SUM у Табліцах Google не апрацоўвае масівы з іншых функцый. Каб прымусіць яго працаваць, вам трэба будзе дадаць яшчэ адну функцыю – ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Як лічыць сімвалы без прабелаў у Google Sheets

Як я адзначыў вышэй, Google Sheets Функцыя LEN падлічвае кожны сімвал, які яна бачыць, уключаючы прабелы.

Але што рабіць, калі памылкова дададзены лішнія прабелы, і вы не жадаеце ўлічваць іх у выніку?

Для такіх выпадкаў, як у Google Табліцах ёсць функцыя TRIM. Ён правярае тэкст на наяўнасць у пачатку, у канцы і паўторных прабелаў паміж імі. Калі TRIM спалучаецца з LEN, апошні не ўлічвае ўсе гэтыя няцотныя прабелы.

Вось прыклад. Я дадаў прабелы ў розных пазіцыях у слупку A. Як бачыце, Google Sheets LEN падлічвае іх усе:

=LEN(A2)

Але як толькі вы інтэгруеце TRIM, усе дадатковыя прасторы ёсцьігнаруецца:

=LEN(TRIM(A2))

Вы можаце пайсці далей і зрабіць так, каб ваша формула не ўлічвала нават гэтыя адзінкавыя прабелы паміж словамі. Функцыя SUBSTITUTE дапаможа. Хаця яго асноўная мэта - замяніць адзін сімвал іншым, ёсць хітрасць, каб прымусіць яго цалкам скараціць прабелы:

• тэкст_для_пошуку гэта дыяпазон, з якім вы працуеце: слупок A, або A2 , калі быць дакладным.
• search_for павінен быць прабелам у падвойных двукоссях: " "
• replace_with павінен утрымліваць пустыя падвойныя двукоссе. Калі вы збіраецеся ігнараваць прабелы, вам трэба замяніць іх літаральна нічым (пусты радок): ""
• number_occurence звычайна выкарыстоўваецца для ўказання асобніка замяняць. Але паколькі я апісваю, як лічыць сімвалы без прабелаў, я прапаную вам апусціць гэты аргумент, бо ён неабавязковы.

Цяпер паспрабуйце сабраць усё гэта ў Google Sheets LEN, і вы ўбачыце, што прабел не ўлічваецца:

=LEN(SUBSTITUTE(A2, " ", ""))

Google Sheets: падлічыць пэўныя сімвалы

Той самы тандэм Google Sheets LEN і SUBSTITUTE выкарыстоўваецца кожны раз, калі вам трэба падлічыць пэўныя сімвалы , літары ці лічбы.

У сваіх прыкладах я збіраюся высветліць колькасць уваходжанняў літары 's'. І на гэты раз я пачну з гатовай формулы:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Давайце разбяром яе на часткі, каб зразумець, якпрацуе:

1. SUBSTITUTE(A2, "s", "") шукае літару 's' у A2 і замяняе ўсе ўваходжанні на "нічога" або пусты радок ( "").
2. LEN(SUBSTITUTE(A2, "s", "") вызначае колькасць усіх сімвалаў, акрамя 's', у A2.
3. LEN(A2) падлічвае ўсе сімвалы ў A2.
4. Нарэшце, вы адымаеце адзін з другога.

Атрыманая розніца паказвае, колькі знакаў ёсць. у ячэйцы:

Заўвага. Вы можаце задацца пытаннем, чаму B1 кажа, што ў A2 ёсць толькі 1 's', а вы бачыце 3?

Справа ў тым, што функцыя SUBSTITUTE адчувальная да рэгістра. Я папрасіў яго прымаць усе выпадкі 's' у ніжнім рэгістры, і так яно і было.

Каб прымусіць яго ігнараваць рэгістр тэксту і апрацоўваць літары як у ніжнім, так і ў верхнім рэгістры, вам трэба будзе выклікаць яшчэ адну функцыю Google Sheets для дапамогі: LOWER.

Парада. Глядзіце іншыя спосабы змены рэгістра тэксту ў Google Sheets.

Гэта так жа проста, як Google Sheets LEN і TRIM, таму што для гэтага патрабуецца толькі тэкст:

=LOWER(text)

І ўсё, што ён робіць, гэта ператварае ўвесь тэкставы радок у o малой літары. Гэты трук - менавіта тое, што вам трэба, каб прымусіць Табліцы Google лічыць пэўныя сімвалы незалежна ад рэгістра тэксту:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

Парада. І, як і раней, каб падлічыць агульную колькасць пэўных сімвалаў у дыяпазоне, абгарніце ваш LEN у SUMPRODUCT:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Палічыце словы ў Google Sheets

Калі ёсць некалькі слоў у ячэйках, хутчэй за ўсё, вам спатрэбіцца іх колькасць замест гэтагадаўжыня радка Табліц Google.

І хаця ёсць некалькі спосабаў зрабіць гэта, сёння я згадаю, як Google Табліцы LEN выконваюць гэтую працу.

Памятайце формулу, якую я выкарыстаў для падліку пэўных сімвалаў у Табліцы Google? Уласна, і тут ён спатрэбіцца. Таму што я не буду літаральна лічыць словы. Замест гэтага я палічу колькасць прабелаў паміж словамі, а затым проста дадам 1. Паглядзіце:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) падлічвае колькасць усіх сімвалаў у ячэйцы.
2. LEN(SUBSTITUTE((A2)," ","")) выдаляе ўсе прабелы з тэкставага радка і падлічвае пакінутыя сімвалы.
3. Потым вы адымаеце адно ад другога, і розніца, якую вы атрымаеце, - гэта колькасць прабелаў у ячэйцы.
4. Паколькі слоў заўсёды больш прабелаў у сказе на адзін, вы дадаеце 1 у канцы.

Табліцы Google: падлік пэўных слоў

Нарэшце, я хацеў бы падзяліцца формулай Табліц Google, якую можна выкарыстоўваць для падліку пэўных слоў.

Вось у мяне песня "Песня фальшывай чарапахі" з фільма "Прыгоды Алісы ў краіне цудаў":

Я хачу ведаць, колькі разоў слова "будзе" сустракаецца ў кожным радку. Мяркую, вы не здзівіцеся, калі скажу, што патрэбная мне формула складаецца з тых жа функцый, што і раней: Google Sheets LEN, SUBSTITUTE і LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

Формула можа выглядае страшна, але я магу вас запэўніць, што гэта лёгка зразумець, так што цярпіце мяне :)

1. Паколькі рэгістр тэксту неважна для мяне, я выкарыстоўваю LOWER(A2) , каб перавесці ўсё ў малы рэгістр.
2. Потым ідзе SUBSTITUTE(LOWER(A2), "будзе",""))) – ён пазбаўляецца ад усіх уваходжанняў 'will', замяняючы іх пустымі радкамі ("").
3. Пасля гэтага я адымаю колькасць сімвалаў без слова 'will' з агульнай даўжыні радка . Лік, які я атрымліваю, улічвае ўсе сімвалы ва ўсіх уваходжаннях слова "will" у кожным радку.

   Такім чынам, калі 'will' з'яўляецца адзін раз, лік роўны 4, паколькі ў слове 4 літары. Калі ён з'яўляецца двойчы, лічба роўная 8 і гэтак далей.

4. Нарэшце, я дзялю гэтую лічбу на даўжыню аднаго слова "буду".

Савет. І зноў жа, калі вы жадаеце атрымаць агульную колькасць усіх з'яўленняў слова "будзе", проста ўключыце ўсю формулу ў SUMPRODUCT:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

Як бачыце , усе гэтыя выпадкі падліку сімвалаў вырашаюцца аднымі і тымі ж шаблонамі тых жа функцый для Табліц Google: LEN, SUBSTITUTE, LOWER і SUMPRODUCT.

Калі некаторыя формулы ўсё яшчэ бянтэжаць вас, або калі вы не ведаеце, як прымяніць усё да вашай канкрэтнай задачы, не саромейцеся і пытайцеся ў раздзеле каментарыяў ніжэй!