V LOOKUP සහ IF ශ්‍රිතය එක්සෙල් හි if කොන්දේසිය සමඟ v-ලුක්අප් එකට ඒකාබද්ධ කරන ආකාරය නිබන්ධනය පෙන්වයි. ඔබේම පෙළ, ශුන්‍ය හෝ හිස් කොටුවකින් #N/A දෝෂ ප්‍රතිස්ථාපනය කිරීමට IF ISNA VLOOKUP සූත්‍ර භාවිතා කරන්නේ කෙසේදැයි ඔබ ඉගෙන ගනු ඇත.

VLOOKUP සහ IF ශ්‍රිතයන් එකට ප්‍රයෝජනවත් වන අතර, ඔවුන් ඊටත් වඩා වටිනා අත්දැකීම් ලබා දෙයි. මෙම නිබන්ධනය මඟින් ඔබට ශ්‍රිත දෙකෙහි වාක්‍ය ඛණ්ඩය හොඳින් මතක ඇති බව ගම්‍ය වේ, එසේ නොමැතිනම් ඉහත සබැඳි අනුගමනය කිරීමෙන් ඔබේ දැනුම වැඩි කර ගැනීමට ඔබට අවශ්‍ය විය හැකිය.

Vlookup with If statement: return True/ අසත්‍ය, ඔව්/නැත, යනාදිය.

ඔබ If සහ Vlookup එකට එකතු කරන විට වඩාත් පොදු අවස්ථාවන්ගෙන් එකක් වන්නේ Vlookup මඟින් ආපසු ලබා දෙන අගය නියැදි අගයක් සමඟ සංසන්දනය කර ඔව් / නැත ආපසු ලබා දීමයි. හෝ සත්‍ය / අසත්‍යය ප්‍රතිඵලයක් ලෙස.

බොහෝ අවස්ථාවලදී, පහත දැක්වෙන සාමාන්‍ය සූත්‍රය හොඳින් ක්‍රියා කරයි:

සරල ඉංග්‍රීසියෙන් පරිවර්තනය කර ඇත, Vlookup සත්‍ය නම් (එනම් නිශ්චිත අගයට සමාන) True ආපසු ලබා දෙන ලෙස සූත්‍රය Excel වෙත උපදෙස් දෙයි. Vlookup අසත්‍ය නම් (නිශ්චිත අගයට සමාන නොවේ), සූත්‍රය False ලබා දෙයි.

පහත ඔබට මෙම IF Vlookup සූත්‍රයේ සැබෑ ජීවිත භාවිතයන් කිහිපයක් සොයා ගත හැක.

උදාහරණ 1. නිශ්චිත අගයක් සොයන්න

ඔබට A තීරුවේ අයිතම ලැයිස්තුවක් සහ B තීරුවේ ප්‍රමාණය ඇති බව කියමු. ඔබ ඔබේ පරිශීලකයින් සඳහා උපකරණ පුවරුවක් සාදන අතර සූත්‍රයක් අවශ්‍ය වේඑය E1 හි අයිතමයක් සඳහා ප්‍රමාණය පරීක්ෂා කර අයිතමය තොගයේ තිබේද නැතහොත් විකුණා තිබේද යන්න පරිශීලකයාට දන්වනු ඇත.

ඔබ ප්‍රමාණය මෙවැනි නිශ්චිත ගැළපුම් සූත්‍රයක් සමඟ සාමාන්‍ය Vlookup එකකින් අදින්න:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

ඉන්පසු, Vlookup හි ප්‍රතිඵලය බිංදුව සමඟ සංසන්දනය කරන IF ප්‍රකාශයක් ලියන්න, එය 0 ට සමාන නම් "No", නැතිනම් "ඔව්" ලබා දෙයි:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

ඔව්/නැත වෙනුවට, ඔබට සත්‍ය/අසත්‍යය හෝ තොග ඇත/විකිණී ඇත හෝ වෙනත් ඕනෑම දෙකක් තේරීම්. උදාහරණයක් ලෙස:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

