ٽيوٽوريل ڏيکاري ٿو ته ڪيئن گڏ ڪجي V LOOKUP ۽ IF فنڪشن کي گڏجي وي-lookup ڪرڻ لاءِ if condition سان Excel ۾. توهان اهو پڻ سکندا ته ڪيئن استعمال ڪجي IF ISNA VLOOKUP فارمولين کي بدلائڻ لاءِ #N/A غلطين کي پنهنجي متن، صفر يا خالي سيل سان.

جڏهن ته VLOOKUP ۽ IF فنڪشن پاڻ ۾ ڪارآمد آهن، گڏو گڏ اهي اڃا به وڌيڪ قيمتي تجربا فراهم ڪن ٿا. ھن سبق جو مطلب آھي ته توھان ٻنھي ڪمن جي نحو کي چڱيءَ طرح ياد رکو، ٻي صورت ۾ توھان مٿي ڏنل لنڪ تي عمل ڪري پنھنجي ڄاڻ ۾ اضافو ڪرڻ چاھيو ٿا.

Vlookup with If بيان: return True/ غلط، ها/نه، وغيره.

هڪ عام منظرنامن مان جڏهن توهان If ۽ Vlookup کي گڏ ڪريو ٿا ته Vlookup پاران واپس ڪيل قدر کي نموني جي قيمت سان ڀيٽڻ ۽ واپسي ها / نه يا True/False نتيجي طور.

اڪثر صورتن ۾، هيٺين عام فارمولا چڱيءَ طرح ڪم ڪندو:

سادي انگريزيءَ ۾ ترجمو ٿيل، فارمولا Excel کي واپس ڪرڻ جي هدايت ڪري ٿو True جيڪڏھن Vlookup صحيح آھي (يعني بيان ڪيل قدر جي برابر). جيڪڏهن Vlookup غلط آهي (مخصوص قدر جي برابر نه آهي)، فارمولا واپس اچي ٿو False .

هيٺ توهان هن IF Vlookup فارمولا جا ڪجھ حقيقي استعمال ڳوليندا.

توهان مقدار کي باقاعده Vlookup سان هن طرح سان درست ميچ فارمولا سان ڪڍو:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

پوءِ، هڪ IF بيان لکو جيڪو Vlookup جي نتيجن کي صفر سان موازنہ ڪري، ۽ موٽائي "نه" جيڪڏهن اهو 0 جي برابر آهي، "ها" ٻي صورت ۾:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

جي بدران ها/نه ، توهان واپس ڪري سگهو ٿا TRUE/FALSE or In Stock/Sold out يا ٻيا ٻه چونڊون. مثال طور:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

توهان نموني سان Vlookup پاران موٽايل قدر جو مقابلو پڻ ڪري سگهو ٿا text . انهي صورت ۾، پڪ ڪريو ته ٽيڪسٽ اسٽرنگ کي اقتباس جي نشانين ۾ شامل ڪيو وڃي، جهڙوڪ:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

مثال 2. Vlookup نتيجن کي ٻئي سيل سان ڀيٽ ڪريو

ٻيو عام مثال Vlookup with if حالت ۾ Excel ۾ Vlookup ٻاھر ھڪڙي قيمت سان ڀيٽ ڪري رھيو آھي ٻئي سيل ۾. مثال طور، اسان چيڪ ڪري سگهون ٿا ته اهو سيل G2 ۾ هڪ نمبر کان وڏو يا برابر آهي:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

۽ هتي اسان جو If فارمولا آهي عمل ۾ Vlookup سان:

اهڙي ئي انداز ۾، توهان پنهنجي Excel If Vlookup فارمولا ۾ سيل ريفرنس سان گڏ ڪنهن به ٻئي منطقي آپريٽر کي استعمال ڪري سگهو ٿا.

مثال 3. ننڍي فهرست ۾ Vlookup قدر

هدف واري ڪالمن ۾ هر سيل کي ٻي لسٽ سان ڀيٽڻ ۽ واپس ڪرڻ لاءِ سچو يا ها جيڪڏهن ڪو ميچ ملي ٿو، غلط يا نه ٻي صورت ۾، هي عام IF ISNA VLOOKUP فارمولا استعمال ڪريو:

جيڪڏهن Vlookup جي نتيجي ۾ #N/A غلطي ٿئي ٿي، ته فارمولا موٽائي ٿو "نه"، مطلب ته ڏسندڙ جي قيمت ڏسڻ واري لسٽ ۾ نه ملي. جيڪڏهن ميچ ملي ٿي، "ها" واپسي آهي. مثال طور:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

