Bu eğitimde V Excel'de if koşulu ile v-lookup yapmak için LOOKUP ve IF işlevini birlikte kullanmayı öğreneceksiniz. Ayrıca #N/A hatalarını kendi metniniz, sıfır veya boş hücre ile değiştirmek için IF ISNA VLOOKUP formüllerini nasıl kullanacağınızı öğreneceksiniz.

DÜŞEYARA ve EĞER işlevleri kendi başlarına yararlı olsalar da birlikte çok daha değerli deneyimler sunarlar. Bu eğitim, iki işlevin sözdizimini iyi hatırladığınız anlamına gelir, aksi takdirde yukarıdaki bağlantıları izleyerek bilgilerinizi tazelemek isteyebilirsiniz.

If deyimi ile Vlookup: True/False, Yes/No, vb. döndürür.

If ve Vlookup'ı bir araya getirdiğinizde en sık karşılaşılan senaryolardan biri, Vlookup tarafından döndürülen değeri örnek bir değerle karşılaştırmak ve Evet / Hayır veya Doğru / Yanlış sonuç olarak.

Çoğu durumda, aşağıdaki genel formül işe yarayacaktır:

Düz İngilizceye çevrildiğinde, formül Excel'e şunları döndürmesini söyler Doğru Vlookup doğruysa (yani belirtilen değere eşitse). Vlookup yanlışsa (belirtilen değere eşit değilse), formül Yanlış .

Aşağıda bu IF Vlookup formülünün gerçek hayattaki birkaç kullanımını bulacaksınız.

Örnek 1. Belirli bir değeri arayın

Diyelim ki, A sütununda öğelerin bir listesi ve B sütununda miktar var. Kullanıcılarınız için bir gösterge tablosu oluşturuyorsunuz ve E1'deki bir öğenin miktarını kontrol edecek ve kullanıcıya öğenin stokta olup olmadığını veya tükendiğini bildirecek bir formüle ihtiyacınız var.

Miktarı, aşağıdaki gibi tam eşleşme formülüne sahip normal bir Vlookup ile çekersiniz:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Ardından, Vlookup'ın sonucunu sıfırla karşılaştıran ve 0'a eşitse "Hayır", değilse "Evet" döndüren bir EĞER deyimi yazın:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0, "Hayır", "Evet")

Bunun yerine Evet/Hayır geri dönebilirsiniz DOĞRU/YANLIŞ veya Stokta var/Satıldı veya diğer iki seçenek. Örneğin:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0, "Tükendi", "Stokta var")

Vlookup tarafından döndürülen değeri örnekle de karşılaştırabilirsiniz Metin Bu durumda, bir metin dizesini aşağıdaki gibi tırnak içine aldığınızdan emin olun:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="örnek metin",TRUE,FALSE)

Örnek 2. Vlookup sonucunu başka bir hücreyle karşılaştırın

Excel'de If koşullu Vlookup'ın bir başka tipik örneği, Vlookup çıktısını başka bir hücredeki bir değerle karşılaştırmaktır. Örneğin, G2 hücresindeki bir sayıdan büyük veya ona eşit olup olmadığını kontrol edebiliriz:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2, "Evet!", "Hayır")

Ve işte Vlookup ile If formülümüz iş başında:

Benzer şekilde, Excel If Vlookup formülünüzde bir hücre başvurusuyla birlikte başka herhangi bir mantıksal işleci kullanabilirsiniz.

Örnek 3. Daha kısa bir listedeki Vlookup değerleri

Hedef sütundaki her hücreyi başka bir listeyle karşılaştırmak ve döndürmek için Doğru veya Evet bir eşleşme bulunursa, Yanlış veya Hayır Aksi takdirde, bu genel EĞER ISNA DÜŞEYARA formülünü kullanın:

Vlookup #N/A hatasıyla sonuçlanırsa, formül "Hayır" döndürür, yani arama değeri arama listesinde bulunmaz. Eşleşme bulunursa, "Evet" döndürülür. Örneğin:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)), "Hayır", "Evet")

İş mantığınız ters sonuçlar gerektiriyorsa, formülün mantığını tersine çevirmek için "Evet" ve "Hayır "ı değiştirmeniz yeterlidir:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)), "Evet", "Hayır")

Excel Farklı hesaplamalar yapmak için Vlookup formülü varsa

Vlookup ile If fonksiyonu, kendi metin mesajlarınızı görüntülemenin yanı sıra, belirlediğiniz kriterlere göre farklı hesaplamalar da yapabilir.

Örneğimizi daha da ileri götürerek, belirli bir satıcının (F1) komisyonunu etkinliklerine bağlı olarak hesaplayalım: 200 $ ve üzeri kazananlar için %20 komisyon, diğer herkes için %10 komisyon.

Bunun için, Vlookup tarafından döndürülen değerin 200'den büyük veya eşit olup olmadığını kontrol edersiniz ve öyleyse %20 ile, aksi takdirde %10 ile çarparsınız:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Burada A2:A10 satıcı adları ve C2:C10 satışlardır.

IF ISNA #N/A hatalarını gizlemek için DÜŞEYARA

