Ohjeessa näytetään, miten yhdistetään V LOOKUP- ja IF-toiminnot yhdessä v-lookupiin if-ehdon kanssa Excelissä. Opit myös käyttämään IF ISNA VLOOKUP-kaavoja #N/A-virheiden korvaamiseksi omalla tekstillä, nollalla tai tyhjällä solulla.

Vaikka VLOOKUP- ja IF-funktiot ovat käyttökelpoisia yksinäänkin, yhdessä ne tuottavat vielä arvokkaampia kokemuksia. Tämä opetusohjelma edellyttää, että muistat näiden kahden funktion syntaksin hyvin, muutoin voit täydentää tietämystäsi seuraamalla yllä olevia linkkejä.

Vlookup ja If-lause: palauta True/False, Yes/No jne.

Yksi yleisimmistä skenaarioista, joissa If ja Vlookup yhdistetään, on verrata Vlookupin palauttamaa arvoa näytearvoon ja palauttaa seuraavat tiedot Kyllä / Ei tai Totta / Väärin tuloksena.

Useimmissa tapauksissa seuraava yleinen kaava toimii hyvin:

Selkokielellä käännettynä kaava käskee Exceliä palauttamaan seuraavat tiedot Totta jos Vlookup on tosi (eli yhtä suuri kuin määritetty arvo). Jos Vlookup on epätosi (ei yhtä suuri kuin määritetty arvo), kaava palauttaa arvon False .

Alla on muutamia todellisia käyttötapoja tälle IF Vlookup -kaavalle.

Esimerkki 1. Tietyn arvon etsiminen

Oletetaan, että sinulla on luettelo tuotteista sarakkeessa A ja määrä sarakkeessa B. Olet luomassa kojelautaa käyttäjiäsi varten ja tarvitset kaavan, joka tarkistaa tuotteen määrän sarakkeessa E1 ja ilmoittaa käyttäjälle, onko tuote varastossa vai loppuunmyyty.

Vedät määrän tavallisella Vlookupilla, jonka kaava on täsmälleen samanlainen kuin tämä:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Kirjoita sitten IF-lause, joka vertaa Vlookupin tulosta nollaan ja palauttaa "Ei", jos tulos on 0, ja "Kyllä", jos tulos on 0:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0, "Ei", "Kyllä")

Sen sijaan, että Kyllä/Ei , voit palauttaa TOTTA/VÄÄRIN tai Varastossa/myyty loppuun tai kaksi muuta vaihtoehtoa. Esimerkiksi:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0, "Myyty loppuun", "Varastossa")

Voit myös verrata Vlookupin palauttamaa arvoa näytteellä teksti Muista tässä tapauksessa sulkea tekstijono lainausmerkkeihin, kuten tässä:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="näyteteksti",TRUE,FALSE)

Esimerkki 2. Vertaa Vlookup-tulosta toiseen soluun

Toinen tyypillinen esimerkki Vlookupin ja If-ehdon käytöstä Excelissä on Vlookupin tuloksen vertaaminen toisessa solussa olevaan arvoon. Voimme esimerkiksi tarkistaa, onko se suurempi tai yhtä suuri kuin solussa G2 oleva luku:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2, "Kyllä!", "Ei")

Ja tässä on If-kaavamme Vlookupin kanssa toiminnassa:

Samalla tavalla voit käyttää mitä tahansa muuta loogista operaattoria yhdessä soluviittauksen kanssa Excel If Vlookup -kaavassa.

Esimerkki 3. Vlookup-arvot lyhyemmässä luettelossa

Vertaa kohdesarakkeen jokaista solua toiseen luetteloon ja palauttaa sen jälkeen Totta tai Kyllä jos vastaavuus löytyy, False tai Ei muuten käytä tätä yleistä IF ISNA VLOOKUP -kaavaa:

Jos Vlookup antaa tulokseksi #N/A-virheen, kaava palauttaa "Ei", mikä tarkoittaa, että hakuarvoa ei löydy hakuluettelosta. Jos vastaavuus löytyy, palautetaan "Kyllä". Esimerkiksi:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)), "Ei", "Kyllä")

Jos liiketoimintalogiikkasi vaatii päinvastaisia tuloksia, vaihda "Kyllä" ja "Ei" keskenään ja käännä kaavan logiikka päinvastaiseksi:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)), "Kyllä", "Ei")

Excel If Vlookup-kaava erilaisten laskelmien suorittamiseksi

Omien tekstiviestien näyttämisen lisäksi If-toiminto Vlookupilla voi suorittaa erilaisia laskutoimituksia määrittämiesi kriteerien perusteella.

Lasketaan esimerkin mukaisesti tietyn myyjän (F1) palkkio tehokkuuden mukaan: 20 % palkkio niille, jotka tienasivat 200 dollaria tai enemmän, ja 10 % kaikille muille.

Tätä varten tarkistetaan, onko Vlookupin palauttama arvo suurempi tai yhtä suuri kuin 200, ja jos on, kerrotaan se 20 prosentilla, muuten 10 prosentilla:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Jossa A2:A10 ovat myyjien nimet ja C2:C10 ovat myynnit.

IF ISNA VLOOKUP piilottaa #N/A virheet

