يوضح البرنامج التعليمي كيفية الجمع بين وظيفة V LOOKUP و IF معًا للبحث عن v مع شرط if في Excel. سوف تتعلم أيضًا كيفية استخدام صيغ IF ISNA VLOOKUP لاستبدال أخطاء # N / A بالنص الخاص بك ، أو خلية فارغة أو صفرية.

بينما تكون وظائف VLOOKUP و IF مفيدة بمفردها ، معًا يقدمون تجارب أكثر قيمة. يشير هذا البرنامج التعليمي إلى أنك تتذكر بناء جملة الوظيفتين جيدًا ، وإلا فقد ترغب في تحسين معرفتك باتباع الروابط أعلاه.

Vlookup with If statement: return True / خطأ ، نعم / لا ، إلخ.

أحد أكثر السيناريوهات شيوعًا عند الجمع بين If و Vlookup معًا هو مقارنة القيمة التي يتم إرجاعها بواسطة Vlookup بقيمة عينة وإرجاع نعم / لا أو صواب / خطأ كنتيجة.

في معظم الحالات ، ستعمل الصيغة العامة التالية بشكل جيد:

مترجمة إلى الإنجليزية العادية ، فإن الصيغة توجه Excel لإرجاع True إذا كان Vlookup صحيحًا (أي يساوي القيمة المحددة). إذا كانت Vlookup خاطئة (لا تساوي القيمة المحددة) ، ترجع الصيغة False .

أدناه ستجد بعض الاستخدامات الواقعية لصيغة IF Vlookup.

مثال 1. ابحث عن قيمة محددة

لنفترض أن لديك قائمة بالعناصر في العمود A والكمية في العمود B. أنت تنشئ لوحة معلومات للمستخدمين وتحتاج إلى صيغةمن شأنها أن تتحقق من كمية عنصر في E1 وتُعلم المستخدم ما إذا كان العنصر في المخزن أم تم بيعه.

يمكنك سحب الكمية باستخدام Vlookup العادي مع صيغة مطابقة تامة مثل:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

بعد ذلك ، اكتب عبارة IF التي تقارن نتيجة Vlookup بصفر ، وتُرجع "لا" إذا كانت تساوي 0 ، أو "نعم" بخلاف ذلك:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

بدلاً من نعم / لا ، يمكنك إرجاع TRUE / FALSE أو متوفر / مباع أو أي اثنين آخرين اختيارات. على سبيل المثال:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

يمكنك أيضًا مقارنة القيمة التي أرجعها Vlookup بنموذج نص . في هذه الحالة ، تأكد من إحاطة سلسلة نصية بعلامات اقتباس ، مثل هذا:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

مثال 2. قارن نتيجة Vlookup بخلية أخرى

مثال نموذجي آخر على يقوم شرط Vlookup مع If في Excel بمقارنة إخراج Vlookup بقيمة في خلية أخرى. على سبيل المثال ، يمكننا التحقق مما إذا كان أكبر من أو يساوي رقمًا في الخلية G2:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

وإليك صيغة If لدينا مع تشغيل Vlookup:

بطريقة مماثلة ، يمكنك استخدام أي عامل منطقي آخر مع مرجع خلية في صيغة Excel If Vlookup.

مثال 3. قيم Vlookup في قائمة أقصر

لمقارنة كل خلية في العمود الهدف بقائمة أخرى وإرجاع صحيح أو نعم إذا تم العثور على تطابق ، خطأ أو لا خلاف ذلك ، استخدم صيغة IF ISNA VLOOKUP العامة هذه:

إذا نتج عن VLOOKUP الخطأ # N / A ، تُرجع الصيغة "لا" ، مما يعني أن قيمة البحث غير موجودة في قائمة البحث. إذا تم العثور على تطابق ، يتم إرجاع "نعم". على سبيل المثال:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

إذا كان منطق عملك يتطلب نتائج معاكسة ، فما عليك سوى تبديل "نعم" و "لا" لعكس منطق الصيغة:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel إذا كانت صيغة Vlookup لإجراء حسابات مختلفة

إلى جانب عرض الرسائل النصية الخاصة بك ، إذا كانت الوظيفة مع Vlookup يمكنها إجراء حسابات مختلفة بناءً على المعايير التي تحددها.

إذا أخذنا مثالنا إلى أبعد من ذلك ، فلنحسب عمولة بائع معين (F1) اعتمادًا على فعاليتها: 20٪ عمولة لمن كسب 200 دولار وأكثر ، 10٪ لأي شخص آخر .

لهذا ، تتحقق مما إذا كانت القيمة التي أرجعها Vlookup أكبر من أو تساوي 200 ، وإذا كانت كذلك ، فاضربها بنسبة 20٪ ، وإلا في 10٪:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

حيث A2: A10 هي أسماء البائعين و C2: C10 عبارة عن مبيعات.

IF ISNA VLOOKUP لإخفاء أخطاء # N / A

إذا لم تتمكن الدالة VLOOKUP من العثور على قيمة محددة ، فإنها تعرض الخطأ # N / A. للقبض على هذا الخطأ واستبداله بالنص الخاص بك ، قم بتضمين صيغة Vlookup في الاختبار المنطقي لوظيفة IF ، مثل هذا:

بطبيعة الحال ، يمكنك كتابة أي نص تريده بدلاً من "غير موجود".