ඔබට Vlookup මඟින් ආපසු ලබා දෙන අගය නියැදි පෙළ සමඟ සැසඳිය හැක. මෙම අවස්ථාවෙහිදී, උද්ධෘත ලකුණු තුළ පෙළ තන්තුවක් ඇතුළත් කිරීමට වග බලා ගන්න:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

උදාහරණ 2. Vlookup ප්‍රතිඵලය වෙනත් කොටුවක් සමඟ සසඳන්න

තවත් සාමාන්‍ය උදාහරණයක් Excel හි If කොන්දේසිය සමඟ Vlookup යනු Vlookup ප්‍රතිදානය වෙනත් කොටුවක අගයක් සමඟ සංසන්දනය කිරීමයි. උදාහරණයක් ලෙස, අපට එය G2 කොටුවේ අංකයකට වඩා විශාල හෝ සමානදැයි පරීක්ෂා කළ හැක:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

සහ මෙන්න අපගේ If සූත්‍රය Vlookup සමඟ ක්‍රියාත්මක වේ:

සමාන ආකාරයකින්, ඔබට ඔබේ Excel If Vlookup සූත්‍රයේ සෛල යොමුවක් සමඟ වෙනත් ඕනෑම තාර්කික ක්‍රියාකරුවෙකු භාවිතා කළ හැක.

උදාහරණ 3. කෙටි ලැයිස්තුවක Vlookup අගයන්

ඉලක්ක තීරුවේ එක් එක් කොටුව වෙනත් ලැයිස්තුවක් සමඟ සංසන්දනය කිරීමට සහ සත්‍ය හෝ ඔව් ගැළපීමක් හමු වුවහොත්, අසත්‍යය හෝ නැත<ආපසු දෙන්න 2> එසේ නොමැතිනම්, මෙම සාමාන්‍ය IF ISNA VLOOKUP සූත්‍රය භාවිතා කරන්න:

Vlookup ප්‍රතිඵලය #N/A දෝෂයක් ඇති කරයි නම්, සූත්‍රය "No" ලබා දෙයි, එනම් සෙවීම් අගය සෙවුම් ලැයිස්තුවේ සොයාගත නොහැක. ගැළපීම සොයාගතහොත්, "ඔව්" ආපසු එවනු ලැබේ. උදාහරණයක් ලෙස:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

ඔබේ ව්‍යාපාර තර්කයට ප්‍රතිවිරුද්ධ ප්‍රතිඵල අවශ්‍ය නම්, සූත්‍රයේ තර්කය ආපසු හැරවීමට "ඔව්" සහ "නැත" සරලව මාරු කරන්න:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel නම් Vlookup සූත්‍රය විවිධ ගණනය කිරීම් සිදු කරයි නම්

ඔබගේම කෙටි පණිවිඩ ප්‍රදර්ශනය කිරීමට අමතරව, Vlookup සමඟින් ශ්‍රිතයට විවිධ ගණනය කිරීම් සිදු කළ හැක ඔබ සඳහන් කරන නිර්ණායක මත පදනම්ව.

අපගේ උදාහරණය තවදුරටත් ගෙන, නිශ්චිත විකුණුම්කරුවෙකුගේ (F1) කොමිස් මුදල ඔවුන්ගේ සඵලතාවය අනුව ගණනය කරමු: $200 සහ ඊට වැඩි අය සඳහා 20% කොමිස්, අනෙක් සියල්ලන්ටම 10% .

මේ සඳහා, Vlookup මඟින් ආපසු ලබා දෙන අගය 200 ට වඩා වැඩි හෝ සමාන දැයි ඔබ පරීක්ෂා කරන්න, එසේ නම්, එය 20% කින් ගුණ කරන්න, එසේ නොමැති නම් 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

A2:A10 විකුණුම්කරුවන්ගේ නම් සහ C2:C10 විකුණුම් වේ.

#N/A දෝෂ සැඟවීමට ISNA VLOOKUP නම්

