ບົດສອນສະແດງໃຫ້ເຫັນວິທີການລວມ V ຟັງຊັນ LOOKUP ແລະ IF ເຂົ້າກັນເພື່ອ v-lookup ກັບ if ໃນ Excel. ນອກນັ້ນທ່ານຍັງຈະໄດ້ຮຽນຮູ້ວິທີການນໍາໃຊ້ສູດ IF ISNA VLOOKUP ເພື່ອທົດແທນຄວາມຜິດພາດ #N/A ດ້ວຍຂໍ້ຄວາມ, ສູນ ຫຼືຕາລາງຫວ່າງເປົ່າຂອງເຈົ້າເອງ.

ໃນຂະນະທີ່ຟັງຊັນ VLOOKUP ແລະ IF ມີປະໂຫຍດດ້ວຍຕົວມັນເອງ. ພວກເຂົາສົ່ງປະສົບການທີ່ມີຄຸນຄ່າຫຼາຍກວ່າເກົ່າ. ການສອນນີ້ຫມາຍຄວາມວ່າທ່ານຈື່ syntax ຂອງສອງຫນ້າທີ່ໄດ້ດີ, ຖ້າບໍ່ດັ່ງນັ້ນທ່ານອາດຈະຕ້ອງການທົບທວນຄວາມຮູ້ຂອງທ່ານໂດຍການປະຕິບັດຕາມການເຊື່ອມຕໍ່ຂ້າງເທິງ.

Vlookup with If statement: return True/ ຜິດ, ແມ່ນ/ບໍ່ແມ່ນ, ແລະອື່ນໆ.

ຫນຶ່ງໃນສະຖານະການທົ່ວໄປທີ່ສຸດເມື່ອທ່ານລວມ If ແລະ Vlookup ເຂົ້າກັນແມ່ນການປຽບທຽບມູນຄ່າທີ່ສົ່ງມາໂດຍ Vlookup ກັບຄ່າຕົວຢ່າງແລະກັບຄືນ ແມ່ນ / ບໍ່ແມ່ນ ຫຼື ຖືກ / False ເປັນຜົນໄດ້ຮັບ.

ໃນກໍລະນີຫຼາຍທີ່ສຸດ, ສູດທົ່ວໄປຕໍ່ໄປນີ້ຈະເຮັດວຽກໄດ້ດີ:

ແປເປັນພາສາອັງກິດທຳມະດາ, ສູດສັ່ງໃຫ້ Excel ກັບຄືນ True ຖ້າ Vlookup ເປັນຈິງ (i.e. ເທົ່າກັບຄ່າທີ່ລະບຸ). ຖ້າ Vlookup ເປັນ false (ບໍ່ເທົ່າກັບຄ່າທີ່ລະບຸ), ສູດຈະສົ່ງກັບ False .

ຢູ່ລຸ່ມນີ້ເຈົ້າຈະພົບເຫັນການໃຊ້ສູດ IF Vlookup ນີ້ໃນຊີວິດຈິງ.

ຕົວຢ່າງ 1. ຊອກຫາຄ່າສະເພາະ

ສົມມຸດວ່າ, ທ່ານມີລາຍການລາຍການຢູ່ໃນຖັນ A ແລະປະລິມານໃນຖັນ B. ທ່ານກໍາລັງສ້າງ dashboard ສໍາລັບຜູ້ໃຊ້ຂອງທ່ານແລະຕ້ອງການສູດ.ທີ່ຈະກວດສອບປະລິມານສໍາລັບລາຍການໃນ E1 ແລະແຈ້ງໃຫ້ຜູ້ໃຊ້ຮູ້ວ່າລາຍການຢູ່ໃນຫຼັກຊັບຫຼືຂາຍອອກ.

ທ່ານດຶງປະລິມານດ້ວຍ Vlookup ປົກກະຕິທີ່ມີສູດການຈັບຄູ່ທີ່ແນ່ນອນເຊັ່ນນີ້:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

