Hướng dẫn chỉ ra cách kết hợp hàm V LOOKUP và IF với nhau để tra cứu v với điều kiện if trong Excel. Bạn cũng sẽ tìm hiểu cách sử dụng các công thức IF ISNA VLOOKUP để thay thế lỗi #N/A bằng văn bản, số 0 hoặc ô trống của riêng bạn.

Mặc dù các hàm VLOOKUP và IF đều hữu ích khi hoạt động cùng nhau họ thậm chí còn cung cấp nhiều kinh nghiệm quý giá hơn. Hướng dẫn này ngụ ý rằng bạn phải nhớ kỹ cú pháp của hai hàm, nếu không, bạn có thể muốn trau dồi kiến ​​thức của mình bằng cách nhấp vào các liên kết ở trên.

Vlookup với câu lệnh If: return True/ Sai, Có/Không, v.v.

Một trong những tình huống phổ biến nhất khi bạn kết hợp If và Vlookup với nhau là so sánh giá trị do Vlookup trả về với giá trị mẫu và trả về Có / Không hoặc kết quả là True / False .

Trong hầu hết các trường hợp, công thức chung sau sẽ hoạt động tốt:

Được dịch bằng tiếng Anh đơn giản, công thức hướng dẫn Excel trả về True nếu Vlookup là đúng (nghĩa là bằng giá trị đã chỉ định). Nếu Vlookup sai (không bằng giá trị đã chỉ định), công thức sẽ trả về Sai .

Dưới đây, bạn sẽ tìm thấy một số cách sử dụng thực tế của công thức IF Vlookup này.

Ví dụ 1. Tra cứu một giá trị cụ thể

Giả sử bạn có danh sách các mặt hàng ở cột A và số lượng ở cột B. Bạn đang tạo trang tổng quan cho người dùng của mình và cần một công thứcsẽ kiểm tra số lượng của một mặt hàng trong E1 và thông báo cho người dùng biết mặt hàng đó còn hàng hay đã bán hết.

Bạn lấy số lượng bằng Vlookup thông thường với công thức đối sánh chính xác như sau:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Sau đó, viết câu lệnh IF so sánh kết quả của Vlookup với 0 và trả về "No" nếu nó bằng 0, "Yes" nếu ngược lại:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

Thay vì Có/Không , bạn có thể trả về TRUE/FALSE hoặc Còn hàng/Đã bán hoặc hai trường hợp khác sự lựa chọn. Ví dụ:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

Bạn cũng có thể so sánh giá trị do Vlookup trả về với văn bản mẫu . Trong trường hợp này, hãy nhớ đặt chuỗi văn bản trong dấu ngoặc kép, như sau:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

Ví dụ 2. So sánh kết quả Vlookup với ô khác

Một ví dụ điển hình khác về Vlookup với điều kiện If trong Excel đang so sánh đầu ra của Vlookup với một giá trị trong một ô khác. Ví dụ: chúng ta có thể kiểm tra xem nó có lớn hơn hoặc bằng một số trong ô G2 hay không:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

Và đây là công thức If của chúng ta với Vlookup đang hoạt động:

Theo cách tương tự, bạn có thể sử dụng bất kỳ toán tử logic nào khác cùng với tham chiếu ô trong công thức If Vlookup của Excel.

Ví dụ 3. Giá trị Vlookup trong danh sách ngắn hơn

Để so sánh từng ô trong cột mục tiêu với một danh sách khác và trả về Đúng hoặc Có nếu tìm thấy kết quả khớp, Sai hoặc Không nếu không, hãy sử dụng công thức chung IF ISNA VLOOKUP này:

Nếu Vlookup dẫn đến lỗi #N/A, công thức sẽ trả về "No", nghĩa là không tìm thấy giá trị tra cứu trong danh sách tra cứu. Nếu tìm thấy kết quả phù hợp, "Có" được trả về. Ví dụ:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

Nếu logic kinh doanh của bạn yêu cầu kết quả ngược lại, chỉ cần hoán đổi "Có" và "Không" để đảo ngược logic của công thức:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Công thức Excel If Vlookup để thực hiện các phép tính khác nhau

Bên cạnh việc hiển thị tin nhắn văn bản của riêng bạn, hàm If với Vlookup có thể thực hiện các phép tính khác nhau dựa trên các tiêu chí bạn chỉ định.

Xét thêm ví dụ của chúng tôi, hãy tính toán hoa hồng của một người bán cụ thể (F1) tùy thuộc vào hiệu quả của họ: 20% hoa hồng cho những người kiếm được 200 đô la trở lên, 10% cho những người khác .

Đối với điều này, bạn kiểm tra xem giá trị do Vlookup trả về có lớn hơn hoặc bằng 200 hay không và nếu có, hãy nhân giá trị đó với 20%, nếu không thì nhân với 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Trong đó A2:A10 là tên người bán và C2:C10 là doanh số.

NẾU ISNA VLOOKUP để ẩn lỗi #N/A

Nếu hàm VLOOKUP không thể tìm thấy một giá trị đã chỉ định, nó sẽ đưa ra lỗi #N/A. Để phát hiện lỗi đó và thay thế nó bằng văn bản của riêng bạn, hãy nhúng công thức Vlookup vào kiểm tra logic của hàm IF, như sau:

