Оқулық Excel бағдарламасындағы if шартымен v-іздеу үшін V ІЗДЕУ және IF функцияларын бірге қалай біріктіру керектігін көрсетеді. Сондай-ақ IF ISNA VLOOKUP формулаларын #N/A қателерін жеке мәтінмен, нөлмен немесе бос ұяшықпен ауыстыру үшін қалай пайдалану керектігін үйренесіз.

VLOOKUP және IF функциялары бірге пайдалы болғанымен. олар одан да құнды тәжірибелер береді. Бұл оқулық екі функцияның синтаксисін жақсы есте сақтауды білдіреді, әйтпесе жоғарыдағы сілтемелерді орындау арқылы біліміңізді толықтырғыңыз келуі мүмкін.

If операторымен дыбыстық шолу: True/ қайтару False, Yes/No, т. немесе нәтиже ретінде True/False болады.

Көп жағдайда келесі жалпы формула жақсы жұмыс істейді:

ЕГЕР(VLOOKUP(…) = мән , TRUE, FALSE)

Кәдімгі ағылшын тіліне аударылған формула, егер Vlookup ақиқат болса (яғни көрсетілген мәнге тең) болса, Excel бағдарламасына True қайтаруды тапсырады. Егер Vlookup жалған болса (көрсетілген мәнге тең емес), формула False мәнін қайтарады.

Төменде IF Vlookup формуласының нақты өмірдегі бірнеше қолданылуын табасыз.

Мысал 1. Арнайы мәнді іздеңіз

Айталық, сізде А бағанында элементтер тізімі және В бағанында саны бар. Сіз пайдаланушылар үшін бақылау тақтасын жасап жатырсыз және формула қажет.бұл E1 элементінің санын тексереді және пайдаланушыға тауардың қоймада бар-жоғын немесе сатылып кеткенін хабарлайды.

Мөлшерді келесідей дәл сәйкестік формуласы бар кәдімгі Vlookup арқылы шығарасыз:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Содан кейін Vlookup нәтижесін нөлмен салыстыратын IF операторын жазыңыз және ол 0-ге тең болса «Жоқ», әйтпесе «Иә» қайтарады:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

Иә/Жоқ орнына ШЫН/ЖАЛҒАН немесе Қорында/Сатылған немесе кез келген басқа екеуін қайтаруға болады. таңдаулар. Мысалы:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

Сонымен қатар Vlookup арқылы қайтарылған мәнді мәтін үлгісімен салыстыруға болады. Бұл жағдайда мәтін жолын тырнақшаға алуды ұмытпаңыз, мысалы:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

2-мысал. Vlookup нәтижесін басқа ұяшықпен салыстырыңыз

Тағы бір типтік мысал Excel бағдарламасындағы If шартымен Vlookup Vlookup нәтижесін басқа ұяшықтағы мәнмен салыстырады. Мысалы, оның G2 ұяшығындағы саннан үлкен немесе оған тең екенін тексере аламыз:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

Және мына жерде Vlookup әрекеті бар If формуласы берілген:

Ұқсас жолмен сіз Excel If Vlookup формуласында ұяшық сілтемесімен бірге кез келген басқа логикалық операторды пайдалана аласыз.

3-мысал. Қысқарақ тізімдегі Vlookup мәндері

Мақсатты бағандағы әрбір ұяшықты басқа тізіммен салыстыру және сәйкестік табылса, Шын немесе Иә мәнін қайтару үшін Өтірік немесе Жоқ әйтпесе, осы жалпы IF ISNA VLOOKUP формуласын пайдаланыңыз:

Егер Vlookup нәтижесінде #N/A қатесі болса, формула "Жоқ" деп қайтарады, яғни іздеу мәні іздеу тізімінде табылмайды. Сәйкестік табылса, «Иә» қайтарылады. Мысалы:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

Егер бизнес логикасы қарама-қарсы нәтижелерді қажет етсе, формула логикасын өзгерту үшін жай ғана "Иә" мен "Жоқ" сөздерін ауыстырыңыз:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel If Vlookup формуласы әртүрлі есептеулерді орындауға арналған

Өз мәтіндік хабарларыңызды көрсетумен қатар, Vlookup функциясы бар If функциясы әртүрлі есептеулерді орындай алады. сіз көрсеткен критерийлер негізінде.

Мысалымызды әрі қарай алатын болсақ, олардың тиімділігіне байланысты белгілі бір сатушының комиссиясын есептеп көрейік (F1): $200 және одан да көп табыс тапқандар үшін 20% комиссия, қалғандары үшін 10% .

Ол үшін Vlookup қайтарған мәннің 200-ден үлкен немесе тең екенін тексересіз, егер болса, оны 20%-ға, әйтпесе 10%-ға көбейтіңіз:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Бұл жерде A2:A10 - сатушы аттары және C2:C10 - сатылымдар.

Егер ISNA VLOOKUP #Жоқ қателерді жасыру үшін

VLOOKUP функциясы көрсетілген мәнді таба алмаса, ол #N/A қатесін шығарады. Бұл қатені анықтау және оны өзіңіздің мәтініңізбен ауыстыру үшін IF функциясының логикалық сынағына Vlookup формуласын енгізіңіз, мысалы:

