Працуючы над справаздачай, інвестыцыйным планам або любым іншым наборам даных з датамі, вам часта можа спатрэбіцца сумаваць лічбы за пэўны перыяд. Гэты падручнік навучыць вас хуткаму і простаму рашэнню - формуле SUMIFS з дыяпазонам дат у якасці крытэрыяў.

У нашым блогу і на іншых форумах Excel людзі часта пытаюцца, як выкарыстоўваць SUMIF для дыяпазону дат. Справа ў тым, што для сумавання дзвюх дат вам трэба вызначыць абедзве даты, у той час як функцыя SUMIF у Excel дазваляе толькі адну ўмову. На шчасце, у нас таксама ёсць функцыя SUMIFS, якая падтрымлівае некалькі крытэрыяў.

Як сумаваць паміж дзвюма датамі ў Excel

Каб сумаваць значэнні ў пэўным дыяпазоне дат, выкарыстоўвайце формула SUMIFS з датамі пачатку і заканчэння ў якасці крытэрыяў. Сінтаксіс функцыі SUMIFS патрабуе, каб вы спачатку ўказалі значэнні для сумавання (сум_дыяпазон), а потым указалі пары дыяпазон/крытэрый. У нашым выпадку дыяпазон (спіс дат) будзе аднолькавым для абодвух крытэрыяў.

Улічваючы вышэйсказанае, агульныя формулы для сумавання значэнняў паміж дзвюма датамі прымаюць наступны выгляд:

У тым ліку парогавыя даты:

За выключэннем парогавых дат:

Як бачыце, розніца толькі ў лагічных аператарах. У першай формуле мы выкарыстоўваем большчым або роўна (>=) і менш або роўна (<=), каб уключыць парогавыя даты ў вынік. Другая формула правярае, ці з'яўляецца дата большай за (>) або меншай за (<), пакідаючы даты пачатку і канца.

У у табліцы ніжэй, выкажам здагадку, што вы хочаце сумаваць праекты, якія павінны быць выкананы ў пэўны дыяпазон дат уключна. Каб зрабіць гэта, выкарыстоўвайце наступную формулу:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Калі вы не жадаеце жорстка закадаваць дыяпазон дат у формулу, вы можаце ўвесці дату пачатку ў F1, дату заканчэння ў G1, аб'яднайце лагічныя аператары і спасылкі на ячэйкі і заключыце ўвесь крытэрый у двукоссе, як гэта:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Каб пазбегнуць магчымых памылак, вы можаце падаць даты з дапамогай функцыі DATE:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))

Сума ў дынамічным дыяпазоне на аснове сённяшняй даты

У сітуацыі, калі вам трэба прасумаваць даныя ў дынамічным дыяпазоне дат (X дзён назад ад сённяшняга дня або Y дзён наперад), пабудуйце крытэрыі з дапамогай функцыі СЁННЯ, якая атрымае бягучую дату і абновіць яе аўтаматычна.

Напрыклад, каб падсумаваць бюджэты, якія павінны быць выкананы за апошні 7 дзён уключаючы сённяшнюю дату , формула:

=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)

Калі вы не хочаце ўключаць бягучую дату ў канчатковы вынік, выкарыстоўвайце менш за аператар (<) для першага крытэрыю для выключэння сённяшняй даты і больш або роўна (>=) для другога крытэрыюуключыце дату, якая за 7 дзён да сённяшняй:

=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)

Аналагічным чынам вы можаце сумаваць значэнні, калі дата складае зададзеную колькасць дзён наперад.

Напрыклад, каб атрымаць агульную суму бюджэтаў, якія павінны быць выкананы ў наступныя 3 дні, выкарыстоўвайце адну з наступных формул:

Сённяшняя дата ўключаецца ў вынік:

=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)

Сённяшняя дата не ўваходзіць у вынік:

=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)

Сума паміж дзвюма датамі і іншым крытэрыем

Каб сумаваць значэнні ў дыяпазоне дат, якія адпавядаюць іншым умовам у іншым слупку, проста дадайце яшчэ адну пару дыяпазон/крытэрый у вашу формулу SUMIFS.

Напрыклад, каб сумаваць бюджэты ў межах пэўнага дыяпазон дат для ўсіх праектаў, якія ўтрымліваюць «падказку» ў сваіх назвах, пашырыце формулу крытэрамі падстаноўкі:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")