Jos VLOOKUP-funktio ei löydä määritettyä arvoa, se heittää #N/A-virheen. Jos haluat napata tämän virheen ja korvata sen omalla tekstilläsi, upota Vlookup-kaava IF-funktion loogiseen testiin seuraavasti:

Voit luonnollisesti kirjoittaa minkä tahansa haluamasi tekstin "Ei löydy" sijasta.

Oletetaan, että sinulla on luettelo myyjien nimistä yhdessä sarakkeessa ja myyntimääristä toisessa sarakkeessa. Tehtävänäsi on etsiä käyttäjän F1-kenttään syöttämää nimeä vastaava numero. Jos nimeä ei löydy, näytä siitä kertova viesti.

Kun nimet ovat A2:A10 ja määrät C2:C10, tehtävä voidaan suorittaa seuraavalla If Vlookup -kaavalla:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Ei löydy", VLOOKUP(F1,$A$2:$C$10,3,FALSE)))

Jos nimi löytyy, vastaava myyntimäärä palautetaan:

Jos hakuarvoa ei löydy, on Ei löydy viesti tulee näkyviin #N/A-virheen sijasta:

Miten tämä kaava toimii

Kaavan logiikka on hyvin yksinkertainen: käytät ISNA-funktiota Vlookupin tarkistamiseen #N/A-virheiden varalta. Jos virhe ilmenee, ISNA palauttaa TRUE, muuten FALSE. Edellä mainitut arvot menevät IF-funktion loogiseen testiin, joka tekee jonkin seuraavista:

• Jos looginen testi on TRUE (#N/A-virhe), näyttöön tulee viesti.
• Jos looginen testi on FALSE (hakuarvo on löydetty), Vlookup palauttaa vastaavuuden normaalisti.

IFNA VLOOKUP uudemmissa Excel-versioissa

Excel 2013:sta alkaen voit käyttää IFNA-funktiota IF ISNA:n sijasta #N/A-virheiden havaitsemiseen ja käsittelyyn:

Esimerkissämme kaava olisi seuraavanlainen:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Ei löydy")

Vihje: Jos haluat saada kiinni kaikenlaisia virheitä, etkä vain #N/A:ta, käytä VLOOKUPia yhdessä IFERROR-funktion kanssa. Lisätietoja löydät täältä: IFERROR VLOOKUP Excelissä.

Excel Vlookup: jos ei löydy palauttaa 0

Kun työskentelet numeeristen arvojen kanssa, saatat haluta palauttaa nollan, kun hakuarvoa ei löydy. Voit tehdä sen käyttämällä edellä käsiteltyä IF ISNA VLOOKUP -kaavaa pienellä muutoksella: tekstiviestin sijasta anna 0 kentässä value_if_true IF-funktion argumentti:

Esimerkkitaulukossamme kaava olisi seuraava:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE)))

Excelin uusimmissa versioissa 2016 ja 2013 voit käyttää IFNA Vlookup -yhdistelmää uudelleen:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: jos sitä ei löydy, palauta tyhjä solu

Tämä on vielä yksi muunnelma "Vlookup if then" -lausekkeesta: älä palauta mitään, kun hakuarvoa ei löydy. Voit tehdä tämän ohjeistamalla kaavaasi palauttamaan tyhjän merkkijonon ("") #N/A-virheen sijasta:

Alla on pari täydellistä kaavaesimerkkiä:

Kaikille Excel-versioille:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 ja Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

If with Index Match - vasemmanpuoleinen vlookup If-ehdon kanssa

Kokeneet Excel-käyttäjät tietävät, että VLOOKUP-toiminto ei ole ainoa tapa tehdä pystysuora haku Excelissä. Tähän tarkoitukseen voidaan käyttää myös INDEX MATCH -yhdistelmää, ja se on vielä tehokkaampi ja monipuolisempi. Hyvä uutinen on, että Index Match voi toimia yhdessä IF:n kanssa täsmälleen samalla tavalla kuin Vlookup.

Esimerkiksi sarakkeessa A on tilausnumeroita ja sarakkeessa B myyjien nimiä. Etsit kaavaa, jolla saat tietyn myyjän tilausnumeron.

Vlookupia ei voi käyttää tässä tapauksessa, koska se ei voi hakea oikealta vasemmalle. Index Match toimii ongelmitta, kunhan hakuarvo löytyy hakusarakkeesta. Jos näin ei ole, näkyviin tulee #N/A-virhe. Jos haluat korvata vakiovirhemerkinnän omalla tekstilläsi, sijoita Index Match IF ISNA:n sisään:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Ei löytynyt", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))))

Excel 2016:ssa ja 2016:ssa voit käyttää IFNA:ta IF ISNA:n sijasta, jotta kaava olisi tiiviimpi:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Ei löydy")

Samalla tavalla voit käyttää Index Matchia muissa If-kaavoissa.

Näin käytät Vlookupia ja IF-lauseketta yhdessä Excelissä. Jos haluat tutustua tarkemmin tässä opetusohjelmassa käsiteltyihin kaavoihin, voit ladata alla olevan esimerkkityökirjan. Kiitän sinua lukemisesta ja toivon, että tapaamme blogissamme ensi viikolla!

Käytännön työkirja ladattavissa

Excel IF Vlookup - kaavaesimerkkejä (.xlsx-tiedosto)