သင်ခန်းစာတွင် V LOOKUP နှင့် IF လုပ်ဆောင်ချက်ကို Excel တွင် if condition ဖြင့် v-lookup ပြုလုပ်ရန် သင်ခန်းစာတွင် ပြသထားသည်။ #N/A အမှားများကို သင့်ကိုယ်ပိုင်စာသား၊ သုည သို့မဟုတ် ဆဲလ်အလွတ်ဖြင့် အစားထိုးရန် IF ISNA VLOOKUP ဖော်မြူလာများကို မည်ကဲ့သို့ အသုံးပြုရမည်ကို သင်လည်း လေ့လာနိုင်ပါသည်။

VLOOKUP နှင့် IF လုပ်ဆောင်ချက်များသည် ၎င်းတို့ကိုယ်တိုင် အသုံးဝင်သော်လည်း အတူတကွ၊ သူတို့က ပိုတန်ဖိုးရှိတဲ့ အတွေ့အကြုံတွေကို ပေးတယ်။ ဤသင်ခန်းစာတွင် သင်သည် လုပ်ဆောင်ချက်နှစ်ခု၏ syntax ကို ကောင်းစွာမှတ်သားထားသည်ဟု ဆိုလိုသည်၊ သို့မဟုတ်ပါက သင်သည် အထက်ဖော်ပြပါလင့်ခ်များကို လိုက်နာခြင်းဖြင့် သင့်အသိပညာကို ဖြုန်းတီးပစ်ချင်ပေမည်။

If statement ဖြင့် ကြည့်ရှုပါ- return True/ မှားသည်၊ ဟုတ်သည်/မဟုတ် စသည်တို့ဖြစ်သည်။

If နှင့် Vlookup တို့ကို ပေါင်းစပ်လိုက်သောအခါ အဖြစ်များဆုံးအခြေအနေတစ်ခုမှာ Vlookup မှပြန်ပေးသောတန်ဖိုးကို နမူနာတန်ဖိုးတစ်ခုဖြင့် နှိုင်းယှဉ်ကာ Yes/No သို့မဟုတ် ရလဒ်အနေဖြင့် True/False ။

အများစုတွင်၊ အောက်ပါအထွေထွေဖော်မြူလာသည် ကောင်းမွန်စွာအလုပ်လုပ်နိုင်သည်-

ရိုးရိုးအင်္ဂလိပ်ဘာသာဖြင့် ဘာသာပြန်ထားသော၊ Vlookup သည် မှန်ပါက၊ Excel မှ True သို့ ပြန်သွားရန် ပုံသေနည်းက ညွှန်ကြားသည် (ဆိုလိုသည်မှာ သတ်မှတ်ထားသောတန်ဖိုးနှင့် ညီမျှသည်)။ Vlookup သည် မှားယွင်းနေပါက (သတ်မှတ်ထားသောတန်ဖိုးနှင့် ညီမျှခြင်းမရှိပါ)၊ ဖော်မြူလာသည် False သို့ ပြန်ပို့ပေးပါသည်။

အောက်တွင် ဤ IF Vlookup ဖော်မြူလာ၏ လက်တွေ့ဘဝအသုံးပြုမှုအချို့ကို သင်တွေ့လိမ့်မည်။

ဥပမာ 1။ တိကျသောတန်ဖိုးကိုရှာဖွေပါ

ဆိုပါစို့၊ သင့်တွင် ကော်လံ A နှင့် ကော်လံ B တွင် အရေအတွက်ရှိသောအရာများစာရင်းရှိသည်။ သင်သည် သင်၏အသုံးပြုသူများအတွက် ဒက်ရှ်ဘုတ်တစ်ခုဖန်တီးနေပြီး ဖော်မြူလာတစ်ခုလိုအပ်ပါသည်။E1 ရှိ ပစ္စည်းတစ်ခုအတွက် အရေအတွက်ကို စစ်ဆေးပြီး ပစ္စည်းလက်ကျန်ရှိမရှိ သို့မဟုတ် ရောင်းကုန်ရှိမရှိ သုံးစွဲသူအား အသိပေးပါမည်။

