Vodič pokazuje kako kombinirati V LOOKUP i IF funkciju zajedno u v-potraži s if uvjetom u Excelu. Također ćete naučiti kako koristiti IF ISNA VLOOKUP formule za zamjenu #N/A grešaka vlastitim tekstom, nulom ili praznom ćelijom.

Dok su funkcije VLOOKUP i IF korisne same za sebe, zajedno pružaju još vrednija iskustva. Ovaj vodič podrazumijeva da dobro pamtite sintaksu dvije funkcije, inače ćete možda htjeti nadopuniti svoje znanje slijedeći gornje veze.

Potražite s If naredbom: return True/ False, Yes/No, itd.

Jedan od najčešćih scenarija kada kombinirate If i Vlookup zajedno je upoređivanje vrijednosti koju vraća Vlookup s vrijednošću uzorka i vraćanje Da / Ne ili True / False kao rezultat.

U većini slučajeva, sljedeća generička formula bi dobro funkcionirala:

Prevedena na običan engleski, formula upućuje Excel da vrati True ako je Vlookup tačan (tj. jednak navedenoj vrijednosti). Ako je Vlookup netačan (nije jednak navedenoj vrijednosti), formula vraća False .

U nastavku ćete naći nekoliko stvarnih upotreba ove formule IF Vlookup.

Primjer 1. Potražite određenu vrijednost

Recimo, imate listu stavki u koloni A i količinu u koloni B. Kreirate kontrolnu ploču za svoje korisnike i potrebna vam je formulakoji bi provjerio količinu za artikal u E1 i obavijestio korisnika da li je artikal na zalihama ili je rasprodan.

Količinu izvlačite redovnim Vlookupom s formulom tačnog podudaranja ovako:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Zatim, napišite IF naredbu koja upoređuje rezultat Vlookupa sa nulom i vraća "Ne" ako je jednak 0, "Da" u suprotnom:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

Umjesto Da/Ne , možete vratiti TRUE/FALSE ili Na stanju/Rasprodano ili bilo koja druga dva izbora. Na primjer:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

Također možete usporediti vrijednost koju vraća Vlookup sa sample text . U ovom slučaju, obavezno stavite tekstualni niz u navodnike, kao što je ovaj:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

Primjer 2. Uporedite rezultat Vlookupa s drugom ćelijom

Još jedan tipičan primjer Uslov Vlookup s If u Excelu je poređenje Vlookup izlaza s vrijednošću u drugoj ćeliji. Na primjer, možemo provjeriti da li je veći ili jednak broju u ćeliji G2:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

A ovdje je naša If formula s Vlookupom u akciji:

Na sličan način, možete koristiti bilo koji drugi logički operator zajedno sa referencom ćelije u vašoj formuli Excel If Vlookup.

Primjer 3. Vlookup vrijednosti na kraćoj listi

Da uporedite svaku ćeliju u ciljnoj koloni sa drugom listom i vratite Tačno ili Da ako se pronađe podudaranje, Netačno ili Ne inače, koristite ovu generičku formulu IF ISNA VLOOKUP:

Ako Vlookup rezultira greškom #N/A, formula vraća "Ne", što znači da vrijednost pretraživanja nije pronađena na listi pretraživanja. Ako se pronađe podudaranje, vraća se "Da". Na primjer:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

Ako vaša poslovna logika zahtijeva suprotne rezultate, jednostavno zamijenite "Da" i "Ne" da obrnete logiku formule:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel If Vlookup formula za obavljanje različitih izračuna

Osim prikazivanja vlastitih tekstualnih poruka, If funkcija s Vlookupom može izvoditi različite proračune na osnovu kriterijuma koje navedete.

Uzmimo dalje naš primjer, izračunajmo proviziju određenog prodavca (F1) u zavisnosti od njihove efektivnosti: 20% provizije za one koji su zaradili 200$ i više, 10% za sve ostale .

Za ovo, provjerite da li je vrijednost koju vraća Vlookup veća ili jednaka 200, a ako jeste, pomnožite je sa 20%, inače sa 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Gdje su A2:A10 imena prodavača, a C2:C10 prodaja.

IF ISNA VLOOKUP za sakrivanje #N/A grešaka

Ako funkcija VLOOKUP ne može pronaći navedenu vrijednost, izbacuje grešku #N/A. Da biste uhvatili tu grešku i zamijenili je svojim tekstom, ugradite Vlookup formulu u logički test funkcije IF, na primjer:

Naravno, možete upisati bilo koji tekst umjesto "Nije pronađeno".

Pretpostavimo da imate listu prodavačaimena u jednoj koloni, a iznosi prodaje u drugoj koloni. Vaš zadatak je da povučete broj koji odgovara imenu koje korisnik unese u F1. Ako naziv nije pronađen, prikažite poruku koja to pokazuje.

Sa imenima u A2:A10 i iznosima C2:C10, zadatak se može ispuniti sa sljedećom formulom If Vlookup:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

Ako je ime pronađeno, vraća se odgovarajući iznos prodaje:

Ako vrijednost pretraživanja nije pronađena, Nije pronađeno umjesto greške #N/A pojavljuje se poruka:

Kako ova formula funkcionira

Logika formule je vrlo jednostavna: koristite ISNA funkciju da provjerite Vlookup za #N/A greške. Ako dođe do greške, ISNA vraća TRUE, inače FALSE. Gore navedene vrijednosti idu na logički test funkcije IF, koji radi jedno od sljedećeg:

• Ako je logički test TRUE (#N/A greška), prikazuje se vaša poruka.
• Ako je logički test FALSE (pronađena je vrijednost pretraživanja), Vlookup vraća podudaranje normalno.

IFNA VLOOKUP u novijim verzijama Excela

Počevši od Excela 2013, vi može koristiti funkciju IFNA umjesto IF ISNA za hvatanje i rukovanje greškama #N/A:

U našem primjeru, formula bi poprimi sljedeći oblik:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

Savjet. Ako želite da uhvatite sve vrste grešaka, ne samo #N/A, koristite VLOOKUP u kombinaciji sa funkcijom IFERROR. Više detalja možete pronaći ovdje: IFERRORVLOOKUP u Excelu.

Excel Vlookup: ako nije pronađen vrati 0

Kada radite s brojčanim vrijednostima, možda ćete htjeti vratiti nulu kada vrijednost pretraživanja nije pronađena. Da biste to učinili, koristite formulu IF ISNA VLOOKUP o kojoj smo gore govorili uz malu modifikaciju: umjesto tekstualne poruke, unesite 0 u argument value_if_true funkcije IF:

U našoj tablici uzorka, formula bi izgledala kako slijedi:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

U najnovije verzije Excela 2016 i 2013, možete ponovo koristiti kombinaciju IFNA Vlookup:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: ako nije pronađen vratite praznu ćeliju

Ovo je još jedna varijacija naredbe "Vlookup if then": ne vraća ništa kada vrijednost pretraživanja nije pronađena. Da biste to učinili, uputite svoju formulu da vrati prazan niz ("") umjesto greške #N/A:

U nastavku je nekoliko primjera kompletnih formula:

Za sve verzije Excela:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Za Excel 2016 i Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

If with Index Match - lijevo vlookup sa If uvjetom

Iskusni korisnici Excela znaju da funkcija VLOOKUP nije jedini način da se izvrši vertikalno traženje u Excelu. Kombinacija INDEX MATCH se također može koristiti u tu svrhu i još je snažnija i svestranija. Dobra vijest je da Index Match može raditi zajedno sa IF na potpuno isti način kaoVlookup.

Na primjer, imate brojeve narudžbi u koloni A i imena prodavača u koloni B. Tražite formulu za povlačenje broja narudžbe za određenog prodavca.

Vlookup ne može biti koristi se u ovom slučaju jer ne može pretraživati ​​s desna na lijevo. Podudaranje indeksa će raditi bez problema sve dok se vrijednost pretraživanja nalazi u koloni za pretraživanje. Ako nije, pojavit će se greška #N/A. Da biste zamijenili standardnu ​​notaciju greške vlastitim tekstom, ugniježdite podudaranje indeksa unutar IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

U Excelu 2016 i 2016 možete koristiti IFNA umjesto IF ISNA da biste formulu učinili više compact:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

Na sličan način možete koristiti Index Match u drugim If formulama.

Ovako koristite Naredba Vlookup i IF zajedno u Excelu. Da biste bliže pogledali formule o kojima se govori u ovom vodiču, možete preuzeti naš primjer radne sveske ispod. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeće sedmice!

Vježbanje za preuzimanje

Excel IF Vlookup - primjeri formule (.xlsx datoteka)