Дзе A2:A10 — гэта назвы праектаў, B2:B10 — лічбы для сумавання, C2:C10 - даты для праверкі, F1 - дата пачатку і G1 - дата заканчэння.

Вядома, нішто не перашкаджае вам увесці трэці крытэрый у sepa ацэнка ячэйкі таксама і спасылка на гэтую ячэйку, як паказана на скрыншоце:

Сінтаксіс крытэрыяў даты SUMIFS

Калі справа даходзіць да выкарыстання дат у якасці крытэрыяў для Excel SUMIF і SUMIFS, вы не першы, хто заблытаўся :)

Аднак пры больш уважлівым разглядзе ўся разнастайнасць варыянтаў выкарыстання зводзіцца да некалькіх простых правіл:

Калі вы паставіце даты непасрэдна ў крытэрыіarguments , затым увядзіце лагічны аператар (>, <, =, ) непасрэдна перад датай і заключыце ўвесь крытэрый у двукоссе. Напрыклад:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Калі дата ўводзіцца ў прадвызначаную ячэйку , укажыце ўмовы ў выглядзе тэкставага радка: заключыце лагічны аператар у двукоссе, каб пачаць радок і выкарыстоўваць амперсанд (&), каб аб'яднаць і скончыць радок. Напрыклад:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Калі дата кіруецца іншай функцыяй , такой як ДАТА або СЁННЯ(), аб'яднайце аператар параўнання і функцыю. Напрыклад:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())

Excel SUMIFS паміж датамі не працуе

Калі ваша формула не працуе або дае няправільныя вынікі, наступныя парады па ліквідацыі непаладак могуць праліць святло на тое, чаму гэта не атрымліваецца і дапаможа вам вырашыць праблему.

Праверце фармат дат і лікаў

Калі, здавалася б, правільная формула SUMIFS не вяртае нічога, акрамя нуля, першае, што трэба праверыць, гэта тое, што вашы даты сапраўды з'яўляюцца датамі , а не тэкставыя радкі, якія выглядаюць толькі як даты. Затым пераканайцеся, што вы сумуеце лічбы, а не лічбы, захаваныя ў выглядзе тэксту. Наступныя падручнікі дапамогуць вам выявіць і выправіць гэтыя праблемы.

• Як змяніць "тэкставыя даты" на рэальныя даты
• Як пераўтварыць тэкст у лік

Выкарыстоўвайце правільны сінтаксіс для крытэрыяў

Пры праверцы дат з дапамогай SUMIFS дату трэба ставіць у двукоссе, напрыклад ">=9/10/2020"; спасылкі на вочкі іфункцыі павінны размяшчацца па-за двукоссямі, напрыклад, "<="&G1 або "<="&TODAY(). Для атрымання поўнай інфармацыі, калі ласка, глядзіце сінтаксіс крытэраў даты.

Праверце логіку формулы

Невялікая памылка друку ў бюджэце можа каштаваць мільёны. Невялікая памылка ў формуле можа каштаваць гадзін часу на адладку. Такім чынам, пры сумаванні паміж 2 датамі праверце, ці не папярэднічае даце пачатку аператар больш за (>) або больш або роўна (>=) і канец дата мае прэфікс менш за (<) або менш або роўна (<=).

Упэўніцеся, што ўсе дыяпазоны аднолькавага памеру

Каб функцыя SUMIFS працавала карэктна, дыяпазон сумы і дыяпазон крытэрыяў павінны быць аднолькавага памеру, у адваротным выпадку #VALUE! адбываецца памылка. Каб выправіць гэта, пераканайцеся, што ўсе аргументы criteria_range маюць такую ​​ж колькасць радкоў і слупкоў, што і sum_range .

Вось як выкарыстоўваць функцыю Excel SUMIFS для сумавання даных у дыяпазон дат. Калі ў вас ёсць на ўвазе іншыя цікавыя рашэнні, я буду вельмі ўдзячны, калі вы падзяліцеся імі ў каментарах. Дзякуй за чытанне і спадзяемся ўбачыць вас у нашым блогу на наступным тыдні!

Практычны сшытак для спампоўкі

Прыклады дыяпазону дат SUMIFS (файл .xlsx)