14>

جيڪڏهن توهان جي ڪاروباري منطق کي مخالف نتيجن جي ضرورت آهي، ته فارمولا جي منطق کي ريورس ڪرڻ لاءِ صرف "ها" ۽ "نه" کي مٽايو:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

15>

Excel If Vlookup فارمولا مختلف حسابن کي انجام ڏيڻ لاءِ

پنهنجا پنهنجا ٽيڪسٽ پيغام ڏيکارڻ کان علاوه، جيڪڏهن Vlookup سان فنڪشن مختلف حسابن کي انجام ڏئي سگهي ٿو توهان جي بيان ڪيل معيار جي بنياد تي.

اسان جي مثال کي اڳتي وڌائيندي، اچو ته هڪ مخصوص وڪرو ڪندڙ جي ڪميشن (F1) جو حساب ڪريون انهن جي اثرائتي جي بنياد تي: 20% ڪميشن انهن لاءِ جن $200 ۽ وڌيڪ ڪيو، 10% ٻين لاءِ .

ان لاءِ، توهان چيڪ ڪريو ته Vlookup پاران موٽايل قيمت 200 کان وڌيڪ يا برابر آهي، ۽ جيڪڏهن آهي، ان کي 20٪ سان ضرب ڪريو، ٻي صورت ۾ 10٪ سان:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

جتي A2:A10 وڪرو ڪندڙ جا نالا آهن ۽ C2:C10 وڪرو آهن.

جيڪڏهن #N/A غلطيون لڪائڻ لاءِ ISNA VLOOKUP

جيڪڏهن VLOOKUP فنڪشن هڪ مخصوص قدر نه ڳولي سگهي، اهو هڪ #N/A غلطي اڇلائي ٿو. ان غلطي کي پڪڙڻ ۽ ان کي پنهنجي متن سان تبديل ڪرڻ لاءِ، IF فنڪشن جي منطقي ٽيسٽ ۾ هڪ Vlookup فارمولا شامل ڪريو، جيئن ته:

قدرتي طور تي، توهان ٽائيپ ڪري سگهو ٿا ڪو به متن جيڪو توهان چاهيو ٿا ان جي بدران "نه مليو".

فرض ڪريو، توهان وٽ وڪرو ڪندڙ جي فهرست آهي.هڪ ڪالم ۾ نالا ۽ ٻئي ڪالمن ۾ سيلز جي رقم. توھان جو ڪم آھي ھڪڙو نمبر ڪڍڻو آھي جيڪو نالو استعمال ڪندڙ F1 ۾ داخل ٿئي ٿو. جيڪڏهن نالو نه ملي ته هڪ پيغام ڏيکاريو جنهن ۾ اشارو ڪيو وڃي.

A2:A10 ۽ مقدار C2:C10 ۾ نالن سان، ڪم کي هيٺين If Vlookup فارمولا سان پورو ڪري سگهجي ٿو:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

جيڪڏهن نالو مليو آهي، هڪ لاڳاپيل سيلز رقم واپس ڪئي ويندي آهي:

جيڪڏهن ڏسندڙ قيمت نه ملي، نه مليو پيغام #N/A غلطي جي بدران ظاهر ٿئي ٿو:

هي فارمولا ڪيئن ڪم ڪندو آهي

فارمولا جي منطق تمام سادي آهي: توهان استعمال ڪريو ISNA فنڪشن #N/A غلطين لاءِ Vlookup چيڪ ڪرڻ لاءِ. جيڪڏهن ڪو نقص ٿئي ٿو، ISNA واپس ڪري ٿو TRUE، ٻي صورت ۾ FALSE. مٿيون قدرون IF فنڪشن جي منطقي ٽيسٽ ڏانھن وڃن ٿيون، جيڪو ھيٺين مان ھڪڙو ڪري ٿو:

• جيڪڏھن منطقي امتحان صحيح آھي (#N/A غلطي)، توھان جو پيغام ڏيکاريو ويندو. <20
• جيڪڏهن منطقي امتحان غلط آهي (ڏسڻ جي قيمت ملي ٿي)، Vlookup عام طور تي هڪ ميچ موٽائي ٿو.

IFNA VLOOKUP نئين Excel ورزن ۾

Excel 2013 سان شروع ڪندي، توهان #N/A غلطين کي پڪڙڻ ۽ سنڀالڻ لاءِ IF ISNA بدران IFNA فنڪشن استعمال ڪري سگھو ٿا:

اسان جي مثال ۾، فارمولا ٿيندو ھيٺ ڏنل شڪل وٺو:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

Excel Vlookup: جيڪڏهن نه مليو ته واپسي 0

جڏهن عددي قدرن سان ڪم ڪري رهيا آهيو، توهان شايد صفر واپس ڪرڻ چاهيو ٿا جڏهن ڏسڻ جي قيمت نه ملي. ان کي مڪمل ڪرڻ لاءِ، استعمال ڪريو IF ISNA VLOOKUP فارمولا جيڪو مٿي بيان ڪيو ويو آهي ٿوري ڦيرڦار سان: ٽيڪسٽ پيغام جي بدران، 0 فراهم ڪريو IF فنڪشن جي value_if_true دليل ۾:

اسان جي نموني واري جدول ۾، فارمولا هن ريت ٿيندو:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

21>

ان ۾ Excel 2016 ۽ 2013 جا تازو ورجن، توهان IFNA Vlookup جو مجموعو ٻيهر استعمال ڪري سگهو ٿا:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: جيڪڏهن نه مليو ته خالي سيل واپس ڪريو

هي هڪ وڌيڪ تبديلي آهي جي "Vlookup if then" بيان: ڪجھ به نه موٽايو جڏهن ڏسڻ جي قيمت نه ملي. ائين ڪرڻ لاءِ، پنھنجي فارمولا کي ھدايت ڪريو ته ھڪڙي خالي اسٽرنگ ("") بجاءِ #N/A غلطي:

ھيٺ مڪمل فارمولا جا ٻه مثال آهن:

سڀني ايڪسل ورزن لاءِ:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

سڀني 2016 ۽ ايڪسل 2013 لاءِ:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

If Index Match سان - left vlookup with If condition

تجربه رکندڙ Excel استعمال ڪندڙ ڄاڻن ٿا ته VLOOKUP فنڪشن صرف هڪ طريقو ناهي جيڪو ايڪسل ۾ عمودي ڏسڻ لاءِ. INDEX MATCH ميلاپ پڻ هن مقصد لاءِ استعمال ڪري سگھجي ٿو ۽ اهو اڃا به وڌيڪ طاقتور ۽ ورڇيل آهي. سٺي خبر اها آهي ته انڊيڪس ميچ IF سان گڏ ڪم ڪري سگهي ٿو بلڪل ساڳئي طريقي سانVlookup.

مثال طور، توهان وٽ ڪالمن A ۾ آرڊر نمبر ۽ ڪالمن B ۾ وڪرو ڪندڙ جا نالا آهن. توهان هڪ فارمولا ڳولي رهيا آهيو ڪنهن مخصوص وڪرو ڪندڙ لاءِ آرڊر نمبر ڪڍڻ لاءِ.

Vlookup نٿو ٿي سگهي هن معاملي ۾ استعمال ڪيو ويو آهي ڇاڪاڻ ته اهو ساڄي کان کاٻي طرف ڳولي نٿو سگهي. Index Match بغير ڪنهن رڪاوٽ جي ڪم ڪندو جيستائين لوڪ اپ ڪالم ۾ نظر اچي ٿي. جيڪڏهن نه، هڪ #N/A غلطي ڏيکاري ويندي. معياري غلطي جي نوٽيفڪيشن کي پنھنجي متن سان تبديل ڪرڻ لاءِ، IF ISNA جي اندر Nest Index Match:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Excel 2016 ۽ 2016 ۾، توھان استعمال ڪري سگھو ٿا IFNA بدران IF ISNA فارمولا کي وڌيڪ بنائڻ لاءِ. ڪمپيڪٽ:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

23>

اهڙيءَ طرح، توهان انڊيڪس ميچ کي ٻين If فارمولن ۾ استعمال ڪري سگهو ٿا.

هي توهان ڪيئن استعمال ڪندا آهيو. Vlookup ۽ IF بيان گڏجي Excel ۾. ھن سبق ۾ بحث ڪيل فارمولين تي ويجھي نظر رکڻ لاءِ، توھان کي ڀليڪار آھي ھيٺ اسان جو نمونو ورڪ بڪ ڊائون لوڊ ڪريو. مان توهان جي پڙهڻ لاءِ مهرباني ڪريان ٿو ۽ اميد اٿم ته توهان کي ايندڙ هفتي اسان جي بلاگ تي ڏسندا!

ڊائون لوڊ لاءِ مشق ورڪ بڪ

Excel IF Vlookup - فارمولا مثال (.xlsx فائل)