ట్యుటోరియల్ V LOOKUP మరియు IF ఫంక్షన్‌లను కలిసి v-lookupకి ఎక్సెల్‌లో if కండిషన్‌తో ఎలా కలపాలో చూపిస్తుంది. మీ స్వంత వచనం, సున్నా లేదా ఖాళీ సెల్‌తో #N/A లోపాలను భర్తీ చేయడానికి IF ISNA VLOOKUP సూత్రాలను ఎలా ఉపయోగించాలో కూడా మీరు నేర్చుకుంటారు.

VLOOKUP మరియు IF ఫంక్షన్‌లు వాటి స్వంతంగా ఉపయోగపడతాయి. వారు మరింత విలువైన అనుభవాలను అందిస్తారు. ఈ ట్యుటోరియల్ మీకు రెండు ఫంక్షన్‌ల సింటాక్స్ బాగా గుర్తుందని సూచిస్తుంది, లేకుంటే పై లింక్‌లను అనుసరించడం ద్వారా మీరు మీ జ్ఞానాన్ని పెంచుకోవచ్చు.

Vlookup with Statement: return True/ తప్పు, అవును/కాదు మొదలైనవి.

మీరు If మరియు Vlookup కలిపినప్పుడు అత్యంత సాధారణ దృశ్యాలలో ఒకటి Vlookup ద్వారా అందించబడిన విలువను నమూనా విలువతో సరిపోల్చడం మరియు అవును / కాదు ని అందించడం. లేదా నిజం / తప్పు ఫలితంగా.

చాలా సందర్భాలలో, కింది సాధారణ సూత్రం చక్కగా పని చేస్తుంది:

సాదా ఆంగ్లంలో అనువదించబడింది, Vlookup ఒప్పు అయితే (అంటే పేర్కొన్న విలువకు సమానం) True ని అందించమని ఫార్ములా Excelని నిర్దేశిస్తుంది. Vlookup తప్పు అయితే (పేర్కొన్న విలువకు సమానం కాదు), ఫార్ములా False ని అందిస్తుంది.

క్రింద మీరు ఈ IF Vlookup ఫార్ములా యొక్క కొన్ని నిజ జీవిత ఉపయోగాలను కనుగొంటారు.

ఉదాహరణ 1. నిర్దిష్ట విలువను శోధించండి

అనుకుందాం, మీరు కాలమ్ Aలో అంశాల జాబితా మరియు కాలమ్ Bలో పరిమాణం కలిగి ఉన్నారు. మీరు మీ వినియోగదారుల కోసం డాష్‌బోర్డ్‌ను సృష్టిస్తున్నారు మరియు ఫార్ములా అవసరంఅది E1లో వస్తువు యొక్క పరిమాణాన్ని తనిఖీ చేస్తుంది మరియు అంశం స్టాక్‌లో ఉందా లేదా విక్రయించబడిందా అనే విషయాన్ని వినియోగదారుకు తెలియజేస్తుంది.

మీరు ఇలాంటి ఖచ్చితమైన మ్యాచ్ ఫార్ములాతో సాధారణ Vlookupతో పరిమాణాన్ని లాగండి:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

తర్వాత, Vlookup యొక్క ఫలితాన్ని సున్నాతో పోల్చి IF స్టేట్‌మెంట్‌ను వ్రాయండి మరియు అది 0కి సమానం అయితే "No"ని అందిస్తుంది, లేకపోతే "అవును":

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

అవును/కాదు కి బదులుగా, మీరు ఒప్పు/తప్పు లేదా ఇన్ స్టాక్/సోల్డ్ అవుట్ లేదా ఏదైనా ఇతర రెండు ఎంపికలు. ఉదాహరణకు:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

మీరు Vlookup ద్వారా అందించబడిన విలువను నమూనా టెక్స్ట్ తో కూడా పోల్చవచ్చు. ఈ సందర్భంలో, కొటేషన్ మార్కులలో టెక్స్ట్ స్ట్రింగ్‌ను జతచేయాలని నిర్ధారించుకోండి, ఇలా:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

