Заавар нь Excel-ийн if нөхцөлтэй V-хайлгахын тулд V LOOKUP болон IF функцийг хэрхэн хослуулахыг харуулсан. Та мөн IF ISNA VLOOKUP томьёог ашиглан #Үгүй алдааг өөрийн текст, тэг эсвэл хоосон нүдээр солих талаар сурах болно.

Хэдийгээр VLOOKUP болон IF функцүүд нь хамтдаа ашигтай байдаг. тэд илүү үнэ цэнэтэй туршлагыг хүргэдэг. Энэ заавар нь та хоёр функцийн синтаксийг сайн санаж байх ёстой гэсэн үг бөгөөд үгүй ​​бол дээрх холбоосыг дагаж мэдлэгээ сайжруулахыг хүсэж болох юм.

If хэллэгээр дахин харах: True буцах/ Худал, Тийм/Үгүй гэх мэт.

Хэрэв болон Vlookup-г хамтад нь нэгтгэх үед тохиолддог хамгийн түгээмэл хувилбаруудын нэг бол Vlookup-аас буцаасан утгыг жишээ утгатай харьцуулж Тийм / Үгүй буцаана. эсвэл үр дүнд нь Үнэн / Худал .

Ихэнх тохиолдолд дараах ерөнхий томьёо сайн ажиллана:

Энгийн англи хэлээр орчуулсан томьёо нь хэрэв Vlookup үнэн (өөрөөр хэлбэл заасан утгатай тэнцүү) бол Үнэн буцаахыг Excel-д заадаг. Хэрэв Vlookup нь худал бол (заасан утгатай тэнцүү биш) томъёо нь Худал -г буцаана.

Доор та энэ IF Vlookup томьёоны бодит амьдрал дээрх цөөн хэдэн хэрэглээг олж харах болно.

Жишээ 1. Тодорхой утгыг хай

Танд А баганад байгаа зүйлсийн жагсаалт, В баганад тоо байна гэж бодъё. Та хэрэглэгчиддээ хяналтын самбар үүсгэж байгаа бөгөөд томьёо хэрэгтэй байна.Энэ нь E1 дэх барааны тоо хэмжээг шалгаж, тухайн зүйл нь нөөцөд байгаа эсвэл зарагдсан эсэхийг хэрэглэгчдэд мэдээлэх болно.

Та тоо хэмжээг яг таарах томъёогоор энгийн Vlookup ашиглан авна уу:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Дараа нь Vlookup-ийн үр дүнг тэгтэй харьцуулсан IF командыг бичээд 0-тэй тэнцүү бол "Үгүй", үгүй ​​бол "Тийм" гэж буцаана:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

Тийм/Үгүй -ийн оронд та ҮНЭН/ХУДАЛ эсвэл Нөөцөд байгаа/Борагдсан эсвэл өөр хоёрыг буцааж болно. сонголтууд. Жишээ нь:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

Та Vlookup-аас буцаасан утгыг дээж текст -тай харьцуулж болно. Энэ тохиолдолд текстийн мөрийг хашилтанд оруулахаа мартуузай:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

Жишээ 2. Vlookup үр дүнг өөр нүдтэй харьцуулах

Өөр нэг ердийн жишээ Excel-ийн If нөхцөлтэй Vlookup нь Vlookup гаралтыг өөр нүдн дэх утгатай харьцуулж байна. Жишээлбэл, бид G2 нүдэн дэх тооноос их эсвэл тэнцүү эсэхийг шалгаж болно:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

Мөн энд Vlookup ажиллаж байгаа If томьёо энд байна:

Үүнтэй адилаар та Excel If Vlookup томьёоны нүдний лавлагааны хамт өөр дурын логик операторыг ашиглаж болно.

Жишээ 3. Богино жагсаалт дахь Vlookup утгууд

Зорилтот баганын нүд бүрийг өөр жагсаалттай харьцуулж, тохирох зүйл олдвол Үнэн эсвэл Тийм гэж буцаахын тулд Худал эсвэл Үгүй< эс бөгөөс энэ ерөнхий IF ISNA VLOOKUP томъёог ашиглана уу:

Хэрэв Vlookup-ийн үр дүнд #N/A алдаа гарвал томьёо нь "Үгүй" гэсэн утгатай бөгөөд хайлтын жагсаалтаас хайлтын утга олдохгүй байна. Хэрэв тохирол олдвол "Тийм" гэж буцаана. Жишээ нь:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

Хэрэв таны бизнесийн логик эсрэг үр дүн шаардлагатай бол томьёоны логикийг өөрчлөхийн тулд "Тийм" ба "Үгүй"-г солиход л болно:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel If Vlookup томъёо нь өөр тооцоолол хийх

Өөрийн текст мессежийг харуулахаас гадна Vlookup-тэй If функц нь өөр өөр тооцоолол хийх боломжтой. таны тодорхойлсон шалгуурт тулгуурлан.

Бидний жишээг цааш нь авч үзвэл, тодорхой худалдагчийн хураамжийг (F1) үр дүнгээс нь хамааруулан тооцъё: 200 доллар ба түүнээс дээш орлого олсон хүмүүст 20%, бусад бүх хүмүүст 10%. .

Үүний тулд та Vlookup-ын буцаасан утга 200-аас их эсвэл тэнцүү эсэхийг шалгах ба хэрэв байгаа бол 20%-иар, үгүй ​​бол 10%-иар үржүүлнэ:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

А2:А10 нь худалдагчийн нэр, С2:С10 нь борлуулалт гэсэн үг.

ХЭРэв ISNA VLOOKUP нь #Үгүй алдааг нуухын тулд