သင်သည် ဤကဲ့သို့သော အတိအကျကိုက်ညီသော ဖော်မြူလာဖြင့် ပုံမှန် Vlookup ဖြင့် အရေအတွက်ကို ဆွဲထုတ်သည်-

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

ထို့နောက်၊ Vlookup ၏ရလဒ်ကို သုညနှင့်နှိုင်းယှဉ်ပြီး 0 နှင့် ညီမျှပါက "Yes" မဟုတ်ပါက-

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

Yes/No အစား၊ သင်သည် TRUE/FALSE သို့မဟုတ် In Stock/Sold out သို့မဟုတ် အခြားနှစ်ခုကို ပြန်ပေးနိုင်ပါသည်။ ရွေးချယ်မှုများ။ ဥပမာ-

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

သင် Vlookup မှပြန်ပေးသောတန်ဖိုးကို နမူနာ စာသား နှင့်လည်း နှိုင်းယှဉ်နိုင်သည်။ ဤကိစ္စတွင်၊ ဤကဲ့သို့သော quotation အမှတ်အသားများတွင် စာသားစာကြောင်းတစ်ကြောင်းကို သေချာစွာထည့်သွင်းပါ-

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

ဥပမာ 2. Vlookup ရလဒ်ကို အခြားဆဲလ်တစ်ခုနှင့် နှိုင်းယှဉ်ပါ

အခြားပုံမှန်ဥပမာတစ်ခုဖြစ်သည်။ Excel ရှိ If condition ဖြင့် Vlookup သည် အခြားဆဲလ်ရှိ တန်ဖိုးတစ်ခုနှင့် Vlookup အထွက်ကို နှိုင်းယှဉ်နေသည်။ ဥပမာအားဖြင့်၊ ၎င်းသည် ဆဲလ် G2 ရှိ နံပါတ်တစ်ခုထက် ကြီးသည် သို့မဟုတ် ညီမျှခြင်း ရှိမရှိ စစ်ဆေးနိုင်သည်-

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

ထို့ပြင် ဤအရာသည် ကျွန်ုပ်တို့၏ Vlookup ဖြင့် လုပ်ဆောင်နေသည့် If ဖော်မြူလာဖြစ်သည်-

အလားတူပုံစံဖြင့်၊ သင်သည် သင်၏ Excel ရှိလျှင် Vlookup ဖော်မြူလာရှိ ဆဲလ်ကိုးကားမှုနှင့်အတူ အခြားယုတ္တိအော်ပရေတာတစ်ခုခုကို အသုံးပြုနိုင်သည်။

ဥပမာ 3. ပိုတိုသောစာရင်းရှိ Vlookup တန်ဖိုးများ

ပစ်မှတ်ကော်လံရှိ ဆဲလ်တစ်ခုစီကို အခြားစာရင်းတစ်ခုနှင့် နှိုင်းယှဉ်ရန်နှင့် ကိုက်ညီမှုတစ်ခုတွေ့ရှိပါက True သို့မဟုတ် Yes သို့ ပြန်သွားရန်၊ False သို့မဟုတ် No မဟုတ်ပါက၊ ဤယေဘုယျ IF ISNA VLOOKUP ဖော်မြူလာကို အသုံးပြုပါ-

Vlookup သည် #N/A error ဖြစ်ပါက၊ formula သည် "No" ဖြင့် ပြန်တက်လာသည် ဆိုလိုသည်မှာ lookup value ကို lookup list တွင်မတွေ့ပါ။ ပွဲတွေ့ပါက "Yes" ကို ပြန်ပေးသည်။ ဥပမာ-

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

သင့်လုပ်ငန်း၏ ယုတ္တိဗေဒသည် ဆန့်ကျင်ဘက်ရလဒ်များ လိုအပ်ပါက ဖော်မြူလာ၏ ယုတ္တိကို ပြောင်းပြန်လှန်ရန် "Yes" နှင့် "No" ကို လဲလှယ်လိုက်ပါ-

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel အကယ်၍ မတူညီသော တွက်ချက်မှုများကို လုပ်ဆောင်ရန် Vlookup ဖော်မြူလာ