ఉదాహరణ 2. Vlookup ఫలితాన్ని మరొక సెల్‌తో పోల్చండి

దీని యొక్క మరొక సాధారణ ఉదాహరణ Excelలోని If కండిషన్‌తో Vlookup అనేది Vlookup అవుట్‌పుట్‌ను మరొక సెల్‌లోని విలువతో పోల్చడం. ఉదాహరణకు, ఇది సెల్ G2లో సంఖ్య కంటే ఎక్కువ లేదా సమానంగా ఉందో లేదో తనిఖీ చేయవచ్చు:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

మరియు ఇక్కడ Vlookupతో మా ఫార్ములా ఉంది:

అదే పద్ధతిలో, మీరు మీ Excel If Vlookup ఫార్ములాలో సెల్ రిఫరెన్స్‌తో పాటు ఏదైనా ఇతర లాజికల్ ఆపరేటర్‌ని ఉపయోగించవచ్చు.

ఉదాహరణ 3. చిన్న జాబితాలో Vlookup విలువలు

లక్ష్య నిలువు వరుసలోని ప్రతి గడిని మరొక జాబితాతో సరిపోల్చడానికి మరియు ఒప్పు లేదా అవును సరిపోలిక కనుగొనబడితే, తప్పు లేదా కాదు లేకపోతే, ఈ సాధారణ IF ISNA VLOOKUP సూత్రాన్ని ఉపయోగించండి:

Vlookup ఫలితంగా #N/A ఎర్రర్ ఏర్పడితే, ఫార్ములా "నో"ని అందిస్తుంది, అంటే శోధన విలువ శోధన జాబితాలో కనుగొనబడలేదు. మ్యాచ్ కనుగొనబడితే, "అవును" తిరిగి ఇవ్వబడుతుంది. ఉదాహరణకు:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

మీ వ్యాపార లాజిక్‌కు వ్యతిరేక ఫలితాలు అవసరమైతే, ఫార్ములా లాజిక్‌ను రివర్స్ చేయడానికి "అవును" మరియు "లేదు"ని మార్చుకోండి:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel ఉంటే Vlookup ఫార్ములా విభిన్న గణనలను నిర్వహించడానికి

మీ స్వంత వచన సందేశాలను ప్రదర్శించడమే కాకుండా, Vlookupతో ఫంక్షన్ విభిన్న గణనలను చేయగలదు మీరు పేర్కొన్న ప్రమాణాల ఆధారంగా.

మా ఉదాహరణను మరింతగా తీసుకుంటే, నిర్దిష్ట విక్రేత (F1) ప్రభావాన్ని బట్టి వారి కమీషన్‌ను గణిద్దాం: $200 మరియు అంతకంటే ఎక్కువ సంపాదించిన వారికి 20% కమీషన్, మిగతా వారికి 10% .

దీని కోసం, మీరు Vlookup ద్వారా అందించబడిన విలువ 200 కంటే ఎక్కువ లేదా సమానంగా ఉందో లేదో తనిఖీ చేయండి మరియు అది ఉంటే, దానిని 20%తో గుణించండి, లేకపోతే 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

ఎక్కడ A2:A10 విక్రేత పేర్లు మరియు C2:C10 విక్రయాలు.

#N/A లోపాలను దాచడానికి ISNA VLOOKUP చేస్తే

VLOOKUP ఫంక్షన్ పేర్కొన్న విలువను కనుగొనలేకపోతే, అది #N/A లోపాన్ని విసురుతుంది. ఆ లోపాన్ని గుర్తించి, దాన్ని మీ స్వంత వచనంతో భర్తీ చేయడానికి, IF ఫంక్షన్ యొక్క లాజికల్ టెస్ట్‌లో Vlookup సూత్రాన్ని పొందుపరచండి, ఇలా:

