টিউটোরিয়ালটি দেখায় কিভাবে V LOOKUP এবং IF ফাংশনকে একত্রিত করে ভি-লুকআপ করার জন্য Excel এ if কন্ডিশন। #N/A ত্রুটিগুলিকে আপনার নিজস্ব পাঠ্য, শূন্য বা ফাঁকা ঘরে প্রতিস্থাপন করতে IF ISNA VLOOKUP সূত্রগুলি কীভাবে ব্যবহার করতে হয় তাও আপনি শিখবেন।

যদিও VLOOKUP এবং IF ফাংশনগুলি তাদের নিজস্বভাবে কাজে লাগে। তারা আরও বেশি মূল্যবান অভিজ্ঞতা প্রদান করে। এই টিউটোরিয়ালটি বোঝায় যে আপনি দুটি ফাংশনের সিনট্যাক্স ভালভাবে মনে রাখবেন, অন্যথায় আপনি উপরের লিঙ্কগুলি অনুসরণ করে আপনার জ্ঞান বাড়াতে চাইতে পারেন।

If বিবৃতি দিয়ে দেখুন: True/ return False, Yes/No, ইত্যাদি।

যখন আপনি If এবং Vlookup একত্রিত করেন তখন সবচেয়ে সাধারণ পরিস্থিতিগুলির মধ্যে একটি হল Vlookup দ্বারা প্রত্যাবর্তিত মানটিকে একটি নমুনা মানের সাথে তুলনা করা এবং হ্যাঁ / না অথবা ফলাফল হিসাবে সত্য / মিথ্যা ।

বেশিরভাগ ক্ষেত্রে, নিম্নলিখিত জেনেরিক সূত্রটি সুন্দরভাবে কাজ করবে:

সরল ইংরেজিতে অনুবাদ করা হয়েছে, সূত্রটি এক্সেলকে True ফেরত দিতে নির্দেশ দেয় যদি Vlookup সত্য হয় (অর্থাৎ নির্দিষ্ট মানের সমান)। যদি Vlookup মিথ্যা হয় (নির্দিষ্ট মানের সমান না হয়), সূত্রটি False প্রদান করে।

নীচে আপনি এই IF Vlookup সূত্রের কিছু বাস্তব-জীবনের ব্যবহার দেখতে পাবেন।

উদাহরণ 1. একটি নির্দিষ্ট মান দেখুন

আসুন, আপনার কলাম A তে আইটেমগুলির একটি তালিকা এবং B কলামে পরিমাণ রয়েছে৷ আপনি আপনার ব্যবহারকারীদের জন্য একটি ড্যাশবোর্ড তৈরি করছেন এবং একটি সূত্র প্রয়োজনএটি E1-এ একটি আইটেমের পরিমাণ পরীক্ষা করবে এবং আইটেমটি স্টকে আছে বা বিক্রি হয়ে গেছে কিনা তা ব্যবহারকারীকে জানাবে।

আপনি একটি নিয়মিত ভ্লুকআপের সাহায্যে এইভাবে সঠিক মিল সূত্রের সাথে পরিমাণ টানবেন:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

তারপর, একটি IF স্টেটমেন্ট লিখুন যা Vlookup-এর ফলাফলকে শূন্যের সাথে তুলনা করে এবং 0 এর সমান হলে "No" প্রদান করে, অন্যথায় "Yes":

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

হ্যাঁ/না এর পরিবর্তে, আপনি সত্য/মিথ্যা বা স্টকে/বিক্রীত অথবা অন্য যেকোন দুটি ফেরত দিতে পারেন পছন্দ উদাহরণস্বরূপ:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

এছাড়াও আপনি নমুনা পাঠ্য এর সাথে Vlookup দ্বারা ফেরত দেওয়া মান তুলনা করতে পারেন। এই ক্ষেত্রে, উদ্ধৃতি চিহ্নগুলিতে একটি টেক্সট স্ট্রিং সংযুক্ত করতে ভুলবেন না, যেমন:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

উদাহরণ 2. অন্য একটি সেলের সাথে Vlookup ফলাফল তুলনা করুন

এর আরেকটি সাধারণ উদাহরণ Vlookup with If condition Excel-এ Vlookup আউটপুটকে অন্য কক্ষের একটি মানের সাথে তুলনা করছে। উদাহরণস্বরূপ, আমরা পরীক্ষা করতে পারি যে এটি G2 সেলের একটি সংখ্যার চেয়ে বড় বা সমান কিনা:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

এবং এখানে আমাদের ইফ ফর্মুলাটি রয়েছে যার সাথে Vlookup কার্যকর হচ্ছে:

একই পদ্ধতিতে, আপনি আপনার Excel If Vlookup সূত্রে একটি সেল রেফারেন্স সহ অন্য যেকোনো লজিক্যাল অপারেটর ব্যবহার করতে পারেন।

উদাহরণ 3. একটি ছোট তালিকায় Vlookup মান