Әрине, "Табылмады" орнына өзіңізге ұнайтын кез келген мәтінді теруге болады.

Сізде сатушы тізімі бар делік.бір бағандағы атаулар және басқа бағанда сату сомасы. Сіздің міндетіңіз - пайдаланушы F1 енгізетін атқа сәйкес санды шығару. Егер атау табылмаса, соны көрсететін хабарды көрсетіңіз.

A2:A10 атауларымен және C2:C10 сомаларымен тапсырманы келесі If Vlookup формуласымен орындауға болады:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

Егер атау табылса, сәйкес сату сомасы қайтарылады:

Егер іздеу мәні табылмаса, Табылмады<#N/A қатесінің орнына 2> хабары пайда болады:

Бұл формула қалай жұмыс істейді

Формуланың логикасы өте қарапайым: сіз ISNA функциясын пайдаланасыз #N/A қателерінің бар-жоғын Vlookup тексеру үшін. Қате орын алса, ISNA "TRUE", әйтпесе "FALSE" мәнін қайтарады. Жоғарыдағы мәндер келесілердің бірін орындайтын IF функциясының логикалық сынағына өтеді:

• Егер логикалық сынақ TRUE (#Жоқ қате) болса, хабарламаңыз көрсетіледі.
• Егер логикалық сынақ ЖАЛҒАН болса (іздеу мәні табылса), Vlookup сәйкестікті қалыпты түрде қайтарады.

Егер жаңа Excel нұсқаларында IFNA VLOOKUP

Excel 2013 бағдарламасынан бастап, сіз #N/A қателерін ұстау және өңдеу үшін IF ISNA орнына IFNA функциясын пайдалана алады:

Біздің мысалда формула келесі пішінді алыңыз:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

Кеңес. Тек #N/A ғана емес, барлық қателерді тұзаққа алғыңыз келсе, VLOOKUP функциясын ҚАТЕУ функциясымен бірге пайдаланыңыз. Толық ақпаратты мына жерден табуға болады: IFERRORExcel бағдарламасында VLOOKUP.

Excel Vlookup: табылмаса, 0 қайтарады

Сандық мәндермен жұмыс істегенде, іздеу мәні табылмаған кезде нөлді қайтарғыңыз келуі мүмкін. Оны орындау үшін жоғарыда талқыланған IF ISNA VLOOKUP формуласын сәл өзгертулермен пайдаланыңыз: мәтіндік хабардың орнына IF функциясының мән_егер_шындық аргументінде 0 мәнін беріңіз:

Үлгі кестеде формула келесідей болады:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 және 2013 нұсқаларының соңғы нұсқаларында IFNA Vlookup комбинациясын қайта пайдалануға болады:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: егер табылмаса бос ұяшықты қайтарады

Бұл тағы бір нұсқа "Vlookup if then" мәлімдемесінің: іздеу мәні табылмаған кезде ештеңе қайтармайды. Ол үшін формулаға #Жоқ қатенің орнына бос жолды ("") қайтаруды тапсырыңыз:

Төмен бірнеше толық формула мысалдары берілген:

Барлық Excel нұсқалары үшін:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 және Excel 2013 үшін:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

Егер Index Match болса - If шартымен сол жақ vlookup

Тәжірибелі Excel пайдаланушылары VLOOKUP функциясы Excel бағдарламасында тік іздеуді жүзеге асырудың жалғыз жолы емес екенін біледі. INDEX MATCH комбинациясы осы мақсат үшін де пайдаланылуы мүмкін және ол одан да күшті және жан-жақты. Жақсы жаңалық, Index Match IF-пен дәл солай жұмыс істей аладыVlookup.

Мысалы, А бағанында тапсырыс нөмірлері және В бағанында сатушы аттары бар. Сіз белгілі бір сатушы үшін тапсырыс нөмірін шығару үшін формуланы іздеп жатырсыз.

Дыбыс іздеу мүмкін емес. бұл жағдайда пайдаланылады, себебі ол оңнан солға қарай іздей алмайды. Іздеу мәні іздеу бағанында табылғанша, Index Match кедергісіз жұмыс істейді. Олай болмаса, #N/A қатесі көрсетіледі. Стандартты қате белгісін өзіңіздің мәтініңізбен ауыстыру үшін IF ISNA ішіне индекс сәйкестігін енгізіңіз:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Excel 2016 және 2016 нұсқаларында формуланы көбірек ету үшін IF ISNA орнына IFNA қолдануға болады. ықшам:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

Ұқсас жолмен сіз Index Match функциясын басқа If формулаларында пайдалана аласыз.

Осылайша пайдаланасыз Vlookup және IF мәлімдемесі Excel бағдарламасында бірге. Осы оқулықта талқыланған формулаларды толығырақ көру үшін төмендегі жұмыс кітабының үлгісін жүктеп алуыңызға болады. Оқығаныңыз үшін алғыс айтамын және келесі аптада блогымызда көреміз деп үміттенемін!

Жүктеп алуға арналған жұмыс кітабы

Excel IF Vlookup - формула мысалдары (.xlsx файлы)