သင့်ကိုယ်ပိုင် စာသားမက်ဆေ့ချ်များကို ပြသခြင်းအပြင်၊ Vlookup ဖြင့် လုပ်ဆောင်ချက်များသည် မတူညီသော တွက်ချက်မှုများကို လုပ်ဆောင်နိုင်လျှင်၊ သင်သတ်မှတ်ထားသော စံနှုန်းများအပေါ် အခြေခံထားသည်။

ကျွန်ုပ်တို့၏ဥပမာကို ယူပြီး၊ ၎င်းတို့၏ ထိရောက်မှုအပေါ် မူတည်၍ တိကျသောရောင်းချသူ (F1) ၏ ကော်မရှင်ခကို တွက်ချက်ကြည့်ကြပါစို့- $200 နှင့် ထို့ထက်ပိုသော သူများအတွက် 20% ကော်မရှင်၊ အခြားလူတိုင်းအတွက် 10% .

၎င်းအတွက်၊ Vlookup မှပြန်ပေးသောတန်ဖိုးသည် 200 ထက် ကြီးသည် သို့မဟုတ် ညီမျှခြင်း ရှိ၊ မရှိ စစ်ဆေးပြီး၊ ၎င်းဖြစ်လျှင် ၎င်းကို 20% နှင့် မြှောက်ပါ သို့မဟုတ် 10% ဖြင့် မြှောက်ပါ-

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

A2:A10 သည် ရောင်းသူအမည်များဖြစ်ပြီး C2:C10 သည် အရောင်းဖြစ်သည်။

#N/A အမှားများကို ဖုံးကွယ်ရန် ISNA VLOOKUP ဆိုလျှင်

VLOOKUP လုပ်ဆောင်ချက်သည် သတ်မှတ်ထားသောတန်ဖိုးကို ရှာမတွေ့ပါက၊ ၎င်းသည် #N/A အမှားအယွင်းတစ်ခု ဖြစ်သွားသည်။ ထိုအမှားကို ဖမ်းပြီး သင့်ကိုယ်ပိုင်စာသားဖြင့် အစားထိုးရန်၊ ဤကဲ့သို့သော IF လုပ်ဆောင်ချက်၏ ယုတ္တိစမ်းသပ်မှုတွင် Vlookup ဖော်မြူလာကို ထည့်သွင်းပါ-

ပုံမှန်အားဖြင့်၊ သင်သည် "မတွေ့ပါ။" အစား သင်နှစ်သက်သည့် မည်သည့်စာသားကိုမဆို ရိုက်ထည့်နိုင်သည်။

ဆိုပါစို့၊ သင့်တွင် ရောင်းသူစာရင်းရှိနေသည်။ကော်လံတစ်ခုရှိ အမည်များနှင့် အခြားကော်လံတစ်ခုရှိ အရောင်းပမာဏ။ သင်၏တာဝန်မှာ F1 တွင်အသုံးပြုသူထည့်သွင်းသောအမည်နှင့်သက်ဆိုင်သည့်နံပါတ်တစ်ခုကိုဆွဲထုတ်ရန်ဖြစ်သည်။ အမည်ကို ရှာမတွေ့ပါက၊ ညွှန်ပြသည့် မက်ဆေ့ချ်ကို ပြပါ။

A2:A10 တွင် အမည်များနှင့် ပမာဏ C2:C10 ဖြင့်၊ လုပ်ဆောင်စရာကို Vlookup ဖော်မြူလာဖြစ်လျှင် အောက်ပါအတိုင်း လုပ်ဆောင်နိုင်သည်-

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

အမည်ကို တွေ့ရှိပါက၊ သက်ဆိုင်ရာ အရောင်းပမာဏကို ပြန်ပေးသည်-

ရှာဖွေမှုတန်ဖိုးကို ရှာမတွေ့ပါက၊ မတွေ့ပါ #N/A အမှားအစား မက်ဆေ့ဂျ်ပေါ်လာသည်-

ဤဖော်မြူလာအလုပ်လုပ်ပုံ

