টিউটোৰিয়েলত দেখুওৱা হৈছে যে কেনেকৈ V LOOKUP আৰু IF ফাংচনক একেলগে একত্ৰিত কৰি Excel ত if condition ৰ সৈতে v-lookup কৰিব পাৰি। আপুনি #N/A ভুলসমূহক আপোনাৰ নিজৰ লিখনী, শূন্য বা খালী ঘৰৰ সৈতে সলনি কৰিবলে IF ISNA VLOOKUP সূত্ৰসমূহ কেনেকৈ ব্যৱহাৰ কৰিব লাগে সেই বিষয়েও শিকিব।

যেতিয়া VLOOKUP আৰু IF ফাংচনসমূহ নিজাববীয়াকৈ, একেলগে উপযোগী তেওঁলোকে আৰু অধিক মূল্যৱান অভিজ্ঞতা প্ৰদান কৰে। এই টিউটোৰিয়েলৰ অৰ্থ হ'ল আপুনি দুটা ফাংচনৰ বাক্যবিন্যাস ভালদৰে মনত ৰাখিব, অন্যথা আপুনি ওপৰৰ সংযোগসমূহ অনুসৰণ কৰি আপোনাৰ জ্ঞান ব্ৰাছ আপ কৰিব বিচাৰিব পাৰে।

If বিবৃতিৰ সৈতে Vlookup কৰক: return True/ মিছা, হয়/নাই, ইত্যাদি।

যেতিয়া আপুনি If আৰু Vlookup একেলগে সংযুক্ত কৰে তেতিয়া এটা সাধাৰণ পৰিস্থিতি হ'ল Vlookup দ্বাৰা ঘূৰাই দিয়া মানক এটা নমুনা মানৰ সৈতে তুলনা কৰা আৰু হয় / নাই ঘূৰাই দিয়া বা সত্য / মিছা ফলাফল হিচাপে।

বেছিভাগ ক্ষেত্ৰতে, নিম্নলিখিত সাধাৰণ সূত্ৰই সুন্দৰভাৱে কাম কৰিব:

সাধাৰণ ইংৰাজীত অনুবাদ কৰা, সূত্ৰই Excelক True ঘূৰাই দিবলৈ নিৰ্দেশ দিয়ে যদি Vlookup সত্য হয় (অৰ্থাৎ ধাৰ্য্য কৰা মানৰ সমান)। যদি Vlookup মিছা হয় (ধাৰ্য্য কৰা মানৰ সমান নহয়), সূত্ৰই False ঘূৰাই দিয়ে।

তলত আপুনি এই IF Vlookup সূত্ৰৰ কেইটামান বাস্তৱ-জীৱনৰ ব্যৱহাৰ পাব।

উদাহৰণ 1. এটা নিৰ্দিষ্ট মান চাওক

ধৰক, আপোনাৰ স্তম্ভ A ত বস্তুৰ তালিকা আৰু স্তম্ভ B ত পৰিমাণ আছে। আপুনি আপোনাৰ ব্যৱহাৰকাৰীসকলৰ বাবে এটা ডেচব'ৰ্ড সৃষ্টি কৰিছে আৰু এটা সূত্ৰৰ প্ৰয়োজনযিয়ে E1 ত এটা বস্তুৰ বাবে পৰিমাণ পৰীক্ষা কৰিব আৰু ব্যৱহাৰকাৰীক জনাই দিব যে বস্তুটো ষ্টকত আছে নে বিক্ৰী হৈ গৈছে।

আপুনি এই ধৰণৰ সঠিক মিল সূত্ৰৰ সৈতে এটা নিয়মীয়া Vlookup ৰ সৈতে পৰিমাণ টানে:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

তাৰ পিছত, এটা IF বিবৃতি লিখক যি Vlookup ৰ ফলাফল শূন্যৰ সৈতে তুলনা কৰে, আৰু "নাই" ঘূৰাই দিয়ে যদি ই 0 ৰ সমান, "হয়" অন্যথা:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

হয়/নাই ৰ পৰিবৰ্তে, আপুনি TRUE/FALSE বা ষ্টকত আছে/বিক্ৰী হৈ গৈছে বা আন যিকোনো দুটা ঘূৰাই দিব পাৰে পছন্দসমূহ। উদাহৰণস্বৰূপ:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

