Το σεμινάριο δείχνει πώς να συνδυάσετε το V LOOKUP και τη λειτουργία IF μαζί για v-lookup με συνθήκη if στο Excel. Θα μάθετε επίσης πώς να χρησιμοποιείτε τους τύπους IF ISNA VLOOKUP για να αντικαταστήσετε τα σφάλματα #N/A με το δικό σας κείμενο, μηδέν ή κενό κελί.

Ενώ οι συναρτήσεις VLOOKUP και IF είναι χρήσιμες από μόνες τους, μαζί προσφέρουν ακόμη πιο πολύτιμες εμπειρίες. Αυτό το σεμινάριο προϋποθέτει ότι θυμάστε καλά τη σύνταξη των δύο συναρτήσεων, διαφορετικά ίσως να θέλετε να αναβαθμίσετε τις γνώσεις σας ακολουθώντας τους παραπάνω συνδέσμους.

Vlookup με δήλωση If: επιστροφή True/False, Yes/No, κ.λπ.

Ένα από τα πιο συνηθισμένα σενάρια όταν συνδυάζετε το If και το Vlookup μαζί είναι να συγκρίνετε την τιμή που επιστρέφει το Vlookup με μια δειγματική τιμή και να επιστρέψετε Ναι / Όχι ή Σωστό / Λάθος ως αποτέλεσμα.

Στις περισσότερες περιπτώσεις, ο ακόλουθος γενικός τύπος θα μπορούσε να λειτουργήσει ικανοποιητικά:

Μεταφρασμένος σε απλά αγγλικά, ο τύπος δίνει εντολή στο Excel να επιστρέψει Αλήθεια εάν η Vlookup είναι αληθής (δηλαδή ίση με την καθορισμένη τιμή). Εάν η Vlookup είναι ψευδής (δεν είναι ίση με την καθορισμένη τιμή), ο τύπος επιστρέφει Ψευδές .

Παρακάτω θα βρείτε μερικές πραγματικές χρήσεις αυτού του τύπου IF Vlookup.

Παράδειγμα 1. Αναζήτηση μιας συγκεκριμένης τιμής

Ας υποθέσουμε ότι έχετε μια λίστα με είδη στη στήλη Α και ποσότητα στη στήλη Β. Δημιουργείτε ένα ταμπλό για τους χρήστες σας και χρειάζεστε έναν τύπο που θα ελέγχει την ποσότητα για ένα είδος στη στήλη Ε1 και θα ενημερώνει τον χρήστη εάν το είδος είναι σε απόθεμα ή εξαντλήθηκε.

Βγάζετε την ποσότητα με ένα κανονικό Vlookup με τύπο ακριβούς αντιστοίχισης όπως αυτός:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Στη συνέχεια, γράψτε μια δήλωση IF που συγκρίνει το αποτέλεσμα του Vlookup με το μηδέν και επιστρέφει "Όχι" αν είναι ίσο με 0, "Ναι" διαφορετικά:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0, "Όχι", "Ναι")

Αντί για Ναι/Όχι , μπορείτε να επιστρέψετε ΣΩΣΤΟ/ΛΑΘΟΣ ή Σε απόθεμα/ξεπούλησε ή οποιεσδήποτε άλλες δύο επιλογές. Για παράδειγμα:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0, "Sold out", "In stock")

Μπορείτε επίσης να συγκρίνετε την τιμή που επιστρέφει το Vlookup με το δείγμα κείμενο Σε αυτή την περίπτωση, φροντίστε να περικλείσετε μια συμβολοσειρά κειμένου σε εισαγωγικά, όπως εδώ:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

Παράδειγμα 2. Σύγκριση αποτελέσματος Vlookup με άλλο κελί

Ένα άλλο τυπικό παράδειγμα του Vlookup με συνθήκη If στο Excel είναι η σύγκριση της εξόδου του Vlookup με μια τιμή σε ένα άλλο κελί. Για παράδειγμα, μπορούμε να ελέγξουμε αν είναι μεγαλύτερη ή ίση με έναν αριθμό στο κελί G2:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2, "Ναι!", "Όχι")

Και εδώ είναι ο τύπος If με Vlookup σε δράση:

Με παρόμοιο τρόπο, μπορείτε να χρησιμοποιήσετε οποιονδήποτε άλλο λογικό τελεστή μαζί με μια αναφορά κελιού στον τύπο Vlookup του Excel If.

Παράδειγμα 3. Τιμές Vlookup σε μια μικρότερη λίστα