ဖော်မြူလာ၏ယုတ္တိသည် အလွန်ရိုးရှင်းပါသည်- သင် ISNA လုပ်ဆောင်ချက်ကို အသုံးပြုသည် #N/A အမှားများအတွက် Vlookup ကိုစစ်ဆေးရန်။ အမှားအယွင်းတစ်ခုဖြစ်ပေါ်ပါက ISNA သည် TRUE ၊ မဟုတ်ပါက FALSE ပြန်လာမည်ဖြစ်သည်။ အထက်ဖော်ပြပါတန်ဖိုးများသည် IF လုပ်ဆောင်ချက်၏ ယုတ္တိစမ်းသပ်မှုသို့ သွားသည်၊ ၎င်းသည် အောက်ပါတို့ထဲမှ တစ်ခုကို လုပ်ဆောင်သည်-

• ယုတ္တိဗေဒစစ်ဆေးမှုသည် မှန်ကန်ပါက (#N/A အမှား)၊ သင့်မက်ဆေ့ဂျ်ကို ပြသမည်ဖြစ်သည်။
• ယုတ္တိဗေဒစမ်းသပ်မှုမှာ FALSE ဖြစ်ပါက (ရှာဖွေမှုတန်ဖိုးကို တွေ့ရှိသည်)၊ Vlookup သည် ပုံမှန်အတိုင်း ကိုက်ညီမှုကို ပြန်ပေးပါသည်။

IFNA VLOOKUP ဗားရှင်းအသစ်တွင် Excel ဗားရှင်းအသစ်

Excel 2013 မှအစ၊ သင်သည်၊ #N/A အမှားများကို ဖမ်းရန်နှင့် ကိုင်တွယ်ရန် IFNA အစား IFNA လုပ်ဆောင်ချက်ကို သုံးနိုင်သည်-

ကျွန်ုပ်တို့၏ ဥပမာတွင်၊ ဖော်မြူလာသည် အောက်ပါပုံသဏ္ဍာန်ကို ယူပါ-

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

အကြံပြုချက်။ #N/A သာမဟုတ်ဘဲ အမှားမျိုးစုံကို ထောင်ဖမ်းချင်ရင် IFERROR လုပ်ဆောင်ချက်နဲ့ VLOOKUP ကိုသုံးပါ။ နောက်ထပ်အသေးစိတ်အချက်အလက်များကို ဤနေရာတွင် တွေ့နိုင်သည်- IFERRORExcel တွင် VLOOKUP။

Excel Vlookup- 0

ပြန်ရှာမတွေ့ပါက ဂဏန်းတန်ဖိုးများနှင့် အလုပ်လုပ်သောအခါ၊ ရှာဖွေမှုတန်ဖိုးကို ရှာမတွေ့သောအခါ သုညတစ်ခု ပြန်ပေးလိုပေမည်။ ၎င်းကိုလုပ်ဆောင်ရန်၊ အထက်တွင်ဖော်ပြထားသော ပြောင်းလဲမှုအနည်းငယ်ဖြင့် IF ISNA VLOOKUP ဖော်မြူလာကို အသုံးပြုပါ- စာသားမက်ဆေ့ချ်အစား IF လုပ်ဆောင်ချက်၏ value_if_true အငြင်းအခုံတွင် 0 ကို ပေးဆောင်ပါ-

ကျွန်ုပ်တို့၏နမူနာဇယားတွင်၊ ဖော်မြူလာမှာ အောက်ပါအတိုင်းဖြစ်သည်-

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

ထဲတွင် Excel 2016 နှင့် 2013 ၏ မကြာသေးမီဗားရှင်းများ၊ IFNA Vlookup ပေါင်းစပ်မှုကို သင် ထပ်မံအသုံးပြုနိုင်ပါသည်-

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup- မတွေ့ပါက ဆဲလ်ဗလာကို ပြန်ပေး

ဤသည် နောက်ထပ်တစ်မျိုးဖြစ်သည်။ "Vlookup if then" ၏ ဖော်ပြချက်- ရှာဖွေမှုတန်ဖိုးကို ရှာမတွေ့သောအခါ မည်သည့်အရာကိုမျှ ပြန်မပေးပါ။ ဒါကိုလုပ်ဖို့၊ #N/A အမှားအစား အလွတ်စာကြောင်း ("") ကို ပြန်ပေးဖို့ သင့်ဖော်မြူလာကို ညွှန်ကြားပါ-

အောက်ပါ ပြီးပြည့်စုံသော ဖော်မြူလာနမူနာ အချို့မှာ-

Excel ဗားရှင်းအားလုံးအတွက်-

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 နှင့် Excel 2013 အတွက်-

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

အညွှန်းနှင့်ကိုက်ညီပါက - If condition ဖြင့် left vlookup

အတွေ့အကြုံရှိ Excel အသုံးပြုသူများသည် VLOOKUP လုပ်ဆောင်ချက်သည် Excel တွင် ဒေါင်လိုက်ကြည့်ရှုရန် တစ်ခုတည်းသောနည်းလမ်းမဟုတ်ကြောင်း သိပါသည်။ INDEX MATCH ပေါင်းစပ်မှုကိုလည်း ဤရည်ရွယ်ချက်အတွက် အသုံးပြုနိုင်ပြီး ၎င်းသည် ပိုမိုအားကောင်းပြီး စွယ်စုံရရှိသည်။ သတင်းကောင်းမှာ Index Match သည် IF နှင့် တူညီသောနည်းလမ်းဖြင့် အတူတူအလုပ်လုပ်နိုင်သည်Vlookup။

ဥပမာ၊ သင့်တွင် ကော်လံ A တွင် အမှာစာနံပါတ်များ နှင့် ကော်လံ B တွင် ရောင်းချသူအမည်များရှိသည်။ တိကျသောရောင်းချသူအတွက် အမှာစာနံပါတ်ကိုဆွဲယူရန် ဖော်မြူလာကို သင်ရှာဖွေနေပါသည်။

Vlookup မလုပ်နိုင်ပါ။ ညာမှဘယ်သို့မရှာဖွေနိုင်သောကြောင့် ဤကိစ္စတွင်အသုံးပြုသည်။ ရှာဖွေမှုကော်လံတွင် ရှာဖွေမှုတန်ဖိုးကို တွေ့ရှိသရွေ့ Index Match သည် အထစ်အငေါ့မရှိဘဲ အလုပ်လုပ်ပါမည်။ မဟုတ်ပါက #N/A error ပေါ်လာပါမည်။ စံအမှားအမှတ်အသားကို သင့်ကိုယ်ပိုင်စာသားဖြင့် အစားထိုးရန်၊ IF ISNA အတွင်းရှိ အညွှန်းကိန်းတူညီမှုကို အသိုက်ပြုလုပ်ပါ-

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Excel 2016 နှင့် 2016 တွင်၊ ဖော်မြူလာပိုမိုပြုလုပ်ရန် IF ISNA အစား IFNA ကို သင်အသုံးပြုနိုင်ပါသည်။ သေးငယ်သည်-

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

အလားတူအားဖြင့်၊ သင်သည် အခြားသော If ဖော်မြူလာများတွင် Index Match ကိုသုံးနိုင်သည်။

ဤသည်မှာ သင်အသုံးပြုပုံဖြစ်သည်။ Vlookup နှင့် IF ကြေညာချက်ကို Excel တွင် တွဲထားသည်။ ဤသင်ခန်းစာတွင် ဆွေးနွေးထားသော ဖော်မြူလာများကို အနီးကပ်ကြည့်ရှုရန်၊ အောက်တွင် ကျွန်ုပ်တို့၏ နမူနာအလုပ်စာအုပ်ကို ဒေါင်းလုဒ်လုပ်ပါ။ ကျွန်ုပ်တို့၏ဘလော့ဂ်တွင် ဖတ်ရှုပြီး နောက်အပတ်တွင် ဆုံတွေ့ခွင့်ရရန် မျှော်လင့်ခြင်းအတွက် ကျေးဇူးတင်ပါသည်။

ဒေါင်းလုဒ်လုပ်ရန် လေ့ကျင့်ခန်းစာအုပ်

Excel IF Vlookup - ဖော်မြူလာနမူနာများ (.xlsx ဖိုင်)