ຈາກນັ້ນ, ຂຽນຖະແຫຼງການ IF ທີ່ສົມທຽບຜົນຂອງ Vlookup ກັບສູນ, ແລະສົ່ງຄືນ "ບໍ່" ຖ້າມັນເທົ່າກັບ 0, "ແມ່ນ" ຖ້າບໍ່ດັ່ງນັ້ນ:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

ແທນ ແມ່ນ/ບໍ່ , ທ່ານສາມາດສົ່ງຄືນ TRUE/FALSE ຫຼື ໃນສະຕັອກ/ຂາຍອອກ ຫຼືສອງອັນອື່ນໆ ທາງເລືອກ. ຕົວຢ່າງ:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

ທ່ານຍັງສາມາດປຽບທຽບມູນຄ່າທີ່ສົ່ງມາໂດຍ Vlookup ດ້ວຍຕົວຢ່າງ text . ໃນ​ກໍ​ລະ​ນີ​ນີ້, ໃຫ້​ແນ່​ໃຈວ່​າ​ການ​ຕິດ​ພັນ​ຕົວ​ອັກ​ສອນ​ໃນ​ເຄື່ອງ​ຫມາຍ​ວົງ​ຢືມ​ເຊັ່ນ​ນີ້:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

ຕົວ​ຢ່າງ 2. ສົມ​ທຽບ​ຜົນ​ໄດ້​ຮັບ Vlookup ກັບ​ເຊ​ລ​ອື່ນ

ອີກ​ຫນຶ່ງ​ຕົວ​ຢ່າງ​ປົກ​ກະ​ຕິ​ຂອງ Vlookup ກັບ If ເງື່ອນໄຂໃນ Excel ແມ່ນການປຽບທຽບຜົນຜະລິດ Vlookup ກັບຄ່າໃນຕາລາງອື່ນ. ຕົວຢ່າງ, ພວກເຮົາສາມາດກວດເບິ່ງວ່າມັນໃຫຍ່ກວ່າ ຫຼືເທົ່າກັບຕົວເລກຢູ່ໃນຕາລາງ G2:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

ແລະນີ້ແມ່ນສູດ If ຂອງພວກເຮົາກັບ Vlookup ໃນການປະຕິບັດ:

ໃນລັກສະນະທີ່ຄ້າຍຄືກັນ, ທ່ານສາມາດນໍາໃຊ້ຕົວປະຕິບັດການທາງໂລຈິກອື່ນ ໆ ພ້ອມກັບການອ້າງອິງເຊລໃນສູດ Excel If Vlookup ຂອງທ່ານ.

ຕົວຢ່າງ 3. ຄ່າ Vlookup ໃນບັນຊີລາຍຊື່ສັ້ນກວ່າ

ເພື່ອປຽບທຽບແຕ່ລະຕາລາງໃນຖັນເປົ້າໝາຍກັບລາຍຊື່ອື່ນ ແລະສົ່ງກັບ ຖືກ ຫຼື ແມ່ນ ຖ້າພົບການຈັບຄູ່, ຜິດ ຫຼື ບໍ່ ຖ້າບໍ່ດັ່ງນັ້ນ, ໃຊ້ສູດ IF ISNA VLOOKUP ທົ່ວໄປນີ້:

ຖ້າ Vlookup ສົ່ງຜົນໃຫ້ເກີດຄວາມຜິດພາດ #N/A, ສູດຄຳນວນຈະໃຫ້ຜົນເປັນ "No", ຊຶ່ງໝາຍຄວາມວ່າບໍ່ພົບຄ່າການຊອກຫາໃນລາຍການຊອກຫາ. ຖ້າພົບການຈັບຄູ່, "ແມ່ນ" ຈະຖືກສົ່ງຄືນ. ຕົວຢ່າງ:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

ຖ້າເຫດຜົນທາງທຸລະກິດຂອງທ່ານຕ້ອງການຜົນໄດ້ຮັບກົງກັນຂ້າມ, ພຽງແຕ່ສະຫຼັບ "ແມ່ນ" ແລະ "ບໍ່" ເພື່ອປ່ຽນເຫດຜົນຂອງສູດ:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel ຖ້າ Vlookup ສູດການຄິດໄລ່ທີ່ແຕກຕ່າງກັນ

