A bemutató azt mutatja be, hogyan kombinálhatjuk a V LOOKUP és IF funkció együtt a v-lookup if feltételhez az Excelben. Azt is megtanulja, hogyan használhatja az IF ISNA VLOOKUP képleteket a #N/A hibák helyettesítésére saját szöveggel, nullával vagy üres cellával.

Míg a VLOOKUP és az IF függvények önmagukban is hasznosak, együtt még értékesebb élményeket nyújtanak. Ez a bemutató feltételezi, hogy jól emlékszel a két függvény szintaxisára, ellenkező esetben érdemes felfrissíteni a tudásodat a fenti linkek segítségével.

Vlookup If utasítással: True/False, Yes/No, stb. visszatérítés.

Az egyik leggyakoribb forgatókönyv az If és a Vlookup kombinálásakor az, hogy a Vlookup által visszaadott értéket összehasonlítjuk egy mintaértékkel, és a következő értéket adjuk vissza Igen / Nem vagy Igaz / Hamis az eredmény.

A legtöbb esetben a következő általános képlet jól működik:

Lefordítva egyszerű angolra, a képlet utasítja az Excelt, hogy adja vissza a következő adatokat Igaz ha a Vlookup igaz (azaz egyenlő a megadott értékkel). Ha a Vlookup hamis (nem egyenlő a megadott értékkel), a képlet a következő értéket adja vissza Hamis .

Az alábbiakban az IF Vlookup formula néhány valós felhasználási módját mutatjuk be.

Példa 1. Egy adott érték keresése

Tegyük fel, hogy az A oszlopban van egy lista a tételekről, a B oszlopban pedig a mennyiségről. Egy műszerfalat készít a felhasználók számára, és szüksége van egy képletre, amely az E1 oszlopban lévő tétel mennyiségét ellenőrzi, és tájékoztatja a felhasználót, hogy az adott tétel raktáron van-e vagy elfogyott.

A mennyiséget egy szabályos Vlookup segítségével húzza ki, pontos egyezés képletével, például így:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Ezután írjon egy IF utasítást, amely összehasonlítja a Vlookup eredményét nullával, és "Nem" választ ad vissza, ha az egyenlő 0-val, egyébként "Igen":

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0, "Nem", "Igen")

Ahelyett, hogy Igen/Nem , akkor visszatérhet TRUE/FALSE vagy Raktáron/eladó vagy bármelyik másik két lehetőség. Például:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0, "Elfogyott", "Készleten")

A Vlookup által visszaadott értéket összehasonlíthatja a mintával is. szöveg Ebben az esetben ügyeljen arra, hogy a szöveges karakterláncot idézőjelek közé zárja, például így:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="minta szöveg",TRUE,FALSE)

Példa 2. A Vlookup eredményének összehasonlítása egy másik cellával

Egy másik tipikus példa az Excelben az If feltételes Vlookup-ra az, hogy a Vlookup kimenetét összehasonlítjuk egy másik cellában lévő értékkel. Például ellenőrizhetjük, hogy nagyobb vagy egyenlő-e a G2 cellában lévő számmal:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2, "Igen!", "Nem")

És itt van az If képletünk a Vlookuppal működés közben:

Hasonló módon bármely más logikai operátort is használhat cellahivatkozással együtt az Excel If Vlookup képletében.

Példa 3. Vlookup értékek egy rövidebb listában

A céloszlop minden egyes cellájának összehasonlítása egy másik listával és visszatérése Igaz vagy Igen ha találunk egyezést, Hamis vagy Nem egyébként használja ezt az általános IF ISNA VLOOKUP képletet:

Ha a Vlookup a #N/A hibát eredményezi, a képlet "Nem" értéket ad vissza, ami azt jelenti, hogy a keresési érték nem található a keresési listában. Ha a találat megvan, akkor "Igen" értéket ad vissza. Például:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)), "Nem", "Igen")

Ha az üzleti logika ellentétes eredményt igényel, egyszerűen cserélje fel az "Igen" és a "Nem" értékeket a képlet logikájának megfordításához:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)), "Igen", "Nem")

Excel If Vlookup képlet különböző számítások elvégzéséhez

A saját szöveges üzenetek megjelenítésén kívül az If funkció a Vlookup funkcióval különböző számításokat végezhet az Ön által megadott kritériumok alapján.

Ha továbbvisszük példánkat, számoljuk ki egy adott eladó (F1) jutalékát a hatékonyságától függően: 20% jutalék azoknak, akik 200 dollárt vagy annál többet kerestek, 10% jutalék mindenki másnak.

Ehhez ellenőrizze, hogy a Vlookup által visszaadott érték nagyobb vagy egyenlő-e 200-nál, és ha igen, szorozza meg 20%-kal, egyébként 10%-kal:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Ahol A2:A10 az eladó neve és C2:C10 az értékesítés.

IF ISNA VLOOKUP a #N/A hibák elrejtéséhez