لنفترض أن لديك قائمة البائعينأسماء في عمود ومبالغ المبيعات في عمود آخر. مهمتك هي سحب رقم مطابق للاسم الذي يدخله المستخدم في F1. إذا لم يتم العثور على الاسم ، اعرض رسالة تشير إلى ذلك.

باستخدام الأسماء الموجودة في A2: A10 والمبالغ C2: C10 ، يمكن تنفيذ المهمة باستخدام صيغة If Vlookup التالية:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

إذا تم العثور على الاسم ، يتم إرجاع مبلغ المبيعات المقابل:

إذا لم يتم العثور على قيمة البحث ، فإن غير موجود تظهر الرسالة بدلاً من الخطأ # N / A:

كيف تعمل هذه الصيغة

منطق الصيغة بسيط للغاية: يمكنك استخدام وظيفة ISNA للتحقق من Vlookup بحثًا عن أخطاء # N / A. في حالة حدوث خطأ ، تقوم ISNA بإرجاع TRUE ، وإلا سترجع FALSE. تنتقل القيم أعلاه إلى الاختبار المنطقي لوظيفة IF ، والذي يقوم بأحد الإجراءات التالية:

• إذا كان الاختبار المنطقي صحيحًا (خطأ # N / A) ، فسيتم عرض رسالتك.
• إذا كان الاختبار المنطقي هو FALSE (تم العثور على قيمة البحث) ، فترجع Vlookup تطابقًا بشكل طبيعي.

IFNA VLOOKUP في إصدارات Excel الأحدث

بدءًا من Excel 2013 ، أنت يمكن استخدام دالة IFNA بدلاً من IF ISNA للقبض على أخطاء # N / A ومعالجتها:

في مثالنا ، خذ الشكل التالي:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

نصيحة. إذا كنت ترغب في اعتراض جميع أنواع الأخطاء ، وليس فقط # N / A ، فاستخدم VLOOKUP مع وظيفة IFERROR. يمكن العثور على مزيد من التفاصيل هنا: IFERRORVLOOKUP في Excel.

Excel Vlookup: إذا لم يتم العثور على إرجاع 0

عند العمل مع القيم الرقمية ، قد ترغب في إرجاع صفر عندما لا يتم العثور على قيمة البحث. للقيام بذلك ، استخدم صيغة IF ISNA VLOOKUP التي تمت مناقشتها أعلاه مع تعديل بسيط: بدلاً من رسالة نصية ، قم بتوفير 0 في وسيطة الدالة IF value_if_true :

في جدول العينة الخاص بنا ، ستظهر الصيغة على النحو التالي:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

في الإصدارات الحديثة من Excel 2016 و 2013 ، يمكنك استخدام تركيبة IFNA Vlookup مرة أخرى:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: إذا لم يتم العثور على خلية فارغة ، فقم بإرجاع الخلية الفارغة

هذا هو شكل آخر آخر من عبارة "Vlookup if then": لا تُرجع شيئًا عندما لا يتم العثور على قيمة البحث. للقيام بذلك ، قم بإرشاد الصيغة الخاصة بك لإرجاع سلسلة فارغة ("") بدلاً من الخطأ # N / A:

أدناه بعض الأمثلة الكاملة للصيغ:

لجميع إصدارات Excel:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

لبرنامج Excel 2016 و Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

إذا كان الأمر مع مطابقة الفهرس - مع البحث الأيسر مع شرط If

يعرف مستخدمو Excel المتمرسون أن وظيفة VLOOKUP ليست هي الطريقة الوحيدة لإجراء بحث عمودي في Excel. يمكن أيضًا استخدام مجموعة INDEX MATCH لهذا الغرض وهي أكثر قوة وتنوعًا. والخبر السار هو أن Index Match يمكن أن يعمل مع IF بنفس الطريقة تمامًا مثلVlookup.

على سبيل المثال ، لديك أرقام الطلبات في العمود A وأسماء البائعين في العمود B. أنت تبحث عن صيغة لسحب رقم الطلب لبائع معين.

لا يمكن أن يكون Vlookup مستخدم في هذه الحالة لأنه لا يمكنه البحث من اليمين إلى اليسار. ستعمل مطابقة الفهرس بدون وجود عوائق طالما تم العثور على قيمة البحث في عمود البحث. إذا لم يكن الأمر كذلك ، فسيظهر خطأ # N / A. لاستبدال تدوين الخطأ القياسي بالنص الخاص بك ، قم بتداخل مطابقة الفهرس داخل IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

في Excel 2016 و 2016 ، يمكنك استخدام IFNA بدلاً من IF ISNA لجعل الصيغة أكثر مضغوط:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

بطريقة مماثلة ، يمكنك استخدام مطابقة الفهرس في صيغ أخرى.

هذه هي الطريقة التي تستخدمها بيان Vlookup و IF معًا في Excel. لإلقاء نظرة فاحصة على الصيغ التي تمت مناقشتها في هذا البرنامج التعليمي ، فنحن نرحب بك لتنزيل نموذج المصنف أدناه. أشكرك على القراءة وآمل أن أراك على مدونتنا الأسبوع المقبل!

تدرب على المصنف للتنزيل

Excel IF Vlookup - أمثلة على الصيغ (ملف .xlsx)