ट्युटोरियलले एक्सेलमा if कन्डिशनको साथ v-lookup गर्न V LOOKUP र IF प्रकार्यलाई कसरी संयोजन गर्ने भनेर देखाउँछ। #N/A त्रुटिहरूलाई आफ्नै पाठ, शून्य वा खाली कक्षमा बदल्नका लागि IF ISNA VLOOKUP सूत्रहरू कसरी प्रयोग गर्ने भनेर तपाईंले पनि सिक्नुहुनेछ।

जबकि VLOOKUP र IF प्रकार्यहरू एकसाथ उपयोगी हुन्छन्। तिनीहरूले अझ मूल्यवान अनुभवहरू प्रदान गर्छन्। यो ट्यूटोरियलले संकेत गर्दछ कि तपाइँ दुई प्रकार्यहरूको वाक्य रचना राम्रोसँग सम्झनुहुन्छ, अन्यथा तपाइँ माथिको लिङ्कहरू पछ्याएर तपाइँको ज्ञानमा ब्रस गर्न चाहनुहुन्छ। False, Yes/No, etc.

जब तपाईले If र Vlookup लाई सँगै जोड्नुहुन्छ भने सबैभन्दा सामान्य परिदृश्य मध्ये एउटा भनेको Vlookup द्वारा फिर्ता गरिएको मानलाई नमूना मानसँग तुलना गर्नु हो र हो / होइन वा True / False परिणामको रूपमा।

अधिकांश अवस्थामा, निम्न जेनेरिक सूत्रले राम्रोसँग काम गर्नेछ:

सादा अंग्रेजीमा अनुवाद गरिएको, सूत्रले Excel लाई True फर्काउन निर्देशन दिन्छ यदि Vlookup सही छ (अर्थात निर्दिष्ट मान बराबर)। यदि Vlookup गलत छ (निर्दिष्ट मानको बराबर छैन), सूत्रले False फर्काउँछ।

तल तपाईंले यो IF Vlookup सूत्रका केही वास्तविक-जीवन प्रयोगहरू फेला पार्नुहुनेछ।

उदाहरण १. एक विशिष्ट मान हेर्नुहोस्

मानौं, तपाईंसँग स्तम्भ A मा वस्तुहरूको सूची र स्तम्भ B मा मात्रा छ। तपाईंले आफ्ना प्रयोगकर्ताहरूको लागि ड्यासबोर्ड सिर्जना गर्दै हुनुहुन्छ र एउटा सूत्र चाहिन्छ।जसले E1 मा वस्तुको परिमाण जाँच गर्नेछ र वस्तु स्टकमा छ वा बेचिएको छ भनी प्रयोगकर्तालाई जानकारी गराउनेछ।

तपाईले नियमित Vlookup मार्फत मात्रालाई यसरी मिलाउनुहुन्छ:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

त्यसपछि, Vlookup को नतिजालाई शून्यसँग तुलना गर्ने IF कथन लेख्नुहोस्, र ० बराबर भएमा "No" फर्काउँछ, अन्यथा "हो":

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

हो/होइन को सट्टा, तपाईंले सत्य/असत्य वा स्टकमा/बिक्री भएको वा कुनै अन्य दुई फर्काउन सक्नुहुन्छ। विकल्पहरू। उदाहरणका लागि:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

तपाईँ Vlookup द्वारा फर्काइएको मानलाई नमूना पाठ सँग पनि तुलना गर्न सक्नुहुन्छ। यस अवस्थामा, उद्धरण चिन्हहरूमा पाठ स्ट्रिङ संलग्न गर्न निश्चित हुनुहोस्, जस्तै:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

उदाहरण २. अर्को सेलसँग Vlookup परिणाम तुलना गर्नुहोस्

को अर्को विशिष्ट उदाहरण एक्सेलमा यदि सर्तसँग Vlookup अर्को सेलको मानसँग Vlookup आउटपुट तुलना गर्दैछ। उदाहरण को लागी, हामी यो सेल G2 मा संख्या भन्दा ठूलो वा बराबर छ भनेर जाँच गर्न सक्छौं:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

र यहाँ कार्यमा Vlookup संग हाम्रो If सूत्र छ:

उस्तै फेसनमा, तपाइँ तपाइँको Excel If Vlookup सूत्रमा सेल सन्दर्भ सहित कुनै पनि अन्य तार्किक अपरेटर प्रयोग गर्न सक्नुहुन्छ।

उदाहरण 3. छोटो सूचीमा Vlookup मानहरू