VLOOKUP ශ්‍රිතයට නිශ්චිත අගයක් සොයාගත නොහැකි නම්, එය #N/A දෝෂයක් ඇති කරයි. එම දෝෂය අල්ලාගෙන එය ඔබේම පෙළකින් ප්‍රතිස්ථාපනය කිරීමට, IF ශ්‍රිතයේ තාර්කික පරීක්ෂණයට Vlookup සූත්‍රයක් ඇතුළත් කරන්න, මේ වගේ:

ස්වාභාවිකව, ඔබට "සොයා නොගත්" වෙනුවට ඔබ කැමති ඕනෑම පෙළක් ටයිප් කළ හැක.

උපකල්පනය කරන විට, ඔබට විකුණුම්කරුවන්ගේ ලැයිස්තුවක් තිබේඑක් තීරුවක නම් සහ තවත් තීරුවක විකුණුම් ප්‍රමාණය. ඔබගේ කාර්යය වන්නේ F1 හි පරිශීලකයා ඇතුළු කරන නමට අනුරූප අංකයක් ඇද ගැනීමයි. නම සොයාගත නොහැකි නම්, එසේ දැක්වෙන පණිවිඩයක් පෙන්වන්න.

A2:A10 හි නම් සහ C2:C10 ප්‍රමාණයන් සමඟ, පහත If Vlookup සූත්‍රය සමඟ කාර්යය ඉටු කළ හැක:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

නම සොයාගතහොත්, අනුරූප විකුණුම් මුදලක් ආපසු එවනු ලැබේ:

සෙවුම් අගය සොයාගත නොහැකි නම්, සොයා නොගත් #N/A දෝෂය වෙනුවට පණිවිඩය දිස්වේ:

මෙම සූත්‍රය ක්‍රියා කරන ආකාරය

සූත්‍රයේ තර්කය ඉතා සරලයි: ඔබ ISNA ශ්‍රිතය භාවිතා කරයි #N/A දෝෂ සඳහා Vlookup පරීක්ෂා කිරීමට. දෝෂයක් සිදුවුවහොත්, ISNA TRUE ලෙස ලබා දෙයි, එසේ නොමැතිනම් FALSE. ඉහත අගයන් IF ශ්‍රිතයේ තාර්කික පරීක්ෂණයට යයි, එය පහත ඒවායින් එකක් කරයි:

• තාර්කික පරීක්ෂණය සත්‍ය නම් (#N/A දෝෂය), ඔබේ පණිවිඩය දර්ශනය වේ.
• තර්කානුකූල පරීක්ෂණය අසත්‍ය නම් (සොයා බැලීමේ අගය හමු වී ඇත), Vlookup සාමාන්‍යයෙන් ගැළපීමක් ලබා දෙයි.

නව Excel අනුවාදවල IFNA VLOOKUP

Excel 2013 සමඟින් පටන් ගෙන, ඔබ #N/A දෝෂ හසුකර ගැනීමට සහ හැසිරවීමට IF ISNA වෙනුවට IFNA ශ්‍රිතය භාවිතා කළ හැක:

අපගේ උදාහරණයේ, සූත්‍රය පහත හැඩය ගන්න:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

ඉඟිය. ඔබ #N/A පමණක් නොව සියලු ආකාරයේ දෝෂ හසුකර ගැනීමට කැමති නම්, IFERROR ශ්‍රිතය සමඟ ඒකාබද්ධව VLOOKUP භාවිතා කරන්න. වැඩි විස්තර මෙතැනින් සොයා ගත හැක: IFERRORExcel හි VLOOKUP.

Excel Vlookup: සොයාගත නොහැකි නම් ආපසු 0

සංඛ්‍යාත්මක අගයන් සමඟ ක්‍රියා කරන විට, සෙවීම් අගය සොයාගත නොහැකි වූ විට ඔබට බිංදුවක් ලබා දීමට අවශ්‍ය විය හැක. එය සිදු කිරීම සඳහා, කුඩා වෙනස් කිරීමක් සමඟ ඉහත සාකච්ඡා කළ IF ISNA VLOOKUP සූත්‍රය භාවිතා කරන්න: කෙටි පණිවිඩයක් වෙනුවට, IF ශ්‍රිතයේ value_if_true තර්කය තුළ 0 සපයන්න:

අපගේ නියැදි වගුවේ, සූත්‍රය පහත පරිදි වේ:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

හි Excel 2016 සහ 2013 හි මෑත සංස්කරණ, ඔබට නැවත IFNA Vlookup සංයෝජනය භාවිතා කළ හැක:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: සොයාගත නොහැකි නම් හිස් කොටුව ආපසු

මෙය තවත් එක් ප්‍රභේදයකි "Vlookup if then" ප්‍රකාශයේ: සෙවීම් අගය සොයාගත නොහැකි වූ විට කිසිවක් ආපසු නොදෙන්න. මෙය සිදු කිරීම සඳහා, #N/A දෝෂය වෙනුවට හිස් තන්තුවක් ("") ආපසු ලබා දීමට ඔබේ සූත්‍රයට උපදෙස් දෙන්න:

පහත සම්පූර්ණ සූත්‍ර උදාහරණ කිහිපයක් වේ:

සියලු Excel අනුවාද සඳහා:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 සහ Excel 2013 සඳහා:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

Index Match සමඟ නම් - If කොන්දේසිය සමඟ වම් vlookup කරන්න

Excel හි සිරස් බැල්මක් කිරීමට ඇති එකම ක්‍රමය VLOOKUP ශ්‍රිතය නොවන බව පළපුරුදු Excel පරිශීලකයන් දනිති. මෙම කාර්යය සඳහා INDEX MATCH සංයෝජනය ද භාවිතා කළ හැකි අතර එය වඩාත් බලවත් සහ බහුකාර්ය වේ. ශුභාරංචිය නම්, Index Match හට හරියටම IF සමඟ එක්ව ක්‍රියා කළ හැකි බවයිVlookup.

උදාහරණයක් ලෙස, ඔබට A තීරුවේ ඇණවුම් අංක සහ B තීරුවේ විකුණුම්කරුවන්ගේ නම් ඇත. ඔබ නිශ්චිත විකුණුම්කරුවෙකු සඳහා ඇණවුම් අංකය ඇද ගැනීමට සූත්‍රයක් සොයමින් සිටී.

Vlookup විය නොහැක එය දකුණේ සිට වමට සෙවිය නොහැකි නිසා මෙම නඩුවේ භාවිතා වේ. සෙවීම් අගය සෙවුම් තීරුවේ ඇති තාක් දර්ශක ගැලපීම බාධාවකින් තොරව ක්‍රියා කරයි. එසේ නොවේ නම්, #N/A දෝෂයක් පෙන්වනු ඇත. ඔබේම පෙළ සමඟ සම්මත දෝෂ අංකනය ප්‍රතිස්ථාපනය කිරීම සඳහා, IF ISNA ඇතුළත nest Index Match:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Excel 2016 සහ 2016 දී, ඔබට සූත්‍රය වැඩි කිරීමට IF ISNA වෙනුවට IFNA භාවිත කළ හැක. compact:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

මේ ආකාරයටම, ඔබට වෙනත් If සූත්‍රවල Index Match භාවිතා කළ හැක.

ඔබ භාවිතා කරන ආකාරය මෙයයි. එක්සෙල් හි Vlookup සහ IF ප්‍රකාශය එකට. මෙම නිබන්ධනයේ සාකච්ඡා කර ඇති සූත්‍ර දෙස සමීපව බැලීමට, පහත අපගේ නියැදි වැඩපොත බාගත කිරීමට ඔබව සාදරයෙන් පිළිගනිමු. කියවීම ගැන මම ඔබට ස්තූතිවන්ත වන අතර ලබන සතියේ අපගේ බ්ලොගයේ ඔබව දැකීමට බලාපොරොත්තු වෙමි!

බාගැනීම සඳහා වැඩපොත පුහුණු වන්න

Excel IF Vlookup - සූත්‍ර උදාහරණ (.xlsx ගොනුව)