আপুনি Vlookup দ্বাৰা ঘূৰাই দিয়া মানক sample text ৰ সৈতেও তুলনা কৰিব পাৰে। এই ক্ষেত্ৰত, এটা লিখনী ষ্ট্ৰিং উদ্ধৃতি চিহ্নত আবদ্ধ কৰাটো নিশ্চিত কৰক, যেনে:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

উদাহৰণ 2. Vlookup ফলাফলক অন্য কোষৰ সৈতে তুলনা কৰক

ৰ আন এটা সাধাৰণ উদাহৰণ Excel ত If অৱস্থাৰ সৈতে Vlookup এ Vlookup আউটপুটক অন্য ঘৰৰ এটা মানৰ সৈতে তুলনা কৰিছে। উদাহৰণস্বৰূপে, আমি পৰীক্ষা কৰিব পাৰো যে ই G2 কোষৰ এটা সংখ্যাতকৈ ডাঙৰ বা সমান নেকি:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

আৰু ইয়াত Vlookup ৰ সৈতে আমাৰ If সূত্ৰ আছে:

এটা একে ধৰণেৰে, আপুনি আপোনাৰ Excel If Vlookup সূত্ৰত এটা কোষ প্ৰসংগৰ সৈতে একেলগে অন্য যিকোনো লজিকেল অপাৰেটৰ ব্যৱহাৰ কৰিব পাৰে।

উদাহৰণ 3. এটা চুটি তালিকাত Vlookup মানসমূহ

লক্ষ্য স্তম্ভৰ প্ৰতিটো ঘৰক অন্য তালিকাৰ সৈতে তুলনা কৰিবলে আৰু সত্য বা হয় ঘূৰাই দিব যদি এটা মিল পোৱা যায়, মিছা বা নাই অন্যথা, এই সাধাৰণ IF ISNA VLOOKUP সূত্ৰ ব্যৱহাৰ কৰক:

যদি Vlookup ৰ ফলত #N/A ভুল হয়, সূত্ৰই "নাই" ঘূৰাই দিয়ে, অৰ্থাৎ লুকআপ মান লুকআপ তালিকাত পোৱা নাযায়। যদি মিল পোৱা যায়, "হয়" ঘূৰাই দিয়া হয়। উদাহৰণস্বৰূপে:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

যদি আপোনাৰ ব্যৱসায়িক যুক্তিৰ বিপৰীত ফলাফলৰ প্ৰয়োজন হয়, সূত্ৰৰ যুক্তি উলটিবলৈ "হয়" আৰু "নাই" শ্বেপ কৰক:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel If Vlookup সূত্ৰ বিভিন্ন গণনা সম্পাদন কৰিবলে

আপোনাৰ নিজৰ লিখনী বাৰ্তা প্ৰদৰ্শন কৰাৰ উপৰিও, যদি Vlookup ৰ সৈতে ফাংচনে বিভিন্ন গণনা সম্পাদন কৰিব পাৰে আপুনি নিৰ্দিষ্ট কৰা মাপকাঠীৰ ওপৰত ভিত্তি কৰি।

আমাৰ উদাহৰণটোক আৰু আগুৱাই লৈ গৈ, তেওঁলোকৰ ফলপ্ৰসূতাৰ ওপৰত নিৰ্ভৰ কৰি এজন নিৰ্দিষ্ট বিক্ৰেতাৰ কমিচন (F1) গণনা কৰোঁ আহক: যিসকলে $200 আৰু তাতকৈ অধিক উপাৰ্জন কৰিছিল তেওঁলোকৰ বাবে 20% কমিচন, বাকী সকলোৰে বাবে 10% .

ইয়াৰ বাবে, আপুনি Vlookup দ্বাৰা ঘূৰাই দিয়া মান 200 তকৈ ডাঙৰ বা সমান নেকি পৰীক্ষা কৰে, আৰু যদি হয়, ইয়াক 20% ৰে গুণ কৰক, অন্যথা 10% ৰে গুণ কৰক:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

য'ত A2:A10 হৈছে বিক্ৰেতাৰ নাম আৰু C2:C10 হৈছে বিক্ৰী।

IF ISNA VLOOKUP to hide #N/A errors