Ha a VLOOKUP függvény nem talál egy megadott értéket, akkor #N/A hibát dob. A hiba elkapásához és saját szöveggel való helyettesítéséhez ágyazzon be egy Vlookup képletet az IF függvény logikai tesztjébe, például így:

Természetesen a "Nem található" helyett bármilyen szöveget beírhat.

Tegyük fel, hogy az egyik oszlopban van egy lista az eladók nevével, a másik oszlopban pedig az eladási összegekkel. Az Ön feladata, hogy az F1-ben a felhasználó által beírt névnek megfelelő számot húzza ki. Ha a név nem található, jelenítsen meg egy erre utaló üzenetet.

Az A2:A10 nevek és a C2:C10 összegek esetén a feladat a következő If Vlookup képlettel teljesíthető:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Nem található", VLOOKUP(F1,$A$2:$C$10,3,FALSE)))

Ha a név megtalálható, a megfelelő értékesítési összeg is visszakerül:

Ha a keresési értéket nem találja, a Nem található üzenet jelenik meg a #N/A hiba helyett:

Hogyan működik ez a képlet

A képlet logikája nagyon egyszerű: az ISNA függvényt használjuk a Vlookup #N/A hibák ellenőrzésére. Ha hiba lép fel, az ISNA TRUE-t ad vissza, egyébként FALSE-t. A fenti értékek az IF függvény logikai tesztjébe kerülnek, amely a következők egyikét végzi:

• Ha a logikai teszt TRUE (#N/A hiba), akkor az Ön üzenete jelenik meg.
• Ha a logikai teszt FALSE (a keresési értéket megtalálták), a Vlookup normál esetben egyezést ad vissza.

IFNA VLOOKUP az újabb Excel verziókban

Az Excel 2013-tól kezdődően az IF ISNA helyett az IF ISNA függvényt használhatja az #N/A hibák elkapására és kezelésére:

Példánkban a képlet a következő formát öltené:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Nem található")

Tipp: Ha nem csak az #N/A hibákat, hanem mindenféle hibát meg szeretne fogni, használja a VLOOKUP-ot az IFERROR funkcióval kombinálva. További részletek itt találhatók: IFERROR VLOOKUP az Excelben.

Excel Vlookup: ha nem található, 0 visszatérés

Amikor numerikus értékekkel dolgozunk, előfordulhat, hogy nullát szeretnénk visszaadni, ha a keresési érték nem található. Ehhez használjuk a fentebb tárgyalt IF ISNA VLOOKUP formulát egy kis módosítással: szöveges üzenet helyett 0-t adjunk meg a value_if_true az IF függvény argumentuma:

A mintatáblázatunkban a képlet a következőképpen néz ki:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE)))

Az Excel 2016 és 2013 legújabb verzióiban ismét használhatja az IFNA Vlookup kombinációt:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: ha nem található, üres cellát ad vissza

Ez egy újabb változata a "Vlookup if then" utasításnak: ne adjon vissza semmit, ha a keresési érték nem található. Ehhez utasítsa a képletet, hogy a #N/A hiba helyett egy üres karakterláncot (""") adjon vissza:

Az alábbiakban néhány teljes képletpélda található:

Minden Excel-verzióhoz:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Az Excel 2016 és az Excel 2013 esetében:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

If with Index Match - bal oldali vlookup If feltétellel

A tapasztalt Excel-felhasználók tudják, hogy a VLOOKUP funkció nem az egyetlen módja a függőleges keresés elvégzésének az Excelben. Az INDEX MATCH kombináció is használható erre a célra, és még erősebb és sokoldalúbb. A jó hír az, hogy az Index Match pontosan ugyanúgy együtt tud működni az IF-fel, mint a Vlookup.

Például az A oszlopban a rendelésszámok, a B oszlopban pedig az eladók nevei szerepelnek. Egy képletet keres egy adott eladó rendelésszámának kinyerésére.

A Vlookup ebben az esetben nem használható, mert nem tud jobbról balra keresni. Az Index Match gond nélkül működik, amíg a keresési érték megtalálható a keresési oszlopban. Ha nem, akkor egy #N/A hiba jelenik meg. Ha a standard hiba jelölést saját szöveggel akarja helyettesíteni, akkor az Index Match-et fészkelje be az IF ISNA-ba:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Nem található", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))))

Az Excel 2016 és 2016 programban az IF ISNA helyett az IF ISNA-t használhatja, hogy a képletet tömörebbé tegye:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Nem található")

Hasonló módon használhatja az Index Matchet más If-képletekben is.

Így használja a Vlookup és az IF utasítás együtt az Excelben. Ha közelebbről meg szeretné nézni a bemutatóban tárgyalt képleteket, szívesen letölti az alábbi minta munkafüzetünket. Köszönöm, hogy elolvasta, és remélem, hogy jövő héten találkozunk a blogunkon!

Gyakorlati munkafüzet letölthető

Excel IF Vlookup - képlet példák (.xlsx fájl)