ນອກຈາກການສະແດງຂໍ້ຄວາມຂອງທ່ານເອງ, ຖ້າຫາກວ່າການເຮັດວຽກກັບ Vlookup ສາມາດປະຕິບັດການຄິດໄລ່ທີ່ແຕກຕ່າງກັນ. ອີງຕາມເງື່ອນໄຂທີ່ທ່ານລະບຸ.

ຍົກຕົວຢ່າງຂອງພວກເຮົາຕື່ມອີກ, ໃຫ້ຄິດໄລ່ຄ່ານາຍໜ້າຂອງຜູ້ຂາຍສະເພາະ (F1) ຂຶ້ນກັບປະສິດທິຜົນຂອງພວກມັນ: ຄ່ານາຍໜ້າ 20% ສໍາລັບຜູ້ທີ່ມີລາຍໄດ້ $200 ແລະຫຼາຍກວ່ານັ້ນ, 10% ສໍາລັບຄົນອື່ນ. .

ສຳລັບອັນນີ້, ທ່ານກວດເບິ່ງວ່າຄ່າທີ່ສົ່ງມາໂດຍ Vlookup ແມ່ນໃຫຍ່ກວ່າ ຫຼືເທົ່າກັບ 200, ແລະຖ້າເປັນ, ໃຫ້ຄູນ 20%, ຖ້າບໍ່ດັ່ງນັ້ນ 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

ບ່ອນທີ່ A2:A10 ແມ່ນຊື່ຜູ້ຂາຍ ແລະ C2:C10 ແມ່ນການຂາຍ.

ຖ້າ ISNA VLOOKUP ເພື່ອເຊື່ອງຄວາມຜິດພາດ #N/A

ຖ້າຟັງຊັນ VLOOKUP ບໍ່ສາມາດຊອກຫາຄ່າທີ່ລະບຸໄດ້, ມັນຈະເກີດຄວາມຜິດພາດ #N/A. ເພື່ອຈັບຄວາມຜິດພາດນັ້ນແລະແທນທີ່ດ້ວຍຂໍ້ຄວາມຂອງທ່ານເອງ, ຝັງສູດ Vlookup ໃນການທົດສອບຢ່າງມີເຫດຜົນຂອງຟັງຊັນ IF, ເຊັ່ນ:

ຕາມທໍາມະຊາດ, ທ່ານສາມາດພິມຂໍ້ຄວາມໃດກໍໄດ້ທີ່ທ່ານຕ້ອງການແທນ "ບໍ່ພົບ".

ສົມມຸດວ່າ, ທ່ານມີລາຍຊື່ຜູ້ຂາຍ.ຊື່ໃນຖັນຫນຶ່ງແລະຈໍານວນການຂາຍໃນຖັນອື່ນ. ວຽກງານຂອງທ່ານແມ່ນເພື່ອດຶງຕົວເລກທີ່ກົງກັບຊື່ທີ່ຜູ້ໃຊ້ໃສ່ໃນ F1. ຖ້າບໍ່ພົບຊື່, ໃຫ້ສະແດງຂໍ້ຄວາມທີ່ລະບຸໄວ້.

ດ້ວຍຊື່ໃນ A2:A10 ແລະຈໍານວນ C2:C10, ວຽກງານດັ່ງກ່າວສາມາດຖືກປະຕິບັດໄດ້ດ້ວຍສູດ If Vlookup:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

ຖ້າຊື່ຖືກພົບເຫັນ, ຈໍານວນການຂາຍທີ່ສອດຄ້ອງກັນຈະຖືກສົ່ງຄືນ:

ຖ້າບໍ່ພົບມູນຄ່າການຊອກຫາ, ບໍ່ພົບ ຂໍ້ຄວາມປະກົດຂຶ້ນແທນຂໍ້ຜິດພາດ #N/A:

ສູດນີ້ເຮັດວຽກແນວໃດ

