Tutorial ini menunjukkan cara mengombinasikan V LOOKUP dan IF berfungsi bersama untuk v-lookup dengan kondisi if di Excel. Anda juga akan mempelajari cara menggunakan rumus IF ISNA VLOOKUP untuk mengganti kesalahan # N / A dengan teks, nol, atau sel kosong Anda sendiri.

Meskipun fungsi VLOOKUP dan IF berguna sendiri-sendiri, bersama-sama mereka memberikan pengalaman yang lebih berharga. Tutorial ini menyiratkan bahwa Anda mengingat sintaks dari dua fungsi dengan baik, jika tidak, Anda mungkin ingin memoles pengetahuan Anda dengan mengikuti tautan di atas.

Vlookup dengan pernyataan If: mengembalikan Benar / Salah, Ya / Tidak, dll.

Salah satu skenario paling umum ketika Anda menggabungkan If dan Vlookup bersama-sama adalah membandingkan nilai yang dikembalikan oleh Vlookup dengan nilai sampel dan mengembalikannya Ya / Tidak atau Benar / Salah sebagai hasilnya.

Dalam sebagian besar kasus, rumus umum berikut ini akan bekerja dengan baik:

Diterjemahkan dalam bahasa Inggris sederhana, rumus menginstruksikan Excel untuk mengembalikan Benar jika Vlookup benar (yaitu sama dengan nilai yang ditentukan). Jika Vlookup salah (tidak sama dengan nilai yang ditentukan), rumus mengembalikan Salah .

Di bawah ini Anda akan menemukan beberapa penggunaan kehidupan nyata dari rumus IF Vlookup ini.

Contoh 1. Mencari nilai tertentu

Katakanlah, Anda memiliki daftar item di kolom A dan kuantitas di kolom B. Anda membuat dasbor untuk pengguna Anda dan memerlukan rumus yang akan memeriksa kuantitas untuk item di E1 dan memberi tahu pengguna apakah item tersebut tersedia atau terjual habis.

Anda menarik kuantitas dengan Vlookup biasa dengan rumus pencocokan tepat seperti ini:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Kemudian, tulis pernyataan IF yang membandingkan hasil Vlookup dengan nol, dan mengembalikan "Tidak" jika sama dengan 0, "Ya" jika tidak:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0, "Tidak", "Ya")

Bukannya Ya/Tidak , Anda dapat mengembalikan BENAR/SALAH atau Stok Tersedia / Habis Terjual atau dua pilihan lainnya. Misalnya:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0, "Habis terjual", "Tersedia")

Anda juga dapat membandingkan nilai yang dikembalikan oleh Vlookup dengan sampel teks Dalam kasus ini, pastikan untuk mengapit string teks dalam tanda kutip, seperti ini:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="contoh teks",TRUE,FALSE)

Contoh 2. Bandingkan hasil Vlookup dengan sel lain

Contoh tipikal lain dari Vlookup dengan kondisi If di Excel adalah membandingkan keluaran Vlookup dengan nilai di sel lain. Misalnya, kita dapat memeriksa apakah lebih besar dari atau sama dengan angka di sel G2:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2, "Ya!", "Tidak")

Dan inilah rumus If kita dengan Vlookup dalam aksi:

Dengan cara yang sama, Anda dapat menggunakan operator logika lainnya bersama dengan referensi sel di Excel Anda Jika rumus Vlookup.

Contoh 3. Nilai Vlookup dalam daftar yang lebih pendek

Untuk membandingkan setiap sel di kolom target dengan daftar lain dan mengembalikannya Benar atau Ya jika ditemukan kecocokan, Salah atau Tidak jika tidak, gunakan rumus IF ISNA VLOOKUP generik ini:

Jika Vlookup menghasilkan kesalahan # N / A, rumus mengembalikan "Tidak", yang berarti nilai pencarian tidak ditemukan dalam daftar pencarian. Jika kecocokan ditemukan, "Ya" dikembalikan. Misalnya:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)), "Tidak", "Ya")

Jika logika bisnis Anda membutuhkan hasil yang berlawanan, cukup tukar "Yes" dan "No" untuk membalikkan logika rumus:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)), "Ya", "Tidak")

Excel Jika rumus Vlookup untuk melakukan perhitungan yang berbeda

Selain menampilkan pesan teks Anda sendiri, fungsi If dengan Vlookup dapat melakukan perhitungan yang berbeda berdasarkan kriteria yang Anda tentukan.

Mengambil contoh kita lebih jauh, mari kita hitung komisi penjual tertentu (F1) tergantung pada keefektifan mereka: komisi 20% untuk mereka yang menghasilkan $200 dan lebih, 10% untuk orang lain.

Untuk ini, Anda memeriksa apakah nilai yang dikembalikan oleh Vlookup lebih besar dari atau sama dengan 200, dan jika ya, kalikan dengan 20%, jika tidak dengan 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE)>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Di mana A2:A10 adalah nama penjual dan C2:C10 adalah penjualan.

JIKA ISNA VLOOKUP untuk menyembunyikan kesalahan #N/A

