Упатството покажува како да се комбинираат V LOOKUP и IF функциите заедно за пребарување v со условот if во Excel. Исто така, ќе научите како да ги користите формулите IF ISNA VLOOKUP за да ги замените #N/A грешките со сопствен текст, нула или празна ќелија.

Додека функциите VLOOKUP и IF се корисни сами по себе, заедно тие даваат уште повредни искуства. Овој туторијал подразбира дека добро се сеќавате на синтаксата на двете функции, инаку можеби ќе сакате да го подобрите вашето знаење следејќи ги горните врски. Неточно, Да/Не, итн.

Едно од најчестите сценарија кога се комбинираат If и Vlookup заедно е да се спореди вредноста вратена од Vlookup со примерок вредност и да се врати Да / Не или Точно / Неточно како резултат.

Во повеќето случаи, следнава генеричка формула би функционирала убаво:

Преведено на обичен англиски, формулата му наложува на Excel да врати True ако Vlookup е точно (т.е. еднакво на наведената вредност). Ако Vlookup е неточен (не е еднаков на наведената вредност), формулата враќа False .

Подолу ќе најдете неколку реални употреби на оваа формула IF Vlookup.

Пример 1. Побарајте одредена вредност

Да речеме, имате список на ставки во колоната А и количина во колоната Б. Вие креирате контролна табла за вашите корисници и ви треба формулашто би ја проверило количината за артикал во Е1 и би го информирал корисникот дали артиклот е на залиха или распродаден.

Количината ја повлекувате со обичен Vlookup со формула точно за совпаѓање како оваа:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Потоа, напишете изјава IF што го споредува резултатот на Vlookup со нула и враќа „Не“ ако е еднакво на 0, „Да“ во спротивно:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

Наместо Да/Не , можете да вратите TRUE/FALSE или На залиха/Продадено или кои било други избори. На пример:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

Можете и да ја споредите вредноста вратена од Vlookup со примерок текст . Во овој случај, задолжително приложете текстуална низа во наводници, вака:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

Пример 2. Споредете го резултатот од Vlookup со друга ќелија

Друг типичен пример за Vlookup со условот If во Excel е споредување на излезот Vlookup со вредност во друга ќелија. На пример, можеме да провериме дали е поголем или еднаков на број во ќелијата G2:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

И тука е нашата формула If со Vlookup во акција:

На сличен начин, можете да користите кој било друг логички оператор заедно со референца на ќелија во формулата Excel If Vlookup.

Пример 3. Вредности на Vlookup во пократок список

За да се спореди секоја ќелија во целната колона со друга листа и да се врати Точно или Да ако се најде совпаѓање, Неточно или Не во спротивно, користете ја оваа генеричка формула IF ISNA VLOOKUP:

Ако Vlookup резултира со грешка #N/A, формулата враќа „Не“, што значи дека вредноста за пребарување не е пронајдена во списокот за пребарување. Доколку се пронајде совпаѓањето, се враќа „Да“. На пример:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

Ако вашата деловна логика бара спротивни резултати, едноставно заменете ги „Да“ и „Не“ за да ја промените логиката на формулата:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel If Vlookup формула за извршување на различни пресметки

Покрај прикажувањето на вашите сопствени текстуални пораки, ако функцијата со Vlookup може да врши различни пресметки врз основа на критериумите што ги одредувате.

Земајќи го нашиот пример понатаму, ајде да ја пресметаме провизијата на одреден продавач (F1) во зависност од нивната ефикасност: 20% провизија за оние кои заработиле 200 долари и повеќе, 10% за сите останати .

За ова, проверувате дали вредноста што ја враќа Vlookup е поголема или еднаква на 200, а ако е, помножете ја со 20%, во спротивно со 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Каде што A2:A10 се имињата на продавачите, а C2:C10 се продажните.

IF ISNA VLOOKUP за да се сокријат #N/A грешки

Ако функцијата VLOOKUP не може да најде одредена вредност, исфрла грешка #N/A. За да ја сфатите таа грешка и да ја замените со ваш сопствен текст, вметнете ја формулата Vlookup во логичкиот тест на функцијата IF, вака:

Нормално, можете да напишете кој било текст што го сакате наместо „Не е пронајден“.

Да се ​​претпостави дека имате список на продавачиимиња во една колона и продажни износи во друга колона. Ваша задача е да повлечете број што одговара на името што корисникот го внесува во F1. Ако името не е пронајдено, прикажете порака што го покажува тоа.

Со имињата во A2:A10 и износите C2:C10, задачата може да се исполни со следнава формула If Vlookup:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

Ако се најде името, се враќа соодветната продажна сума:

Ако не се најде вредноста за пребарување, Не е пронајдена наместо грешката #N/A се појавува порака:

Како функционира оваа формула

Логиката на формулата е многу едноставна: ја користите функцијата ISNA за да го проверите Vlookup за #N/A грешки. Ако се појави грешка, ISNA враќа ТОЧНО, инаку НЕТОЧНО. Горенаведените вредности одат на логичкиот тест на функцијата IF, кој прави едно од следново:

• Ако логичкиот тест е ТОЧЕН (#N/A грешка), се прикажува вашата порака.
• Ако логичкиот тест е НЕТОЧЕН (пронајдена е вредноста за пребарување), Vlookup враќа совпаѓање нормално.

IFNA VLOOKUP во поновите верзии на Excel

Почнувајќи со Excel 2013, вие може да ја користи функцијата IFNA наместо IF ISNA за фаќање и справување со #N/A грешки:

Во нашиот пример, формулата би земете ја следната форма:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

Совет. Ако сакате да заробите секакви грешки, не само #N/A, користете VLOOKUP во комбинација со функцијата IFERROR. Повеќе детали можете да најдете овде: IFERRORVLOOKUP во Excel.

Excel Vlookup: ако не е пронајден враќа 0

Кога работите со нумерички вредности, можеби ќе сакате да вратите нула кога вредноста за пребарување не е пронајдена. За да го направите тоа, користете ја формулата IF ISNA VLOOKUP дискутирана погоре со мала промена: наместо текстуална порака, внесете 0 во аргументот value_if_true на функцијата IF:

Во нашата табела со примероци, формулата ќе оди на следниов начин:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Во неодамнешните верзии на Excel 2016 и 2013 година, можете повторно да ја користите комбинацијата IFNA Vlookup:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: ако не се најде вратете ја празна ќелија

Ова е уште една варијација од изјавата „Vlookup if then“: не враќај ништо кога не е пронајдена вредноста за пребарување. За да го направите ова, наредете ја вашата формула да врати празна низа ("") наместо грешката #N/A:

Подолу се неколку целосни примери на формула:

За сите верзии на Excel:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

За Excel 2016 и Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

If with Index Match - лево vlookup со услов If

Искусни корисници на Excel знаат дека функцијата VLOOKUP не е единствениот начин за вертикално пребарување во Excel. Комбинацијата INDEX MATCH може да се користи и за оваа намена и е уште помоќна и разноврсна. Добрата вест е дека Index Match може да работи заедно со IF на ист начин какоVlookup.

На пример, имате броеви на нарачки во колоната А и имиња на продавачи во колона Б. Барате формула за да го повлечете бројот на нарачката за одреден продавач.

Vlookup не може да биде се користи во овој случај бидејќи не може да пребарува од десно кон лево. Index Match ќе работи без проблем сè додека вредноста за пребарување се наоѓа во колоната за пребарување. Ако не, ќе се појави грешка # N/A. За да ја замените стандардната нотација за грешка со сопствен текст, вметнете го Index Match во IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Во Excel 2016 и 2016 година, можете да користите IFNA наместо IF ISNA за да ја направите формулата повеќе компактен:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

На сличен начин, можете да го користите Index Match во други формули If.

Вака го користите Vlookup и IF изјава заедно во Excel. За да ги разгледате подетално формулите дискутирани во ова упатство, добредојдени сте да ја преземете нашата работна книга примерок подолу. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!

Вежбајте работна книга за преземање

Excel IF Vlookup - примери на формула (датотека .xlsx)