Mae'r tiwtorial yn dangos sut i gyfuno swyddogaeth V LOOKUP ac IF gyda'i gilydd i v-lookup ag os cyflwr yn Excel. Byddwch hefyd yn dysgu sut i ddefnyddio fformiwlâu IF ISNA VLOOKUP i ddisodli # N/A gwallau gyda'ch testun eich hun, sero neu gell wag.

Tra bod y swyddogaethau VLOOKUP ac IF yn ddefnyddiol ar eu pen eu hunain, gyda'i gilydd maent yn darparu profiadau mwy gwerthfawr fyth. Mae'r tiwtorial hwn yn awgrymu eich bod yn cofio cystrawen y ddwy ffwythiant yn dda, neu efallai y byddwch am loywi eich gwybodaeth drwy ddilyn y dolenni uchod. Anghywir, Ydw/Nac ydw, ac ati.

Un o'r senarios mwyaf cyffredin pan fyddwch chi'n cyfuno If a Vlookup gyda'i gilydd yw cymharu'r gwerth a ddychwelwyd gan Vlookup gyda gwerth sampl a dychwelyd Yes / Na neu Gwir / Gau fel y canlyniad.

Yn y rhan fwyaf o achosion, byddai'r fformiwla generig ganlynol yn gweithio'n dda:

Wedi'i chyfieithu mewn Saesneg clir, mae'r fformiwla yn cyfarwyddo Excel i ddychwelyd Gwir os yw Vlookup yn wir (h.y. hafal i'r gwerth penodedig). Os yw Vlookup yn ffug (ddim yn hafal i'r gwerth penodedig), mae'r fformiwla yn dychwelyd Gau .

Isod fe welwch ychydig o ddefnyddiau bywyd go iawn o'r fformiwla IF Vlookup hon.

Enghraifft 1. Chwiliwch am werth penodol

Dewch i ni ddweud, mae gennych restr o eitemau yng ngholofn A a nifer yng ngholofn B. Rydych yn creu dangosfwrdd ar gyfer eich defnyddwyr ac angen fformiwlaa fyddai'n gwirio maint eitem yn E1 ac yn hysbysu'r defnyddiwr a yw'r eitem mewn stoc neu wedi gwerthu allan.

Rydych yn tynnu'r swm gyda Vlookup rheolaidd gyda fformiwla gyfatebol union fel hyn:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Yna, ysgrifennwch ddatganiad IF sy'n cymharu canlyniad Vlookup â sero, ac yn dychwelyd "Na" os yw'n hafal i 0, "Ie" fel arall:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

Yn lle Ie/Nac ydw , gallwch ddychwelyd TRUE/FALSE neu Mewn Stoc/Wedi Gwerthu neu unrhyw ddau arall dewisiadau. Er enghraifft:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

Gallwch hefyd gymharu'r gwerth a ddychwelwyd gan Vlookup gyda sampl testun . Yn yr achos hwn, gofalwch eich bod yn amgáu llinyn testun mewn dyfynodau, fel hyn:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

Enghraifft 2. Cymharwch ganlyniad Vlookup â chell arall

Enghraifft nodweddiadol arall o Mae cyflwr Vlookup ag Os yn Excel yn cymharu allbwn Vlookup â gwerth mewn cell arall. Er enghraifft, gallwn wirio a yw'n fwy na neu'n hafal i rif yng nghell G2:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

A dyma ein fformiwla If gyda Vlookup ar waith:

13>

Yn yr un modd, gallwch ddefnyddio unrhyw weithredwr rhesymegol arall ynghyd â chyfeirnod cell yn eich fformiwla Excel If Vlookup.

Enghraifft 3. Gwerthoedd Vlookup mewn rhestr fyrrach

I gymharu pob cell yn y golofn darged â rhestr arall a dychwelyd Gwir neu Ie os canfyddir cyfatebiaeth, Anghywir neu Na fel arall, defnyddiwch y fformiwla generig IF ISNA VLOOKUP:

Os yw Vlookup yn arwain at y gwall # N/A, mae'r fformiwla yn dychwelyd "Na", sy'n golygu nad yw'r gwerth chwilio i'w gael yn y rhestr chwilio. Os canfyddir y cydweddiad, dychwelir "Ie". Er enghraifft:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

Os yw rhesymeg eich busnes yn gofyn am y canlyniadau cyferbyniol, cyfnewidiwch "Ie" a "Na" i wrthdroi rhesymeg y fformiwla:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Ar wahân i ddangos eich negeseuon testun eich hun, Os gall swyddogaeth gyda Vlookup wneud cyfrifiadau gwahanol yn seiliedig ar y meini prawf rydych chi'n eu nodi.

Gan gymryd ein hesiampl ymhellach, gadewch i ni gyfrifo comisiwn gwerthwr penodol (F1) yn dibynnu ar ei effeithiolrwydd: comisiwn o 20% i'r rhai a wnaeth $200 a mwy, 10% i bawb arall .

Ar gyfer hyn, rydych yn gwirio a yw'r gwerth a ddychwelwyd gan Vlookup yn fwy na neu'n hafal i 200, ac os ydyw, lluoswch ef ag 20%, fel arall â 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Lle mae A2:A10 yn enwau gwerthwyr a C2:C10 yn werthiannau.

OS YW ISNA VLOOKUP i guddio # gwallau Dd/G

Os na all y swyddogaeth VLOOKUP ddod o hyd i werth penodol, mae'n taflu gwall # N/A. I ddal y gwall hwnnw a rhoi eich testun eich hun yn ei le, mewnosodwch fformiwla Vlookup ym mhrawf rhesymegol y swyddogaeth IF, fel hyn:

Yn naturiol, gallwch deipio unrhyw destun yr ydych yn ei hoffi yn lle "Heb ei ganfod".

Gan dybio, mae gennych restr o'r gwerthwrenwau mewn un golofn a symiau gwerthiant mewn colofn arall. Eich tasg yw tynnu rhif sy'n cyfateb i'r enw y mae'r defnyddiwr yn ei nodi yn F1. Os na chanfyddir yr enw, dangoswch neges yn nodi hynny.

Gyda'r enwau yn A2:A10 a'r symiau C2:C10, gellir cyflawni'r dasg gyda'r fformiwla If Vlookup a ganlyn:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

Os canfyddir yr enw, dychwelir swm gwerthiant cyfatebol:

Os na ddarganfyddir y gwerth chwilio, mae'r Heb ganfod neges yn ymddangos yn lle'r gwall # N/A:

Sut mae'r fformiwla hon yn gweithio

Mae rhesymeg y fformiwla yn syml iawn: rydych chi'n defnyddio'r ffwythiant ISNA i wirio Vlookup am # wallau N/A. Os bydd gwall, mae ISNA yn dychwelyd TRUE, fel arall ANGHYWIR. Mae'r gwerthoedd uchod yn mynd i brawf rhesymegol y ffwythiant IF, sy'n gwneud un o'r canlynol:

• Os yw'r prawf rhesymegol yn WIR (gwall # N/A), dangosir eich neges.<20
• Os yw'r prawf rhesymegol yn ANGHYWIR (canfyddir gwerth chwilio), mae Vlookup yn dychwelyd matsien fel arfer.

IFNA VLOOKUP mewn fersiynau Excel mwy diweddar

Gan ddechrau gydag Excel 2013, chi yn gallu defnyddio'r ffwythiant IFNA yn lle IF ISNA i ddal a thrin gwallau # N/A:

Yn ein hesiampl, byddai'r fformiwla cymerwch y siâp canlynol:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

Awgrym. Os hoffech chi ddal pob math o wallau, nid yn unig #N/A, defnyddiwch VLOOKUP ar y cyd â'r swyddogaeth IFERROR. Ceir rhagor o fanylion yma: IFERRORVLOOKUP yn Excel.

Excel Vlookup: os na chanfyddir dychweliad 0

Wrth weithio gyda gwerthoedd rhifiadol, efallai y byddwch am ddychwelyd sero pan na chanfyddir y gwerth chwilio. I'w wneud, defnyddiwch y fformiwla IF ISNA VLOOKUP a drafodwyd uchod gydag ychydig o addasiad: yn lle neges destun, rhowch 0 yn arg value_if_true y ffwythiant IF:

Yn ein tabl sampl, byddai'r fformiwla yn mynd fel a ganlyn:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Yn y fersiynau diweddar o Excel 2016 a 2013, gallwch ddefnyddio'r cyfuniad IFNA Vlookup eto:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: os na chaiff ei ganfod, dychwelwch gell wag

Dyma un amrywiad arall o'r datganiad "Vlookup os felly": dychwelwch ddim pan na chanfyddir y gwerth chwilio. I wneud hyn, dywedwch wrth eich fformiwla i ddychwelyd llinyn gwag ("") yn lle'r gwall # N/A:

Isod yn ychydig o enghreifftiau fformiwla cyflawn:

Ar gyfer pob fersiwn Excel:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Ar gyfer Excel 2016 ac Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

Os gyda Index Match - vlookup chwith gyda Os cyflwr

Mae defnyddwyr Excel profiadol yn gwybod nad swyddogaeth VLOOKUP yw'r unig ffordd i wneud chwiliad fertigol yn Excel. Gellir defnyddio'r cyfuniad INDEX MATCH hefyd at y diben hwn ac mae hyd yn oed yn fwy pwerus ac amlbwrpas. Y newyddion da yw y gall Index Match gydweithio ag IF yn union yr un ffordd agVlookup.

Er enghraifft, mae gennych rifau archeb yng ngholofn A ac enwau gwerthwyr yng ngholofn B. Rydych yn chwilio am fformiwla i dynnu'r rhif archeb ar gyfer gwerthwr penodol.

Ni all Vlookup fod a ddefnyddir yn yr achos hwn oherwydd ni all chwilio o'r dde i'r chwith. Bydd Index Match yn gweithio heb gyfyngiad cyn belled â bod y gwerth chwilio i'w gael yn y golofn chwilio. Os na, bydd gwall #D/A yn ymddangos. I ddisodli'r nodiant gwall safonol gyda'ch testun eich hun, nyth Index Match y tu mewn i IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Yn Excel 2016 a 2016, gallwch ddefnyddio IFNA yn lle IF ISNA i wneud y fformiwla yn fwy compact:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

Yn yr un modd, gallwch ddefnyddio Index Match mewn fformiwlâu If eraill.

Dyma sut rydych chi'n defnyddio Datganiad Vlookup ac IF gyda'i gilydd yn Excel. I gael golwg agosach ar y fformiwlâu a drafodir yn y tiwtorial hwn, mae croeso i chi lawrlwytho ein gweithlyfr enghreifftiol isod. Diolch i chi am ddarllen a gobeithio eich gweld ar ein blog wythnos nesaf!

Gweithlyfr ymarfer i'w lawrlwytho

Excel IF Vlookup - enghreifftiau fformiwla (ffeil .xlsx)