Για να συγκρίνετε κάθε κελί στη στήλη-στόχο με μια άλλη λίστα και να επιστρέψετε Αλήθεια ή Ναι αν βρεθεί μια αντιστοιχία, Ψευδές ή Όχι διαφορετικά, χρησιμοποιήστε αυτόν τον γενικό τύπο IF ISNA VLOOKUP:

Εάν το Vlookup καταλήξει στο σφάλμα #N/A, ο τύπος επιστρέφει "Όχι", που σημαίνει ότι η τιμή αναζήτησης δεν βρίσκεται στη λίστα αναζήτησης. Εάν η αντιστοιχία βρεθεί, επιστρέφεται "Ναι". Για παράδειγμα:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)), "No", "Yes")

Εάν η επιχειρησιακή σας λογική απαιτεί τα αντίθετα αποτελέσματα, απλά ανταλλάξτε τα "Ναι" και "Όχι" για να αντιστρέψετε τη λογική του τύπου:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)), "Yes", "No")

Excel Εάν ο τύπος Vlookup για την εκτέλεση διαφορετικών υπολογισμών

Εκτός από την εμφάνιση των δικών σας μηνυμάτων κειμένου, η λειτουργία If με Vlookup μπορεί να εκτελέσει διαφορετικούς υπολογισμούς με βάση τα κριτήρια που καθορίζετε.

Συνεχίζοντας το παράδειγμά μας, ας υπολογίσουμε την προμήθεια ενός συγκεκριμένου πωλητή (F1) ανάλογα με την αποτελεσματικότητά του: 20% προμήθεια για όσους έβγαλαν 200 δολάρια και πάνω, 10% για όλους τους άλλους.

Για το σκοπό αυτό, ελέγχετε αν η τιμή που επιστρέφει το Vlookup είναι μεγαλύτερη ή ίση με 200 και, αν είναι, την πολλαπλασιάζετε με 20%, διαφορετικά με 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Όπου A2:A10 είναι τα ονόματα των πωλητών και C2:C10 είναι οι πωλήσεις.

IF ISNA VLOOKUP για την απόκρυψη σφαλμάτων #N/A

Εάν η συνάρτηση VLOOKUP δεν μπορεί να βρει μια καθορισμένη τιμή, πετάει ένα σφάλμα #N/A. Για να πιάσετε αυτό το σφάλμα και να το αντικαταστήσετε με το δικό σας κείμενο, ενσωματώστε έναν τύπο Vlookup στη λογική δοκιμή της συνάρτησης IF, όπως παρακάτω:

Φυσικά, μπορείτε να πληκτρολογήσετε οποιοδήποτε κείμενο θέλετε αντί για το "Δεν βρέθηκε".

Ας υποθέσουμε ότι έχετε μια λίστα με ονόματα πωλητών σε μια στήλη και ποσά πωλήσεων σε μια άλλη στήλη. Ο στόχος σας είναι να βγάλετε έναν αριθμό που αντιστοιχεί στο όνομα που εισάγει ο χρήστης στην F1. Αν το όνομα δεν βρεθεί, εμφανίστε ένα μήνυμα που να το αναφέρει.

Με τα ονόματα στα A2:A10 και τα ποσά C2:C10, η εργασία μπορεί να εκπληρωθεί με τον ακόλουθο τύπο If Vlookup:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Δεν βρέθηκε", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

Εάν βρεθεί το όνομα, επιστρέφεται το αντίστοιχο ποσό πώλησης:

Εάν η τιμή αναζήτησης δεν βρεθεί, η Δεν βρέθηκε αντί για το σφάλμα #N/A:

Πώς λειτουργεί αυτή η φόρμουλα

Η λογική του τύπου είναι πολύ απλή: χρησιμοποιείτε τη συνάρτηση ISNA για να ελέγξετε το Vlookup για σφάλματα #N/A. Εάν προκύψει σφάλμα, η ISNA επιστρέφει TRUE, διαφορετικά FALSE. Οι παραπάνω τιμές πηγαίνουν στον λογικό έλεγχο της συνάρτησης IF, η οποία κάνει ένα από τα ακόλουθα:

• Εάν ο λογικός έλεγχος είναι ΑΛΗΘΗΣ (σφάλμα #N/A), εμφανίζεται το μήνυμά σας.
• Εάν ο λογικός έλεγχος είναι FALSE (η τιμή αναζήτησης έχει βρεθεί), το Vlookup επιστρέφει κανονικά μια αντιστοιχία.

IFNA VLOOKUP σε νεότερες εκδόσεις του Excel

Από το Excel 2013, μπορείτε να χρησιμοποιήσετε τη συνάρτηση IFNA αντί της IF ISNA για να εντοπίσετε και να χειριστείτε σφάλματα #N/A:

Στο παράδειγμά μας, ο τύπος θα έχει την ακόλουθη μορφή:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Δεν βρέθηκε")

Συμβουλή. Αν θέλετε να παγιδεύσετε όλα τα είδη σφαλμάτων, όχι μόνο #N/A, χρησιμοποιήστε το VLOOKUP σε συνδυασμό με τη συνάρτηση IFERROR. Περισσότερες λεπτομέρειες μπορείτε να βρείτε εδώ: IFERROR VLOOKUP στο Excel.

Excel Vlookup: αν δεν βρεθεί επιστρέφει 0

Όταν εργάζεστε με αριθμητικές τιμές, μπορεί να θέλετε να επιστρέφετε ένα μηδέν όταν η τιμή αναζήτησης δεν βρίσκεται. Για να το κάνετε αυτό, χρησιμοποιήστε τον τύπο IF ISNA VLOOKUP που συζητήθηκε παραπάνω με μια μικρή τροποποίηση: αντί για ένα μήνυμα κειμένου, δώστε 0 στο πεδίο value_if_true όρισμα της συνάρτησης IF:

Στον πίνακα του δείγματός μας, ο τύπος θα έχει ως εξής:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Στις πρόσφατες εκδόσεις του Excel 2016 και 2013, μπορείτε να χρησιμοποιήσετε ξανά τον συνδυασμό IFNA Vlookup:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: αν δεν βρεθεί επιστρέφει κενό κελί

Αυτή είναι μια ακόμη παραλλαγή της δήλωσης "Vlookup if then": μην επιστρέφετε τίποτα όταν η τιμή αναζήτησης δεν βρίσκεται. Για να το κάνετε αυτό, δώστε εντολή στον τύπο σας να επιστρέφει μια κενή συμβολοσειρά ("") αντί για το σφάλμα #N/A:

Ακολουθούν μερικά παραδείγματα πλήρων τύπων:

Για όλες τις εκδόσεις του Excel:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Για το Excel 2016 και το Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

If με Index Match - αριστερό vlookup με συνθήκη If

Οι έμπειροι χρήστες του Excel γνωρίζουν ότι η συνάρτηση VLOOKUP δεν είναι ο μόνος τρόπος για να κάνετε κάθετη αναζήτηση στο Excel. Ο συνδυασμός INDEX MATCH μπορεί επίσης να χρησιμοποιηθεί για το σκοπό αυτό και είναι ακόμη πιο ισχυρός και ευέλικτος. Τα καλά νέα είναι ότι ο συνδυασμός Index Match μπορεί να λειτουργήσει μαζί με το IF με τον ίδιο ακριβώς τρόπο όπως η Vlookup.

Για παράδειγμα, έχετε αριθμούς παραγγελιών στη στήλη Α και ονόματα πωλητών στη στήλη Β. Ψάχνετε για έναν τύπο για να αντλήσετε τον αριθμό παραγγελίας για έναν συγκεκριμένο πωλητή.

Το Vlookup δεν μπορεί να χρησιμοποιηθεί σε αυτή την περίπτωση, επειδή δεν μπορεί να κάνει αναζήτηση από τα δεξιά προς τα αριστερά. Το Index Match θα λειτουργήσει χωρίς πρόβλημα εφόσον η τιμή αναζήτησης βρίσκεται στη στήλη αναζήτησης. Αν όχι, θα εμφανιστεί ένα σφάλμα #N/A. Για να αντικαταστήσετε την τυπική σημείωση σφάλματος με το δικό σας κείμενο, φωλιάστε το Index Match μέσα στο IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Δεν βρέθηκε", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Στο Excel 2016 και 2016, μπορείτε να χρησιμοποιήσετε IFNA αντί για IF ISNA για να κάνετε τον τύπο πιο συμπαγή:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Δεν βρέθηκε")

Με παρόμοιο τρόπο, μπορείτε να χρησιμοποιήσετε την αντιστοίχιση ευρετηρίου σε άλλους τύπους If.

Με αυτόν τον τρόπο χρησιμοποιείτε το Vlookup και τη δήλωση IF μαζί στο Excel. Για να ρίξετε μια πιο προσεκτική ματιά στους τύπους που συζητήθηκαν σε αυτό το σεμινάριο, μπορείτε να κατεβάσετε το δείγμα του βιβλίου εργασίας μας παρακάτω. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω στο blog μας την επόμενη εβδομάδα!

Βιβλίο ασκήσεων για κατέβασμα

Excel IF Vlookup - παραδείγματα τύπων (.xlsx αρχείο)