যদি VLOOKUP ফাংচনে এটা ধাৰ্য্য কৰা মান বিচাৰি নাপায়, ই এটা #N/A ভুল নিক্ষেপ কৰে। সেই ভুল ধৰিবলৈ আৰু ইয়াক আপোনাৰ নিজৰ লিখনীৰ সৈতে সলনি কৰিবলৈ, IF ফাংচনৰ লজিকেল পৰীক্ষাত এটা Vlookup সূত্ৰ এম্বেড কৰক, যেনে:

স্বাভাৱিকভাৱে, আপুনি "Not found" ৰ পৰিৱৰ্তে আপোনাৰ পছন্দৰ যিকোনো লিখনী টাইপ কৰিব পাৰে।

ধৰি লওক, আপোনাৰ বিক্ৰেতাৰ তালিকা আছেএটা স্তম্ভত নাম আৰু আন এটা স্তম্ভত বিক্ৰীৰ পৰিমাণ। আপোনাৰ কাম হ'ল ব্যৱহাৰকাৰীয়ে F1 ত প্ৰৱেশ কৰা নামৰ সৈতে সংগতি ৰাখি এটা সংখ্যা টানিব। যদি নামটো পোৱা নাযায়, তেনেকুৱা এটা বাৰ্তা প্ৰদৰ্শন কৰক।

A2:A10 ত থকা নাম আৰু C2:C10 ৰ পৰিমাণৰ সৈতে, কামটো নিম্নলিখিত যদি Vlookup সূত্ৰৰ সৈতে পূৰণ কৰিব পাৰি:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

যদি নামটো পোৱা যায়, এটা সংশ্লিষ্ট বিক্ৰীৰ পৰিমাণ ঘূৰাই দিয়া হয়:

যদি লুকআপ মান পোৱা নাযায়, পোৱা হোৱা নাই #N/A ভুলৰ পৰিৱৰ্তে বাৰ্তাটো ওলায়:

এই সূত্ৰটোৱে কেনেকৈ কাম কৰে

সূত্ৰটোৰ যুক্তি অতি সহজ: আপুনি ISNA ফাংচন ব্যৱহাৰ কৰে #N/A ভুলৰ বাবে Vlookup পৰীক্ষা কৰিবলে। যদি এটা ভুল হয়, ISNA এ TRUE ঘূৰাই দিয়ে, অন্যথা FALSE । ওপৰৰ মানসমূহ IF ফাংচনৰ লজিকেল পৰীক্ষালৈ যায়, যি নিম্নলিখিতৰ এটা কৰে:

• যদি লজিকেল পৰীক্ষা TRUE হয় (#N/A ত্ৰুটি), আপোনাৰ বাৰ্তা প্ৰদৰ্শিত হয়।
• যদি লজিকেল পৰীক্ষাটো FALSE হয় (লুকাপ মান পোৱা গৈছে), Vlookup এ সাধাৰণভাৱে এটা মিল ঘূৰাই দিয়ে।

নতুন Excel সংস্কৰণত IFNA VLOOKUP

এক্সেল 2013 ৰ পৰা আৰম্ভ কৰি, আপুনি #N/A ভুল ধৰিবলৈ আৰু নিয়ন্ত্ৰণ কৰিবলৈ IF ISNA ৰ পৰিবৰ্তে IFNA ফাংচন ব্যৱহাৰ কৰিব পাৰে:

আমাৰ উদাহৰণত, সূত্ৰটোৱে হ'ব তলত দিয়া আকৃতি লওক:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

টিপচ্। যদি আপুনি সকলো ধৰণৰ ভুল ট্ৰেপ কৰিব বিচাৰে, কেৱল #N/A নহয়, IFERROR ফাংচনৰ সৈতে VLOOKUP ব্যৱহাৰ কৰক। অধিক বিৱৰণ ইয়াত পোৱা যাব: IFERRORExcel ত VLOOKUP।

Excel Vlookup: যদি পোৱা নাযায় return 0

সংখ্যাগত মানসমূহৰ সৈতে কাম কৰাৰ সময়ত, আপুনি এটা শূন্য ঘূৰাই দিব বিচাৰিব পাৰে যেতিয়া লুকআপ মান পোৱা নাযায়। ইয়াক কৰিবলৈ, ওপৰত আলোচনা কৰা IF ISNA VLOOKUP সূত্ৰটো অলপ পৰিবৰ্তনৰ সৈতে ব্যৱহাৰ কৰক: এটা লিখনী বাৰ্তাৰ পৰিবৰ্তে, IF ফাংচনৰ value_if_true যুক্তিত 0 যোগান ধৰক:

আমাৰ নমুনা টেবুলত, সূত্ৰটো তলত দিয়া ধৰণে যাব:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 আৰু 2013 ৰ শেহতীয়া সংস্কৰণসমূহত, আপুনি IFNA Vlookup সংমিশ্ৰণ পুনৰ ব্যৱহাৰ কৰিব পাৰে:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: যদি পোৱা নাযায় তেন্তে খালী কোষ ঘূৰাই দিয়ক

এইটো আৰু এটা ভিন্নতা "Vlookup if then" বিবৃতিৰ: একো ঘূৰাই নিদিয়ে যেতিয়া লুকআপ মান পোৱা নাযায়। ইয়াৰ বাবে, আপোনাৰ সূত্ৰক #N/A ভুলৰ পৰিবৰ্তে এটা খালী ষ্ট্ৰিং ("") ঘূৰাই দিবলৈ নিৰ্দেশ দিয়ক:

তলত দুটামান সম্পূৰ্ণ সূত্ৰৰ উদাহৰণ:

সকলো এক্সেল সংস্কৰণৰ বাবে:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

এক্সেল ২০১৬ আৰু এক্সেল ২০১৩ৰ বাবে:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

If with Index Match - left vlookup with If condition

অভিজ্ঞ Excel ব্যৱহাৰকাৰীসকলে জানে যে VLOOKUP ফাংচনটোৱেই এক্সেলত উলম্ব লুকআপ কৰাৰ একমাত্ৰ উপায় নহয়। ইয়াৰ বাবেও INDEX MATCH সংমিশ্ৰণ ব্যৱহাৰ কৰিব পাৰি আৰু ই আৰু অধিক শক্তিশালী আৰু বহুমুখী। ভাল খবৰটো হ’ল যে ইনডেক্স মেচে আই এফৰ সৈতে একেলগে কাম কৰিব পাৰে ঠিক একেদৰেইVlookup.

উদাহৰণস্বৰূপে, আপোনাৰ A স্তম্ভত অৰ্ডাৰ নম্বৰ আৰু B স্তম্ভত বিক্ৰেতাৰ নাম আছে। আপুনি এটা নিৰ্দিষ্ট বিক্ৰেতাৰ বাবে অৰ্ডাৰ নম্বৰ টানিবলৈ এটা সূত্ৰ বিচাৰিছে।

Vlookup হ'ব নোৱাৰে এই ক্ষেত্ৰত ব্যৱহাৰ কৰা হয় কাৰণ ই সোঁফালৰ পৰা বাওঁফালে সন্ধান কৰিব নোৱাৰে। সূচী মিলে কোনো বাধা নোহোৱাকৈ কাম কৰিব যেতিয়ালৈকে লুকআপ মান লুকআপ স্তম্ভত পোৱা যায়। যদি নহয়, এটা #N/A ভুল দেখা যাব। প্ৰামাণিক ভুল সংকেতক আপোনাৰ নিজৰ লিখনীৰ সৈতে সলনি কৰিবলে, IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

এক্সেল 2016 আৰু 2016 ত, আপুনি সূত্ৰটো অধিক কৰিবলৈ IF ISNA ৰ পৰিবৰ্তে IFNA ব্যৱহাৰ কৰিব পাৰে compact:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

একেদৰে, আপুনি অন্য If সূত্ৰসমূহত সূচী মিল ব্যৱহাৰ কৰিব পাৰে।

আপুনি এইদৰে ব্যৱহাৰ কৰে Excel ত Vlookup আৰু IF ষ্টেটমেন্ট একেলগে। এই টিউটোৰিয়েলত আলোচনা কৰা সূত্ৰসমূহ ভালদৰে চাবলৈ, আপুনি তলত আমাৰ নমুনা কাৰ্য্যপুস্তিকা ডাউনলোড কৰিবলৈ স্বাগতম। মই আপোনাক পঢ়াৰ বাবে ধন্যবাদ জনাইছো আৰু অহা সপ্তাহত আমাৰ ব্লগত আপোনাক লগ পাম বুলি আশা কৰিছো!

ডাউনলোডৰ বাবে অনুশীলন কাৰ্য্যপুস্তিকা

Excel IF Vlookup - সূত্ৰৰ উদাহৰণ (.xlsx ফাইল)