Хэрэв VLOOKUP функц нь заасан утгыг олж чадахгүй бол #N/A алдаа гаргадаг. Энэ алдааг олж, өөрийн текстээр солихын тулд IF функцийн логик тестэнд Vlookup томьёог оруулаарай, тухайлбал:

Мэдээж та "Одоогүй" гэсний оронд хүссэн текстээ бичиж болно.

Танд худалдагчийн жагсаалт байна гэж бодъё.нэг баганад нэр, нөгөө баганад борлуулалтын дүн. Таны даалгавар бол F1-д хэрэглэгчийн оруулсан нэрэнд тохирох тоог татах явдал юм. Хэрэв нэр олдохгүй бол үүнийг харуулсан мессежийг харуулна уу.

A2:A10 дахь нэрс болон C2:C10 хэмжээтэй бол даалгаврыг дараах If Vlookup томъёогоор гүйцэтгэж болно:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

Хэрэв нэр олдвол зохих борлуулалтын дүнг буцаана:

Хэрэв хайлтын утга олдохгүй бол Олдсонгүй<#N/A алдааны оронд 2> мессеж гарч ирнэ:

Энэ томъёо хэрхэн ажилладаг вэ

Томьёоны логик нь маш энгийн: та ISNA функцийг ашигладаг. Vlookup дээр #N/A алдаа байгаа эсэхийг шалгах. Хэрэв алдаа гарвал ISNA нь ҮНЭН, үгүй ​​бол ХУДАЛ-г буцаана. Дээрх утгууд нь IF функцийн логик тест рүү орох бөгөөд энэ нь дараах зүйлсийн аль нэгийг гүйцэтгэдэг:

• Хэрэв логик тест ҮНЭН (#Үгүй алдаа) байвал таны мессеж гарч ирнэ.
• Хэрэв логик тест ХУДАЛ бол (хайлтын утга олдвол) Vlookup нь тохирохыг буцаана.

Excel-ийн шинэ хувилбаруудад IFNA VLOOKUP

Excel 2013-аас эхлэн та #N/A алдааг барьж, зохицуулахын тулд IF ISNA-ийн оронд IFNA функцийг ашиглаж болно:

Манай жишээнд томъёо дараах байдалтай байна. дараах хэлбэрийг авна уу:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

Зөвлөгөө. Хэрэв та #N/A гэлтгүй бүх төрлийн алдаа гаргахыг хүсвэл VLOOKUP-г IFERROR функцтэй хослуулан ашиглаарай. Дэлгэрэнгүй мэдээллийг эндээс авах боломжтой: IFERRORExcel доторх VLOOKUP.

Excel Vlookup: олдохгүй бол 0

тоон утгуудтай ажиллах үед хайлтын утга олдохгүй бол тэгийг буцаана. Үүнийг хийхийн тулд дээр дурдсан IF ISNA VLOOKUP томьёог бага зэрэг өөрчлөлт оруулан ашиглана уу: текст мессежийн оронд IF функцийн утга_хэрэв_үнэн аргумент дотор 0-г оруулна уу:

Манай жишээ хүснэгтэд томъёо дараах байдлаар явагдана:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 болон 2013 хувилбарын сүүлийн хувилбаруудад та IFNA Vlookup хослолыг дахин ашиглаж болно:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: олдохгүй бол хоосон нүдийг буцаана

Энэ бол өөр нэг хувилбар юм. "Vlookup if then" мэдэгдлийн: хайлтын утга олдохгүй үед юу ч буцаадаггүй. Үүнийг хийхийн тулд өөрийн томьёодоо #N/A алдааны оронд хоосон мөр ("") буцаахыг зааж өгнө үү:

Доор Эдгээр нь бүрэн хэмжээний томьёоны жишээ юм:

Бүх Excel хувилбаруудад:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 болон Excel 2013-д:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

Хэрэв Index Match-тэй бол - If нөхцөлтэйгээр зүүн vlookup

Туршлагатай Excel-ийн хэрэглэгчид VLOOKUP функц нь Excel дээр босоо хайлт хийх цорын ганц арга биш гэдгийг мэддэг. INDEX MATCH хослолыг энэ зорилгоор ашиглаж болох бөгөөд энэ нь илүү хүчирхэг, олон талт юм. Сайн мэдээ гэвэл Index Match нь IF-тэй яг адилхан ажиллах боломжтой юмVlookup.

Жишээ нь, та А баганад захиалгын дугаар, В баганад худалдагчийн нэр байна. Та тодорхой худалдагчийн захиалгын дугаарыг татах томьёог хайж байна.

Vlookup хийх боломжгүй. баруунаас зүүн тийш хайх боломжгүй тул энэ тохиолдолд ашигладаг. Хайлтын баганад хайлтын утга олдсон тохиолдолд Index Match ямар ч саадгүй ажиллах болно. Үгүй бол #N/A алдаа гарч ирнэ. Стандарт алдааны тэмдэглэгээг өөрийн текстээр солихын тулд Index Match дотор IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Excel 2016 болон 2016-д та томьёог илүү болгохын тулд IF ISNA-н оронд IFNA-г ашиглаж болно. нягт:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

Үүнтэй адил та Index Match-ийг бусад If томъёонд ашиглаж болно.

Та ингэж ашигладаг. Vlookup болон IF мэдэгдлийг Excel дээр хамтад нь. Энэхүү гарын авлагад дурдсан томъёог илүү нарийвчлан үзэхийн тулд та доорх бидний жишээ ажлын номыг татаж авахыг урьж байна. Уншсан танд баярлалаа, дараа долоо хоногт манай блог дээр уулзана гэж найдаж байна!

Татаж авах дасгалын ном

Excel IF Vlookup - formula examples (.xlsx file)