Đương nhiên, bạn có thể nhập bất kỳ văn bản nào bạn thích thay vì "Không tìm thấy".

Giả sử, bạn có một danh sách người bántên trong một cột và số tiền bán hàng trong một cột khác. Nhiệm vụ của bạn là kéo một số tương ứng với tên người dùng nhập vào F1. Nếu không tìm thấy tên, hãy hiển thị thông báo cho biết như vậy.

Với các tên trong A2:A10 và số tiền C2:C10, tác vụ có thể được hoàn thành với công thức If Vlookup sau:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

Nếu tìm thấy tên, số tiền bán hàng tương ứng sẽ được trả về:

Nếu không tìm thấy giá trị tra cứu, Không tìm thấy thông báo xuất hiện thay vì lỗi #N/A:

Cách thức hoạt động của công thức này

Logic của công thức rất đơn giản: bạn sử dụng hàm ISNA để kiểm tra lỗi #N/A của Vlookup. Nếu xảy ra lỗi, ISNA trả về TRUE, nếu không thì FALSE. Các giá trị trên được chuyển đến kiểm tra logic của hàm IF, thực hiện một trong các thao tác sau:

• Nếu kiểm tra logic là TRUE (lỗi #N/A), thông báo của bạn sẽ được hiển thị.
• Nếu kiểm tra logic là SAI (tìm thấy giá trị tra cứu), Vlookup trả về kết quả khớp bình thường.

IFNA VLOOKUP trong các phiên bản Excel mới hơn

Bắt đầu với Excel 2013, bạn có thể sử dụng hàm IFNA thay vì IF ISNA để nắm bắt và xử lý lỗi #N/A:

Trong ví dụ của chúng tôi, công thức sẽ có hình dạng sau:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

Mẹo. Nếu bạn muốn loại bỏ tất cả các loại lỗi, không chỉ lỗi #N/A, hãy sử dụng VLOOKUP kết hợp với hàm IFERROR. Thông tin chi tiết có thể được tìm thấy ở đây: IFERRORVLOOKUP trong Excel.

Vlookup Excel: nếu không tìm thấy trả về 0

Khi làm việc với các giá trị số, bạn có thể muốn trả về số 0 khi không tìm thấy giá trị tra cứu. Để hoàn thành, hãy sử dụng công thức IF ISNA VLOOKUP đã thảo luận ở trên với một chút sửa đổi: thay vì tin nhắn văn bản, hãy cung cấp 0 trong đối số value_if_true của hàm IF:

Trong bảng mẫu của chúng tôi, công thức sẽ như sau:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Trong phiên bản gần đây của Excel 2016 và 2013, bạn có thể sử dụng lại tổ hợp IFNA Vlookup:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: nếu không tìm thấy trả về ô trống

Đây là một biến thể khác của câu lệnh "Vlookup if then": không trả về gì khi không tìm thấy giá trị tra cứu. Để thực hiện việc này, hãy hướng dẫn công thức của bạn trả về một chuỗi trống ("") thay vì lỗi #N/A:

Below là một vài ví dụ về công thức hoàn chỉnh:

Đối với tất cả các phiên bản Excel:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Đối với Excel 2016 và Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

Nếu có Khớp chỉ mục - vlookup bên trái với điều kiện Nếu

Người dùng Excel có kinh nghiệm biết rằng hàm VLOOKUP không phải là cách duy nhất để thực hiện tra cứu theo chiều dọc trong Excel. Tổ hợp INDEX MATCH cũng có thể được sử dụng cho mục đích này và nó thậm chí còn mạnh mẽ và linh hoạt hơn. Tin vui là Kết hợp chỉ mục có thể hoạt động cùng với IF theo cách chính xác nhưVlookup.

Ví dụ: bạn có số đơn hàng ở cột A và tên người bán ở cột B. Bạn đang tìm công thức để lấy số đơn hàng cho một người bán cụ thể.

Vlookup không thể được sử dụng trong trường hợp này vì nó không thể tìm kiếm từ phải sang trái. Kết hợp chỉ mục sẽ hoạt động mà không gặp trở ngại nào miễn là giá trị tra cứu được tìm thấy trong cột tra cứu. Nếu không, lỗi #N/A sẽ hiển thị. Để thay thế ký hiệu lỗi tiêu chuẩn bằng văn bản của riêng bạn, hãy lồng Khớp chỉ mục bên trong IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Trong Excel 2016 và 2016, bạn có thể sử dụng IFNA thay vì IF ISNA để tạo công thức hiệu quả hơn rút gọn:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

Theo cách tương tự, bạn có thể sử dụng Kết hợp chỉ mục trong các công thức If khác.

Đây là cách bạn sử dụng Câu lệnh Vlookup và IF cùng nhau trong Excel. Để xem kỹ hơn các công thức được thảo luận trong hướng dẫn này, bạn có thể tải xuống sổ làm việc mẫu của chúng tôi bên dưới. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!

Sách bài tập thực hành để tải xuống

Excel IF Vlookup - ví dụ về công thức (tệp .xlsx)