টার্গেট কলামের প্রতিটি ঘরকে অন্য তালিকার সাথে তুলনা করতে এবং সত্য বা হ্যাঁ যদি একটি মিল পাওয়া যায়, মিথ্যা বা না<ফেরত দিতে 2> অন্যথায়, এই জেনেরিক IF ISNA VLOOKUP সূত্রটি ব্যবহার করুন:

যদি Vlookup এর ফলে #N/A ত্রুটি দেখা দেয়, সূত্রটি "না" প্রদান করে, যার অর্থ লুকআপ তালিকায় লুকআপ মান পাওয়া যায় না। মিল পাওয়া গেলে, "হ্যাঁ" ফেরত দেওয়া হয়। উদাহরণস্বরূপ:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

যদি আপনার ব্যবসার যুক্তির বিপরীত ফলাফলের প্রয়োজন হয়, তবে সূত্রের যুক্তিকে বিপরীত করতে "হ্যাঁ" এবং "না" অদলবদল করুন:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel If Vlookup সূত্র বিভিন্ন গণনা সম্পাদন করতে

আপনার নিজস্ব পাঠ্য বার্তা প্রদর্শনের পাশাপাশি, যদি Vlookup এর সাথে ফাংশন বিভিন্ন গণনা সম্পাদন করতে পারে আপনার নির্দিষ্ট করা মানদণ্ডের উপর ভিত্তি করে।

আমাদের উদাহরণটিকে আরও এগিয়ে নিয়ে, আসুন একটি নির্দিষ্ট বিক্রেতার কমিশন (F1) তাদের কার্যকারিতার উপর নির্ভর করে গণনা করি: যারা $200 বা তার বেশি করেছেন তাদের জন্য 20% কমিশন, অন্য সবার জন্য 10% .

এর জন্য, আপনি Vlookup দ্বারা প্রত্যাবর্তিত মানটি 200 এর চেয়ে বড় বা সমান কিনা তা পরীক্ষা করুন এবং যদি তা হয় তবে এটিকে 20% দ্বারা গুণ করুন, অন্যথায় 10% দ্বারা:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

যেখানে A2:A10 হল বিক্রেতার নাম এবং C2:C10 হল বিক্রয়৷

#N/A ত্রুটিগুলি লুকানোর জন্য যদি ISNA VLOOKUP

যদি VLOOKUP ফাংশন একটি নির্দিষ্ট মান খুঁজে না পায় তবে এটি একটি #N/A ত্রুটি নিক্ষেপ করে। সেই ত্রুটিটি ধরতে এবং এটিকে আপনার নিজের পাঠ্যের সাথে প্রতিস্থাপন করতে, IF ফাংশনের যৌক্তিক পরীক্ষায় একটি Vlookup সূত্র এম্বেড করুন, এইভাবে:

স্বাভাবিকভাবেই, আপনি "নট ফাউন্ড" এর পরিবর্তে আপনার পছন্দের যেকোনো লেখা টাইপ করতে পারেন।

ধরুন, আপনার কাছে বিক্রেতার একটি তালিকা আছে।একটি কলামে নাম এবং অন্য কলামে বিক্রয়ের পরিমাণ। আপনার কাজ হল F1-এ ব্যবহারকারী যে নামের সাথে সঙ্গতিপূর্ণ একটি সংখ্যা টান। যদি নামটি না পাওয়া যায়, তাহলে এটি নির্দেশ করে একটি বার্তা প্রদর্শন করুন৷

A2:A10 এবং পরিমাণ C2:C10-এ নামগুলির সাথে, কাজটি নিম্নলিখিত If Vlookup সূত্র দিয়ে পূরণ করা যেতে পারে:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

যদি নামটি পাওয়া যায়, একটি সংশ্লিষ্ট বিক্রয়ের পরিমাণ ফেরত দেওয়া হয়:

যদি সন্ধানের মান পাওয়া না যায়, নট পাওয়া যায়<#N/A ত্রুটির পরিবর্তে 2> বার্তাটি উপস্থিত হয়:

এই সূত্রটি কীভাবে কাজ করে

সূত্রটির যুক্তি খুবই সহজ: আপনি ISNA ফাংশন ব্যবহার করেন #N/A ত্রুটির জন্য Vlookup চেক করতে। যদি একটি ত্রুটি ঘটে, ISNA TRUE প্রদান করে, অন্যথায় FALSE। উপরের মানগুলি IF ফাংশনের লজিক্যাল পরীক্ষায় যায়, যা নিম্নলিখিতগুলির মধ্যে একটি করে:

• যদি লজিক্যাল পরীক্ষাটি সত্য হয় (#N/A ত্রুটি), আপনার বার্তাটি প্রদর্শিত হয়৷<20
• যদি যৌক্তিক পরীক্ষা মিথ্যা হয় (লুকআপ মান পাওয়া যায়), Vlookup সাধারনভাবে একটি মিল ফেরত দেয়।

ইফনা VLOOKUP নতুন এক্সেল সংস্করণে

এক্সেল 2013 থেকে শুরু করে, আপনি #N/A ত্রুটিগুলি ধরতে এবং পরিচালনা করতে IF ISNA এর পরিবর্তে IFNA ফাংশন ব্যবহার করতে পারেন:

আমাদের উদাহরণে, সূত্রটি হবে নিম্নলিখিত আকার নিন:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

টিপ। আপনি যদি শুধু #N/A নয়, সব ধরনের ত্রুটি ফাঁদে ফেলতে চান, তাহলে IFERROR ফাংশনের সাথে VLOOKUP ব্যবহার করুন। আরো বিস্তারিত এখানে পাওয়া যাবে: IFERRORএক্সেল-এ VLOOKUP।

Excel Vlookup: যদি না পাওয়া যায় রিটার্ন 0

সংখ্যাসূচক মান নিয়ে কাজ করার সময়, লুকআপ মান না পাওয়া গেলে আপনি একটি শূন্য ফেরত দিতে চাইতে পারেন। এটি করার জন্য, উপরে আলোচিত IF ISNA VLOOKUP সূত্রটি একটু পরিবর্তনের সাথে ব্যবহার করুন: একটি পাঠ্য বার্তার পরিবর্তে, IF ফাংশনের value_if_true আর্গুমেন্টে 0 সরবরাহ করুন:

আমাদের নমুনা টেবিলে, সূত্রটি নিম্নরূপ হবে:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

এক্সেল 2016 এবং 2013 এর সাম্প্রতিক সংস্করণ, আপনি আবার IFNA Vlookup সংমিশ্রণটি ব্যবহার করতে পারেন:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: যদি না পাওয়া যায় তাহলে ফাঁকা ঘর ফেরত দিন

এটি আরও একটি ভিন্নতা "Vlookup if then" বিবৃতিটির: লুকআপ মান পাওয়া না গেলে কিছুই ফেরত দেবেন না। এটি করার জন্য, #N/A ত্রুটির পরিবর্তে একটি খালি স্ট্রিং ("") ফেরত দিতে আপনার সূত্র নির্দেশ করুন:

নীচে কয়েকটি সম্পূর্ণ সূত্র উদাহরণ:

সমস্ত এক্সেল সংস্করণের জন্য:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

এক্সেল 2016 এবং এক্সেল 2013-এর জন্য:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

ইফ উইথ ইনডেক্স ম্যাচ - ইফ কন্ডিশন সহ বাম vlookup

অভিজ্ঞ এক্সেল ব্যবহারকারীরা জানেন যে VLOOKUP ফাংশনই Excel এ উল্লম্ব লুকআপ করার একমাত্র উপায় নয়। INDEX MATCH সংমিশ্রণটিও এই উদ্দেশ্যে ব্যবহার করা যেতে পারে এবং এটি আরও শক্তিশালী এবং বহুমুখী। ভাল খবর হল যে Index Match ঠিক একই ভাবে IF এর সাথে একসাথে কাজ করতে পারেVlookup।

উদাহরণস্বরূপ, কলাম A-তে আপনার অর্ডার নম্বর এবং B কলামে বিক্রেতার নাম রয়েছে। আপনি একটি নির্দিষ্ট বিক্রেতার জন্য অর্ডার নম্বর টানতে একটি সূত্র খুঁজছেন।

Vlookup হতে পারে না। এই ক্ষেত্রে ব্যবহৃত হয় কারণ এটি ডান থেকে বামে অনুসন্ধান করতে পারে না। যতক্ষণ না লুকআপ কলামে লুকআপ মান পাওয়া যায় ততক্ষণ ইনডেক্স ম্যাচ কোনও বাধা ছাড়াই কাজ করবে। না হলে, একটি #N/A ত্রুটি দেখাবে৷ আপনার নিজের পাঠ্যের সাথে স্ট্যান্ডার্ড ত্রুটির স্বরলিপি প্রতিস্থাপন করতে, IF ISNA-এর ভিতরে নেস্ট ইনডেক্স ম্যাচ করুন:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

এক্সেল 2016 এবং 2016-এ, আপনি সূত্রটিকে আরও তৈরি করতে IF ISNA-এর পরিবর্তে IFNA ব্যবহার করতে পারেন কমপ্যাক্ট:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

একইভাবে, আপনি অন্যান্য ইফ সূত্রে ইনডেক্স ম্যাচ ব্যবহার করতে পারেন।

আপনি এইভাবে ব্যবহার করেন। Excel এ Vlookup এবং IF স্টেটমেন্ট একসাথে। এই টিউটোরিয়ালে আলোচিত সূত্রগুলি ঘনিষ্ঠভাবে দেখার জন্য, আপনাকে নীচের আমাদের নমুনা ওয়ার্কবুক ডাউনলোড করতে স্বাগত জানাই৷ আমি পড়ার জন্য আপনাকে ধন্যবাদ এবং আশা করি আগামী সপ্তাহে আমাদের ব্লগে আপনাকে দেখতে পাব!

ডাউনলোডের জন্য অনুশীলন ওয়ার্কবুক

Excel IF Vlookup - সূত্র উদাহরণ (.xlsx ফাইল)