సహజంగా, మీరు "కనుగొనబడలేదు"కి బదులుగా మీకు నచ్చిన ఏదైనా వచనాన్ని టైప్ చేయవచ్చు.

అనుకోండి, మీ వద్ద విక్రేత జాబితా ఉందిఒక కాలమ్‌లో పేర్లు మరియు మరొక కాలమ్‌లో అమ్మకాల మొత్తాలు. F1లో వినియోగదారు నమోదు చేసిన పేరుకు సంబంధించిన సంఖ్యను లాగడం మీ పని. పేరు కనుగొనబడకపోతే, అలా సూచించే సందేశాన్ని ప్రదర్శించండి.

A2:A10లోని పేర్లు మరియు C2:C10 మొత్తాలతో, కింది If Vlookup ఫార్ములాతో పనిని పూర్తి చేయవచ్చు:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

పేరు కనుగొనబడితే, సంబంధిత విక్రయ మొత్తం తిరిగి ఇవ్వబడుతుంది:

శోధన విలువ కనుగొనబడకపోతే, కనుగొనబడలేదు #N/A ఎర్రర్‌కు బదులుగా సందేశం కనిపిస్తుంది:

ఈ ఫార్ములా ఎలా పని చేస్తుంది

ఫార్ములా లాజిక్ చాలా సులభం: మీరు ISNA ఫంక్షన్‌ని ఉపయోగిస్తారు #N/A ఎర్రర్‌ల కోసం Vlookupని తనిఖీ చేయడానికి. లోపం సంభవించినట్లయితే, ISNA TRUEని అందిస్తుంది, లేకుంటే FALSE. పై విలువలు IF ఫంక్షన్ యొక్క తార్కిక పరీక్షకు వెళ్తాయి, ఇది కింది వాటిలో ఒకదానిని చేస్తుంది:

• లాజికల్ పరీక్ష TRUE అయితే (#N/A లోపం), మీ సందేశం ప్రదర్శించబడుతుంది.
• లాజికల్ పరీక్ష తప్పు అయితే (లుకప్ విలువ కనుగొనబడింది), Vlookup సాధారణంగా సరిపోలికను అందిస్తుంది.

కొత్త Excel వెర్షన్‌లలో IFNA VLOOKUP

Excel 2013తో ప్రారంభించి, మీరు #N/A లోపాలను పట్టుకోవడానికి మరియు నిర్వహించడానికి IF ISNAకి బదులుగా IFNA ఫంక్షన్‌ని ఉపయోగించవచ్చు:

మా ఉదాహరణలో, ఫార్ములా కింది ఆకారాన్ని తీసుకోండి:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

చిట్కా. మీరు #N/A మాత్రమే కాకుండా అన్ని రకాల లోపాలను ట్రాప్ చేయాలనుకుంటే, IFERROR ఫంక్షన్‌తో కలిపి VLOOKUPని ఉపయోగించండి. మరిన్ని వివరాలను ఇక్కడ చూడవచ్చు: IFERRORExcelలో VLOOKUP.

Excel Vlookup: కనుగొనబడకపోతే తిరిగి 0

సంఖ్యా విలువలతో పని చేస్తున్నప్పుడు, శోధన విలువ కనుగొనబడనప్పుడు మీరు సున్నాని తిరిగి ఇవ్వవచ్చు. దీన్ని పూర్తి చేయడానికి, పైన చర్చించిన IF ISNA VLOOKUP సూత్రాన్ని కొద్దిగా సవరణతో ఉపయోగించండి: వచన సందేశానికి బదులుగా, IF ఫంక్షన్ యొక్క value_if_true ఆర్గ్యుమెంట్‌లో 0ని అందించండి:

మా నమూనా పట్టికలో, సూత్రం క్రింది విధంగా ఉంటుంది:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

లో Excel 2016 మరియు 2013 యొక్క ఇటీవలి సంస్కరణలు, మీరు IFNA Vlookup కలయికను మళ్లీ ఉపయోగించవచ్చు:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: కనుగొనబడకపోతే ఖాళీ సెల్‌ను తిరిగి ఇవ్వండి

ఇది మరొక వైవిధ్యం "Vlookup if then" స్టేట్‌మెంట్: శోధన విలువ కనుగొనబడనప్పుడు ఏమీ ఇవ్వదు. దీన్ని చేయడానికి, #N/A ఎర్రర్‌కు బదులుగా ఖాళీ స్ట్రింగ్ ("")ని అందించమని మీ ఫార్ములాకు సూచించండి:

క్రింద కొన్ని పూర్తి ఫార్ములా ఉదాహరణలు:

అన్ని Excel వెర్షన్‌ల కోసం:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 మరియు Excel 2013 కోసం:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

ఇండెక్స్ మ్యాచ్‌తో ఉంటే - ఇఫ్ కండిషన్‌తో vlookup వదిలివేయండి

అనుభవజ్ఞులైన Excel వినియోగదారులకు VLOOKUP ఫంక్షన్ మాత్రమే Excelలో నిలువుగా చూసే మార్గం కాదని తెలుసు. ఈ ప్రయోజనం కోసం INDEX MATCH కలయికను కూడా ఉపయోగించవచ్చు మరియు ఇది మరింత శక్తివంతమైనది మరియు బహుముఖమైనది. శుభవార్త ఏమిటంటే, ఇండెక్స్ మ్యాచ్ సరిగ్గా అదే విధంగా IFతో కలిసి పని చేస్తుందిVlookup.

ఉదాహరణకు, మీరు A నిలువు వరుసలో ఆర్డర్ నంబర్‌లను మరియు B కాలమ్‌లో విక్రేత పేర్లను కలిగి ఉన్నారు. మీరు నిర్దిష్ట విక్రేత కోసం ఆర్డర్ నంబర్‌ని లాగడానికి ఫార్ములా కోసం చూస్తున్నారు.

Vlookup ఉండకూడదు ఈ సందర్భంలో ఉపయోగించబడింది ఎందుకంటే ఇది కుడి నుండి ఎడమకు శోధించదు. లుకప్ కాలమ్‌లో లుకప్ విలువ కనుగొనబడినంత వరకు ఇండెక్స్ మ్యాచ్ ఎటువంటి ఇబ్బంది లేకుండా పని చేస్తుంది. లేకపోతే, #N/A ఎర్రర్ కనిపిస్తుంది. మీ స్వంత టెక్స్ట్‌తో ప్రామాణిక ఎర్రర్ సంజ్ఞామానాన్ని భర్తీ చేయడానికి, IF ISNA లోపల nest Index Match:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Excel 2016 మరియు 2016లో, మీరు ఫార్ములాను మరింత చేయడానికి IF ISNAకి బదులుగా IFNAని ఉపయోగించవచ్చు కాంపాక్ట్:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

ఇదే పద్ధతిలో, మీరు ఇతర If ఫార్ములాల్లో ఇండెక్స్ మ్యాచ్‌ని ఉపయోగించవచ్చు.

మీరు ఈ విధంగా ఉపయోగిస్తారు. Excelలో Vlookup మరియు IF స్టేట్‌మెంట్ కలిసి. ఈ ట్యుటోరియల్‌లో చర్చించిన సూత్రాలను నిశితంగా పరిశీలించడానికి, దిగువన ఉన్న మా నమూనా వర్క్‌బుక్‌ని డౌన్‌లోడ్ చేసుకోవడానికి మీకు స్వాగతం. చదివినందుకు ధన్యవాదాలు మరియు మిమ్మల్ని వచ్చే వారం మా బ్లాగ్‌లో కలుస్తానని ఆశిస్తున్నాను!

డౌన్‌లోడ్ కోసం వర్క్‌బుక్‌ను ప్రాక్టీస్ చేయండి

Excel IF Vlookup - ఫార్ములా ఉదాహరణలు (.xlsx ఫైల్)