DÜŞEYARA işlevi belirtilen bir değeri bulamazsa, #YOK hatası verir. Bu hatayı yakalamak ve kendi metninizle değiştirmek için, EĞER işlevinin mantıksal testine aşağıdaki gibi bir VDüşeyARA formülü yerleştirin:

Doğal olarak, "Bulunamadı" yerine istediğiniz herhangi bir metni yazabilirsiniz.

Diyelim ki, bir sütunda satıcı adları ve başka bir sütunda satış tutarları listeniz var. Göreviniz, kullanıcının F1'e girdiği ada karşılık gelen bir sayı çekmektir. Ad bulunamazsa, bunu belirten bir mesaj görüntüleyin.

A2:A10'daki adlar ve C2:C10'daki tutarlar ile görev aşağıdaki If Vlookup formülü ile yerine getirilebilir:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Bulunamadı", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

İsim bulunursa, karşılık gelen bir satış tutarı döndürülür:

Arama değeri bulunamazsa Bulunamadı mesajı #N/A hatası yerine görüntülenir:

Bu formül nasıl çalışır?

Formülün mantığı çok basittir: Vlookup'ı #N/A hatalarına karşı kontrol etmek için ISNA işlevini kullanırsınız. Bir hata oluşursa, ISNA DOĞRU, aksi takdirde YANLIŞ döndürür. Yukarıdaki değerler, aşağıdakilerden birini yapan IF işlevinin mantıksal testine gider:

• Mantıksal test DOĞRU ise (#N/A hatası), mesajınız görüntülenir.
• Mantıksal test FALSE ise (arama değeri bulunursa), Vlookup normal olarak bir eşleşme döndürür.

Daha yeni Excel sürümlerinde IFNA DÜŞEYARA

Excel 2013'ten itibaren, #N/A hatalarını yakalamak ve işlemek için IF ISNA yerine IFNA işlevini kullanabilirsiniz:

Örneğimizde, formül aşağıdaki şekli alacaktır:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Bulunamadı")

İpucu: Yalnızca #N/A değil, her türlü hatayı yakalamak istiyorsanız, DÜŞEYARA işlevini EĞERHATA işleviyle birlikte kullanın. Daha fazla ayrıntı burada bulunabilir: Excel'de EĞERHATA DÜŞEYARA.

Excel Vlookup: bulunamazsa 0 döndürür

Sayısal değerlerle çalışırken, arama değeri bulunamadığında sıfır döndürmek isteyebilirsiniz. Bunu yapmak için, yukarıda tartışılan EĞER ISNA DÜŞEYARA formülünü küçük bir değişiklikle kullanın: metin mesajı yerine value_if_true IF fonksiyonunun argümanı:

Örnek tablomuzda formül aşağıdaki gibi olacaktır:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 ve 2013'ün son sürümlerinde, IFNA Vlookup kombinasyonunu tekrar kullanabilirsiniz:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: bulunamazsa boş hücre döndürür

Bu, "Vlookup if then" deyiminin bir başka varyasyonudur: arama değeri bulunamadığında hiçbir şey döndürmez. Bunu yapmak için, formülünüze #N/A hatası yerine boş bir dize ("") döndürmesini söyleyin:

Aşağıda birkaç tam formül örneği verilmiştir:

Tüm Excel sürümleri için:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 ve Excel 2013 için:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

Dizin Eşleşmeli If - If koşullu sol vlookup

Deneyimli Excel kullanıcıları, Excel'de dikey arama yapmanın tek yolunun DÜŞEYARA işlevi olmadığını bilirler. INDEX MATCH kombinasyonu da bu amaçla kullanılabilir ve daha da güçlü ve çok yönlüdür. İyi haber şu ki, Index Match, IF ile birlikte Vlookup ile tamamen aynı şekilde çalışabilir.

Örneğin, A sütununda sipariş numaralarınız ve B sütununda satıcı adlarınız var. Belirli bir satıcı için sipariş numarasını çekecek bir formül arıyorsunuz.

Vlookup bu durumda kullanılamaz çünkü sağdan sola arama yapamaz. Index Match, arama değeri arama sütununda bulunduğu sürece sorunsuz çalışacaktır. Aksi takdirde, #N/A hatası görünecektir. Standart hata gösterimini kendi metninizle değiştirmek için, Index Match'i IF ISNA'nın içine yerleştirin:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Bulunamadı", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))

Excel 2016 ve 2016'da, formülü daha kompakt hale getirmek için IF ISNA yerine IFNA kullanabilirsiniz:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Bulunamadı")

Benzer şekilde, Dizin Eşleştirmesini diğer Eğer formüllerinde de kullanabilirsiniz.

Excel'de Vlookup ve IF deyimlerini bu şekilde birlikte kullanabilirsiniz. Bu eğitimde ele alınan formüllere daha yakından bakmak için aşağıdaki örnek çalışma kitabımızı indirebilirsiniz. Okuduğunuz için teşekkür eder, gelecek hafta blogumuzda görüşmek dileğiyle!

İndirmek için pratik çalışma kitabı

Excel IF Vlookup - formül örnekleri (.xlsx dosyası)