ເຫດຜົນຂອງສູດແມ່ນງ່າຍດາຍຫຼາຍ: ທ່ານໃຊ້ຟັງຊັນ ISNA ເພື່ອກວດສອບ Vlookup ສໍາລັບ #N/A errors. ຖ້າມີຂໍ້ຜິດພາດເກີດຂຶ້ນ, ISNA ກັບຄືນ TRUE, ຖ້າບໍ່ດັ່ງນັ້ນ FALSE. ຄ່າຂ້າງເທິງນີ້ໄປຫາການທົດສອບຕາມເຫດຜົນຂອງຟັງຊັນ IF, ເຊິ່ງເຮັດອັນໃດອັນໜຶ່ງຕໍ່ໄປນີ້:

• ຖ້າການທົດສອບຕາມເຫດຜົນແມ່ນ TRUE (#N/A error), ຂໍ້ຄວາມຂອງເຈົ້າຈະຖືກສະແດງ.<20
• ຖ້າການທົດສອບຕາມເຫດຜົນແມ່ນ FALSE (ພົບຄ່າຊອກຫາ), Vlookup ຈະສົ່ງຄືນການຈັບຄູ່ຕາມປົກກະຕິ.

IFNA VLOOKUP ໃນ Excel ລຸ້ນໃໝ່ກວ່າ

ເລີ່ມຕົ້ນດ້ວຍ Excel 2013, ທ່ານ ສາມາດໃຊ້ຟັງຊັນ IFNA ແທນ IF ISNA ເພື່ອຈັບ ແລະຈັດການຂໍ້ຜິດພາດ #N/A:

ໃນຕົວຢ່າງຂອງພວກເຮົາ, ສູດຈະ ເອົາຮູບຮ່າງຕໍ່ໄປນີ້:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

ເຄັດລັບ. ຖ້າທ່ານຕ້ອງການທີ່ຈະຈັບຄວາມຜິດພາດທຸກປະເພດ, ບໍ່ພຽງແຕ່ #N/A, ໃຊ້ VLOOKUP ປະສົມປະສານກັບຟັງຊັນ IFERROR. ລາຍລະອຽດເພີ່ມເຕີມສາມາດພົບໄດ້ທີ່ນີ້: IFERRORVLOOKUP ໃນ Excel.

Excel Vlookup: ຖ້າບໍ່ພົບຜົນຕອບແທນ 0

ເມື່ອເຮັດວຽກກັບຄ່າຕົວເລກ, ທ່ານອາດຈະຕ້ອງການສົ່ງຄ່າສູນເມື່ອບໍ່ພົບຄ່າການຊອກຫາ. ເພື່ອໃຫ້ມັນເຮັດໄດ້, ໃຊ້ສູດ IF ISNA VLOOKUP ທີ່ໄດ້ກ່າວມາຂ້າງເທິງດ້ວຍການດັດແກ້ເລັກນ້ອຍ: ແທນທີ່ຈະເປັນຂໍ້ຄວາມ, ສະຫນອງ 0 ໃນ argument value_if_true ຂອງຟັງຊັນ IF:

ໃນຕາຕະລາງຕົວຢ່າງຂອງພວກເຮົາ, ສູດຈະໄປດັ່ງນີ້:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

ໃນ ຮຸ່ນຫຼ້າສຸດຂອງ Excel 2016 ແລະ 2013, ທ່ານສາມາດນໍາໃຊ້ການປະສົມປະສານ IFNA Vlookup ອີກເທື່ອຫນຶ່ງ:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: ຖ້າບໍ່ພົບການສົ່ງຄືນຕາລາງຫວ່າງເປົ່າ

ນີ້ແມ່ນຫນຶ່ງການປ່ຽນແປງເພີ່ມເຕີມ ຂອງຄໍາຖະແຫຼງ "Vlookup if then": ກັບຄືນບໍ່ມີຫຍັງເມື່ອຄ່າຄົ້ນຫາບໍ່ພົບ. ເພື່ອເຮັດສິ່ງນີ້, ແນະນໍາສູດຂອງທ່ານໃຫ້ກັບຄືນ string ຫວ່າງເປົ່າ ("") ແທນຄວາມຜິດພາດ #N/A:

ຂ້າງລຸ່ມນີ້ ເປັນຕົວຢ່າງຂອງສູດສົມບູນສອງສາມຢ່າງ:

ສຳລັບທຸກລຸ້ນ Excel:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

ສຳລັບ Excel 2016 ແລະ Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

ຖ້າມີ Index Match - ຊ້າຍ vlookup ກັບເງື່ອນໄຂ If

ຜູ້ໃຊ້ Excel ທີ່ມີປະສົບການຮູ້ວ່າຟັງຊັນ VLOOKUP ບໍ່ແມ່ນວິທີດຽວທີ່ຈະເຮັດການຊອກຫາແນວຕັ້ງໃນ Excel. ການປະສົມປະສານຂອງ INDEX MATCH ຍັງສາມາດຖືກນໍາໃຊ້ເພື່ອຈຸດປະສົງນີ້ແລະມັນມີປະສິດທິພາບຫຼາຍແລະມີຄວາມຫລາກຫລາຍ. ຂ່າວດີແມ່ນວ່າ Index Match ສາມາດເຮັດວຽກຮ່ວມກັນກັບ IF ​​ໃນລັກສະນະດຽວກັນກັບVlookup.

ຕົວຢ່າງ, ທ່ານມີຕົວເລກການສັ່ງຊື້ຢູ່ໃນຖັນ A ແລະຊື່ຜູ້ຂາຍໃນຖັນ B. ທ່ານກຳລັງຊອກຫາສູດເພື່ອດຶງຕົວເລກການສັ່ງຊື້ຂອງຜູ້ຂາຍສະເພາະ.

Vlookup ບໍ່ສາມາດເປັນ ໃຊ້ໃນກໍລະນີນີ້ເນື່ອງຈາກວ່າມັນບໍ່ສາມາດຄົ້ນຫາຈາກຂວາຫາຊ້າຍ. Index Match ຈະເຮັດວຽກໂດຍບໍ່ມີບັນຫາຕາບໃດທີ່ຄ່າຊອກຫາຢູ່ໃນຖັນຊອກຫາ. ຖ້າບໍ່ແມ່ນ, ຂໍ້ຜິດພາດ #N/A ຈະປາກົດຂຶ້ນ. ເພື່ອແທນທີ່ຫມາຍຄວາມຜິດພາດມາດຕະຖານດ້ວຍຂໍ້ຄວາມຂອງທ່ານເອງ, ວາງ Index Match ພາຍໃນ IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

ໃນ Excel 2016 ແລະ 2016, ທ່ານສາມາດນໍາໃຊ້ IFNA ແທນ IF ISNA ເພື່ອເຮັດໃຫ້ສູດເພີ່ມເຕີມ compact:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

ໃນລັກສະນະທີ່ຄ້າຍຄືກັນ, ທ່ານສາມາດນໍາໃຊ້ Index Match ໃນສູດ If ອື່ນໆ.

ນີ້ແມ່ນວິທີທີ່ທ່ານໃຊ້ Vlookup ແລະຄໍາຖະແຫຼງ IF ຮ່ວມກັນໃນ Excel. ເພື່ອໃຫ້ໄດ້ເບິ່ງທີ່ໃກ້ຊິດຢູ່ໃນສູດທີ່ໄດ້ປຶກສາຫາລືໃນບົດສອນນີ້, ທ່ານຍິນດີທີ່ຈະດາວໂຫລດປື້ມຄູ່ມືຂອງພວກເຮົາຂ້າງລຸ່ມນີ້. ຂ້າພະເຈົ້າຂໍຂອບໃຈທ່ານສໍາລັບການອ່ານແລະຫວັງວ່າຈະໄດ້ພົບທ່ານໃນ blog ຂອງພວກເຮົາໃນອາທິດຕໍ່ໄປ!

ປື້ມຄູ່ມືການປະຕິບັດສໍາລັບການດາວໂຫຼດ

Excel IF Vlookup - ຕົວຢ່າງສູດ (ໄຟລ໌ .xlsx)