Jika fungsi VLOOKUP tidak dapat menemukan nilai yang ditentukan, ia melempar kesalahan #N/A. Untuk menangkap kesalahan itu dan menggantinya dengan teks Anda sendiri, sematkan rumus Vlookup dalam tes logis fungsi IF, seperti ini:

Tentu saja, Anda bisa mengetikkan teks apa pun yang Anda sukai, bukan "Not found" (Tidak ditemukan).

Misalkan, Anda memiliki daftar nama penjual di satu kolom dan jumlah penjualan di kolom lain. Tugas Anda adalah menarik angka yang sesuai dengan nama yang dimasukkan pengguna di F1. Jika nama tidak ditemukan, tampilkan pesan yang menunjukkan demikian.

Dengan nama-nama di A2: A10 dan jumlah C2: C10, tugas tersebut dapat dipenuhi dengan rumus If Vlookup berikut:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Tidak ditemukan", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

Jika nama ditemukan, jumlah penjualan yang sesuai akan dikembalikan:

Jika nilai pencarian tidak ditemukan, maka Tidak ditemukan muncul alih-alih kesalahan #N/A:

Bagaimana formula ini bekerja

Logika rumus ini sangat sederhana: Anda menggunakan fungsi ISNA untuk memeriksa Vlookup untuk kesalahan # N / A. Jika terjadi kesalahan, ISNA mengembalikan TRUE, jika tidak, FALSE. Nilai-nilai di atas masuk ke tes logis fungsi IF, yang melakukan salah satu dari yang berikut ini:

• Jika tes logika adalah TRUE (kesalahan #N/A), pesan Anda akan ditampilkan.
• Jika tes logis adalah FALSE (nilai pencarian ditemukan), Vlookup mengembalikan kecocokan secara normal.

IFNA VLOOKUP dalam versi Excel yang lebih baru

Dimulai dengan Excel 2013, Anda dapat menggunakan fungsi IFNA alih-alih IF ISNA untuk menangkap dan menangani kesalahan # N / A:

Dalam contoh kita, rumusnya akan berbentuk seperti berikut ini:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Tidak ditemukan")

Tip. Jika Anda ingin menjebak semua jenis kesalahan, tidak hanya # N / A, gunakan VLOOKUP yang dikombinasikan dengan fungsi IFERROR. Rincian lebih lanjut dapat ditemukan di sini: IFERROR VLOOKUP di Excel.

Excel Vlookup: jika tidak ditemukan kembali 0

Ketika bekerja dengan nilai numerik, Anda mungkin ingin mengembalikan nilai nol ketika nilai pencarian tidak ditemukan. Untuk melakukannya, gunakan rumus IF ISNA VLOOKUP yang dibahas di atas dengan sedikit modifikasi: alih-alih pesan teks, berikan 0 di dalam value_if_true argumen dari fungsi IF:

Dalam tabel contoh kita, rumusnya akan menjadi seperti berikut ini:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Di versi terbaru Excel 2016 dan 2013, Anda dapat menggunakan kombinasi IFNA Vlookup lagi:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: jika tidak ditemukan mengembalikan sel kosong

Ini adalah satu variasi lagi dari pernyataan "Vlookup if then": tidak mengembalikan apa pun saat nilai pencarian tidak ditemukan. Untuk melakukan ini, instruksikan rumus Anda untuk mengembalikan string kosong ("") alih-alih kesalahan # N / A:

Di bawah ini adalah beberapa contoh rumus lengkap:

Untuk semua versi Excel:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Untuk Excel 2016 dan Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

Jika dengan Index Match - vlookup kiri dengan kondisi If

Pengguna Excel yang berpengalaman tahu bahwa fungsi VLOOKUP bukan satu-satunya cara untuk melakukan pencarian vertikal di Excel. Kombinasi INDEX MATCH juga dapat digunakan untuk tujuan ini dan bahkan lebih kuat dan serbaguna. Kabar baiknya adalah Index Match dapat bekerja sama dengan IF dengan cara yang persis sama seperti Vlookup.

Misalnya, Anda memiliki nomor pesanan di kolom A dan nama penjual di kolom B. Anda mencari rumus untuk menarik nomor pesanan untuk penjual tertentu.

Vlookup tidak dapat digunakan dalam kasus ini karena tidak dapat mencari dari kanan ke kiri. Index Match akan bekerja tanpa hambatan selama nilai pencarian ditemukan di kolom pencarian. Jika tidak, kesalahan #N/A akan muncul. Untuk mengganti notasi kesalahan standar dengan teks Anda sendiri, sarangkan Index Match di dalam IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Tidak ditemukan", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))))

Di Excel 2016 dan 2016, Anda dapat menggunakan IFNA alih-alih IF ISNA untuk membuat rumus lebih ringkas:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Tidak ditemukan")

Dengan cara yang sama, Anda dapat menggunakan Pencocokan Indeks dalam rumus If lainnya.

Ini adalah bagaimana Anda menggunakan pernyataan Vlookup dan IF bersama-sama di Excel. Untuk melihat lebih dekat rumus yang dibahas dalam tutorial ini, Anda dipersilakan untuk mengunduh buku kerja sampel kami di bawah ini. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Buku kerja latihan untuk diunduh

Excel IF Vlookup - contoh rumus (file .xlsx)