लक्ष्य स्तम्भको प्रत्येक कक्षलाई अर्को सूचीसँग तुलना गर्न र True वा हो यदि मिल्दो भेटियो भने, False वा No अन्यथा, यो जेनेरिक IF ISNA VLOOKUP सूत्र प्रयोग गर्नुहोस्:

यदि Vlookup ले #N/A त्रुटि देखाउँछ भने, सूत्रले "No" फर्काउँछ, जसको अर्थ लुकअप सूचीमा लुकअप मान फेला पर्दैन। यदि मिलान फेला पर्यो भने, "हो" फर्काइन्छ। उदाहरणका लागि:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

यदि तपाईंको व्यापार तर्कलाई विपरीत परिणामहरू चाहिन्छ भने, सूत्रको तर्कलाई उल्टाउनको लागि "हो" र "होइन" लाई बदल्नुहोस्:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel If Vlookup सूत्र विभिन्न गणनाहरू प्रदर्शन गर्न

तपाईँको आफ्नै पाठ सन्देशहरू प्रदर्शन गर्न बाहेक, यदि Vlookup सँग प्रकार्यले फरक गणना गर्न सक्छ। तपाईंले तोक्नुभएको मापदण्डको आधारमा।

हाम्रो उदाहरणलाई अगाडि बढाउँदै, तिनीहरूको प्रभावकारिताको आधारमा एक विशिष्ट बिक्रेता (F1) को कमिशन गणना गरौं: $200 र त्योभन्दा बढी कमाउनेहरूका लागि 20% कमिशन, अरू सबैका लागि 10% .

यसको लागि, तपाईंले Vlookup द्वारा फिर्ता गरेको मान २०० भन्दा ठूलो वा बराबर छ कि छैन जाँच गर्नुहोस्, र यदि यो छ भने, यसलाई 20%, अन्यथा 10% द्वारा गुणा गर्नुहोस्:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

जहाँ A2:A10 बिक्रेताको नाम हो र C2:C10 बिक्री हो।

IF ISNA VLOOKUP #N/A त्रुटिहरू लुकाउन

यदि VLOOKUP प्रकार्यले निर्दिष्ट मान फेला पार्न सक्दैन भने, यसले #N/A त्रुटि फ्याँक्छ। त्यो त्रुटि समात्न र यसलाई आफ्नै पाठले प्रतिस्थापन गर्न, IF प्रकार्यको तार्किक परीक्षणमा Vlookup सूत्र इम्बेड गर्नुहोस्, जस्तै:

स्वाभाविक रूपमा, तपाईंले "फेला परेन" को सट्टा आफूलाई मनपर्ने कुनै पनि पाठ टाइप गर्न सक्नुहुन्छ।

मान्नुहोस्, तपाईंसँग विक्रेताको सूची छ।एउटा स्तम्भमा नाम र अर्को स्तम्भमा बिक्री रकम। तपाईको कार्य भनेको प्रयोगकर्ताले F1 मा प्रविष्ट गरेको नामसँग सम्बन्धित नम्बर तान्नु हो। यदि नाम फेला परेन भने, त्यसो देखाउने सन्देश देखाउनुहोस्।

A2:A10 र मात्रा C2:C10 मा नामहरू सहित, निम्न If Vlookup सूत्रद्वारा कार्य पूरा गर्न सकिन्छ:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

यदि नाम फेला पर्‍यो भने, सम्बन्धित बिक्री रकम फिर्ता गरिन्छ:

यदि लुकअप मान फेला परेन भने, फेला परेन सन्देश #N/A त्रुटिको सट्टा देखा पर्दछ:

यस सूत्रले कसरी काम गर्छ

सूत्रको तर्क धेरै सरल छ: तपाइँ ISNA प्रकार्य प्रयोग गर्नुहुन्छ #N/A त्रुटिहरूको लागि Vlookup जाँच गर्न। यदि त्रुटि भयो भने, ISNA ले TRUE फर्काउँछ, अन्यथा FALSE। माथिका मानहरू IF प्रकार्यको तार्किक परीक्षणमा जान्छन्, जसले निम्न मध्ये एउटा गर्छ:

• यदि तार्किक परीक्षण सत्य हो (#N/A त्रुटि), तपाईंको सन्देश प्रदर्शित हुन्छ।<20
• यदि तार्किक परीक्षण FALSE छ (लुकअप मान फेला पर्यो), Vlookup ले सामान्यतया मिल्दोजुल्दो फर्काउँछ।

IFNA VLOOKUP नयाँ Excel संस्करणहरूमा

Excel 2013 बाट सुरु गर्दै, तपाईंले #N/A त्रुटिहरू समात्न र ह्यान्डल गर्न IF ISNA को सट्टा IFNA प्रकार्य प्रयोग गर्न सक्छ:

हाम्रो उदाहरणमा, सूत्रले निम्न आकार लिनुहोस्:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

टिप। यदि तपाईं #N/A मात्र होइन, सबै प्रकारका त्रुटिहरू ट्र्याप गर्न चाहनुहुन्छ भने, IFERROR प्रकार्यसँग संयोजनमा VLOOKUP प्रयोग गर्नुहोस्। थप विवरणहरू यहाँ फेला पार्न सकिन्छ: IFERRORएक्सेलमा VLOOKUP।

Excel Vlookup: फेला परेन भने फिर्ता ०

संख्यात्मक मानहरूसँग काम गर्दा, लुकअप मान फेला परेन भने तपाईंले शून्य फर्काउन सक्नुहुन्छ। यो गर्नको लागि, थोरै परिमार्जनको साथ माथि छलफल गरिएको IF ISNA VLOOKUP सूत्र प्रयोग गर्नुहोस्: पाठ सन्देशको सट्टा, IF प्रकार्यको value_if_true तर्कमा 0 आपूर्ति गर्नुहोस्:

हाम्रो नमूना तालिकामा, सूत्र निम्नानुसार जान्छ:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

21>

मा Excel 2016 र 2013 को भर्खरका संस्करणहरू, तपाईंले IFNA Vlookup संयोजन फेरि प्रयोग गर्न सक्नुहुन्छ:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: यदि फेला परेन भने खाली कक्ष फर्काउनुहोस्

यो एक थप भिन्नता हो। "Vlookup if then" कथन को: लुकअप मान फेला परेन भने केहि पनि फिर्ता नगर्नुहोस्। यो गर्नको लागि, #N/A त्रुटिको सट्टा खाली स्ट्रिङ ("") फिर्ता गर्न आफ्नो सूत्रलाई निर्देशन दिनुहोस्:

तल केही पूर्ण सूत्र उदाहरणहरू छन्:

सबै एक्सेल संस्करणहरूका लागि:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

एक्सेल 2016 र एक्सेल 2013 को लागि:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

If Index Match सँग - If condition संग बायाँ vlookup

अनुभवी एक्सेल प्रयोगकर्ताहरूलाई थाहा छ कि VLOOKUP प्रकार्य Excel मा ठाडो लुकअप गर्ने एक मात्र तरिका होइन। यस उद्देश्यका लागि INDEX MATCH संयोजन पनि प्रयोग गर्न सकिन्छ र यो अझ शक्तिशाली र बहुमुखी छ। सुसमाचार यो हो कि सूचकांक मिलानले IF सँग ठ्याक्कै उस्तै रूपमा काम गर्न सक्छVlookup।

उदाहरणका लागि, तपाईंसँग स्तम्भ A मा अर्डर नम्बरहरू र स्तम्भ B मा बिक्रेताको नामहरू छन्। तपाईं कुनै विशेष विक्रेताको अर्डर नम्बर तान्नको लागि सूत्र खोज्दै हुनुहुन्छ।

Vlookup हुन सक्दैन। यस अवस्थामा प्रयोग गरियो किनभने यसले दायाँबाट बायाँ खोज्न सक्दैन। लुकअप स्तम्भमा लुकअप मान फेला परेसम्म अनुक्रमणिका मिलानले कुनै अवरोध बिना काम गर्नेछ। यदि होइन भने, #N/A त्रुटि देखा पर्नेछ। मानक त्रुटि सङ्केतलाई तपाईंको आफ्नै पाठसँग बदल्नको लागि, IF ISNA भित्र नेस्ट इन्डेक्स मिलान गर्नुहोस्:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Excel 2016 र 2016 मा, तपाईंले सूत्रलाई थप बनाउन IF ISNA को सट्टा IFNA प्रयोग गर्न सक्नुहुन्छ। कम्प्याक्ट:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

उस्तै तरिकामा, तपाईंले अन्य यदि सूत्रहरूमा अनुक्रमणिका मिलान प्रयोग गर्न सक्नुहुन्छ।

तपाईले यसरी प्रयोग गर्नुहुन्छ Vlookup र IF कथन Excel मा सँगै। यस ट्यूटोरियलमा छलफल गरिएका सूत्रहरूलाई नजिकबाट हेर्नको लागि, तपाइँलाई तलको हाम्रो नमूना कार्यपुस्तिका डाउनलोड गर्न स्वागत छ। पढ्नुभएकोमा धन्यवाद र अर्को हप्ता हाम्रो ब्लगमा भेट्ने आशा गर्दछु!

डाउनलोडका लागि अभ्यास कार्यपुस्तिका

Excel IF Vlookup - सूत्र उदाहरणहरू (.xlsx फाइल)