V LOOKUP மற்றும் IF செயல்பாடுகளை எக்செல் இல் if நிபந்தனையுடன் v-lookup உடன் இணைப்பது எப்படி என்பதை டுடோரியல் காட்டுகிறது. IF ISNA VLOOKUP சூத்திரங்களை உங்கள் சொந்த உரை, பூஜ்ஜியம் அல்லது வெற்று செல் மூலம் #N/A பிழைகளுக்குப் பதிலாக எப்படிப் பயன்படுத்துவது என்பதை நீங்கள் கற்றுக் கொள்வீர்கள்.

VLOOKUP மற்றும் IF செயல்பாடுகள் தனித்தனியாக பயனுள்ளதாக இருக்கும். அவர்கள் இன்னும் மதிப்புமிக்க அனுபவங்களை வழங்குகிறார்கள். இரண்டு செயல்பாடுகளின் தொடரியல் நீங்கள் நன்றாக நினைவில் வைத்திருப்பதை இந்த டுடோரியல் குறிக்கிறது, இல்லையெனில் மேலே உள்ள இணைப்புகளைப் பின்பற்றுவதன் மூலம் உங்கள் அறிவை மேம்படுத்திக்கொள்ள விரும்பலாம்.

Vlookup with Statement: return True/ தவறு, ஆம்/இல்லை, முதலியன.

நீங்கள் If மற்றும் Vlookup ஐ இணைக்கும்போது மிகவும் பொதுவான காட்சிகளில் ஒன்று Vlookup வழங்கும் மதிப்பை மாதிரி மதிப்புடன் ஒப்பிட்டு ஆம் / இல்லை அல்லது True / False விளைவாக.

பெரும்பாலான சந்தர்ப்பங்களில், பின்வரும் பொதுவான சூத்திரம் நன்றாக வேலை செய்யும்:

வெற்று ஆங்கிலத்தில் மொழிபெயர்க்கப்பட்டுள்ளது, Vlookup உண்மையாக இருந்தால் (அதாவது குறிப்பிட்ட மதிப்புக்கு சமம்) True என்பதை எக்செல் வழங்கும்படி சூத்திரம் அறிவுறுத்துகிறது. Vlookup தவறு என்றால் (குறிப்பிட்ட மதிப்புக்கு சமமாக இல்லை), சூத்திரம் False என்பதைத் தரும்.

கீழே இந்த IF Vlookup சூத்திரத்தின் சில நிஜ வாழ்க்கைப் பயன்பாடுகளைக் காணலாம்.

எடுத்துக்காட்டு 1. ஒரு குறிப்பிட்ட மதிப்பைப் பார்க்கவும்

உங்களிடம் உருப்படிகளின் பட்டியல் A நெடுவரிசையில் உள்ளது மற்றும் அளவு B நெடுவரிசையில் உள்ளது என்று வைத்துக்கொள்வோம். உங்கள் பயனர்களுக்காக ஒரு டாஷ்போர்டை உருவாக்குகிறீர்கள், அதற்கு சூத்திரம் தேவைஇது E1 இல் உள்ள ஒரு பொருளின் அளவைச் சரிபார்த்து, அது கையிருப்பில் உள்ளதா அல்லது விற்றுத் தீர்ந்துவிட்டதா என்பதை பயனருக்குத் தெரிவிக்கும்.

இது போன்ற சரியான பொருத்த சூத்திரத்துடன் வழக்கமான Vlookup மூலம் அளவைப் பெறுவீர்கள்:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

பின்னர், Vlookup இன் முடிவை பூஜ்ஜியத்துடன் ஒப்பிட்டு ஒரு IF அறிக்கையை எழுதவும், அது 0 க்கு சமமாக இருந்தால் "இல்லை" என்றும், இல்லையெனில் "ஆம்" என்றும் வழங்கும்:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

ஆம்/இல்லை என்பதற்குப் பதிலாக, உண்மை/தவறு அல்லது இருப்பிலுள்ளது/விற்றுத் தீர்ந்துவிட்டது அல்லது வேறு ஏதேனும் இரண்டை வழங்கலாம் தேர்வுகள். எடுத்துக்காட்டாக:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

நீங்கள் Vlookup வழங்கும் மதிப்பை மாதிரி உரை உடன் ஒப்பிடலாம். இந்த வழக்கில், மேற்கோள் குறிகளில் உரைச் சரத்தை இணைக்கவும், இது போன்றது:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

எடுத்துக்காட்டு 2. Vlookup முடிவை மற்றொரு கலத்துடன் ஒப்பிடுக

இன்னொரு பொதுவான உதாரணம் Vlookup with If condition Excel இல் உள்ள Vlookup வெளியீட்டை மற்றொரு கலத்தில் உள்ள மதிப்புடன் ஒப்பிடுகிறது. எடுத்துக்காட்டாக, செல் G2 இல் உள்ள எண்ணை விட அதிகமாக உள்ளதா அல்லது அதற்கு சமமாக உள்ளதா என்பதை நாம் சரிபார்க்கலாம்:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

மேலும் Vlookup செயல்பாட்டில் உள்ள எங்களின் If சூத்திரம் இதோ:

இதே பாணியில், உங்கள் எக்செல் இஃப் வ்லூக்அப் சூத்திரத்தில் உள்ள செல் குறிப்புடன் வேறு எந்த லாஜிக்கல் ஆபரேட்டரையும் நீங்கள் பயன்படுத்தலாம்.

எடுத்துக்காட்டு 3. சுருக்கமான பட்டியலில் Vlookup மதிப்புகள்

இலக்கு நெடுவரிசையில் உள்ள ஒவ்வொரு கலத்தையும் மற்றொரு பட்டியலுடன் ஒப்பிட்டு சரி அல்லது ஆம் பொருத்தம் கண்டறியப்பட்டால், தவறு அல்லது இல்லை இல்லையெனில், இந்த பொதுவான IF ISNA VLOOKUP சூத்திரத்தைப் பயன்படுத்தவும்:

Vlookup இல் #N/A பிழை ஏற்பட்டால், சூத்திரம் "இல்லை" என்று வழங்கும், அதாவது தேடல் பட்டியலில் தேடல் மதிப்பு காணப்படவில்லை. பொருத்தம் கண்டறியப்பட்டால், "ஆம்" என்று திருப்பி அனுப்பப்படும். எடுத்துக்காட்டாக:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

உங்கள் வணிக தர்க்கத்திற்கு எதிர் முடிவுகள் தேவைப்பட்டால், சூத்திரத்தின் தர்க்கத்தை மாற்றியமைக்க "ஆம்" மற்றும் "இல்லை" என்பதை மாற்றவும்:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

எக்செல் என்றால் Vlookup சூத்திரம் வெவ்வேறு கணக்கீடுகளைச் செய்ய வேண்டும்

உங்கள் சொந்த உரைச் செய்திகளைக் காண்பிப்பதைத் தவிர, Vlookup உடன் செயல்பட்டால் வெவ்வேறு கணக்கீடுகளைச் செய்ய முடியும் நீங்கள் குறிப்பிடும் அளவுகோல்களின் அடிப்படையில்.

எங்கள் உதாரணத்தை எடுத்துக்கொண்டால், ஒரு குறிப்பிட்ட விற்பனையாளரின் (F1) கமிஷனை அவர்களின் செயல்திறனைப் பொறுத்து கணக்கிடுவோம்: $200 மற்றும் அதற்கு மேல் சம்பாதித்தவர்களுக்கு 20% கமிஷன், மற்ற அனைவருக்கும் 10% .

இதற்காக, Vlookup வழங்கும் மதிப்பு 200ஐ விட அதிகமாக உள்ளதா அல்லது அதற்கு சமமாக உள்ளதா என்பதைச் சரிபார்க்கவும், அது இருந்தால், அதை 20% ஆல் பெருக்கவும், இல்லையெனில் 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

A2:A10 என்பது விற்பனையாளர் பெயர்கள் மற்றும் C2:C10 என்பது விற்பனையாகும்.

#N/A பிழைகளை மறைக்க ISNA VLOOKUP செய்தால்

VLOOKUP செயல்பாட்டால் ஒரு குறிப்பிட்ட மதிப்பைக் கண்டறிய முடியவில்லை எனில், அது #N/A பிழையை ஏற்படுத்துகிறது. அந்தப் பிழையைப் பிடித்து, அதை உங்கள் சொந்த உரையுடன் மாற்ற, IF செயல்பாட்டின் தருக்க சோதனையில் Vlookup சூத்திரத்தை உட்பொதிக்கவும்:

இயற்கையாகவே, "கண்டுபிடிக்கப்படவில்லை" என்பதற்குப் பதிலாக நீங்கள் விரும்பும் எந்த உரையையும் தட்டச்சு செய்யலாம்.

உங்களிடம் விற்பனையாளரின் பட்டியல் உள்ளது.ஒரு நெடுவரிசையில் பெயர்கள் மற்றும் மற்றொரு நெடுவரிசையில் விற்பனைத் தொகைகள். F1 இல் பயனர் உள்ளிடும் பெயருடன் தொடர்புடைய எண்ணை இழுப்பதே உங்கள் பணி. பெயர் கிடைக்கவில்லை எனில், அதைக் குறிக்கும் செய்தியைக் காட்டவும்.

A2:A10 மற்றும் அளவு C2:C10 இல் உள்ள பெயர்களுடன், பின்வரும் If Vlookup சூத்திரத்தைப் பயன்படுத்தி பணியை நிறைவேற்றலாம்:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

பெயர் கண்டுபிடிக்கப்பட்டால், தொடர்புடைய விற்பனைத் தொகை திருப்பியளிக்கப்படும்:

தேடுதல் மதிப்பு கிடைக்கவில்லை எனில், கண்டுபிடிக்கப்படவில்லை<#N/A பிழைக்கு பதிலாக 2> செய்தி தோன்றும்:

இந்த சூத்திரம் எவ்வாறு செயல்படுகிறது

சூத்திரத்தின் தர்க்கம் மிகவும் எளிது: நீங்கள் ISNA செயல்பாட்டைப் பயன்படுத்துகிறீர்கள் #N/A பிழைகளுக்கு Vlookup ஐ சரிபார்க்க. பிழை ஏற்பட்டால், ISNA ஆனது TRUE ஐ வழங்கும், இல்லையெனில் FALSE. மேலே உள்ள மதிப்புகள் IF செயல்பாட்டின் தருக்க சோதனைக்குச் செல்கின்றன, இது பின்வருவனவற்றில் ஒன்றைச் செய்கிறது:

• தருக்க சோதனை உண்மையாக இருந்தால் (#N/A பிழை), உங்கள் செய்தி காட்டப்படும்.
• தர்க்கரீதியான சோதனை தவறானதாக இருந்தால் (தேடுதல் மதிப்பு கண்டறியப்பட்டது), Vlookup ஒரு பொருத்தத்தை சாதாரணமாக வழங்கும்.

புதிய Excel பதிப்புகளில் IFNA VLOOKUP

Excel 2013 இல் தொடங்கி, நீங்கள் #N/A பிழைகளைப் பிடிக்கவும் கையாளவும் IF ISNA க்குப் பதிலாக IFNA செயல்பாட்டைப் பயன்படுத்தலாம்:

எங்கள் எடுத்துக்காட்டில், சூத்திரம் பின்வரும் வடிவத்தை எடுக்கவும்:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

குறிப்பு. #N/A மட்டுமின்றி, அனைத்து வகையான பிழைகளையும் சிக்க வைக்க விரும்பினால், IFERROR செயல்பாட்டுடன் இணைந்து VLOOKUP ஐப் பயன்படுத்தவும். மேலும் விவரங்களை இங்கே காணலாம்: IFERRORஎக்செல் இல் VLOOKUP.

எக்செல் வ்லூக்அப்: காணப்படவில்லை என்றால் திரும்ப 0

எண் மதிப்புகளுடன் பணிபுரியும் போது, ​​தேடுதல் மதிப்பு காணப்படாத போது, ​​பூஜ்ஜியத்தை வழங்க விரும்பலாம். இதைச் செய்ய, ஒரு சிறிய மாற்றத்துடன் மேலே விவாதிக்கப்பட்ட IF ISNA VLOOKUP சூத்திரத்தைப் பயன்படுத்தவும்: உரைச் செய்திக்குப் பதிலாக, IF செயல்பாட்டின் value_if_true வாதத்தில் 0 ஐ வழங்கவும்:

எங்கள் மாதிரி அட்டவணையில், சூத்திரம் பின்வருமாறு செல்லும்:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

இதில் Excel 2016 மற்றும் 2013 இன் சமீபத்திய பதிப்புகளில், நீங்கள் IFNA Vlookup கலவையை மீண்டும் பயன்படுத்தலாம்:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: கிடைக்கவில்லை என்றால் காலியாக செல் திரும்பவும்

இது மேலும் ஒரு மாறுபாடு "Vlookup if then" அறிக்கையின்: தேடுதல் மதிப்பு காணப்படாதபோது எதையும் திரும்பப் பெறாது. இதைச் செய்ய, #N/A பிழைக்கு பதிலாக ஒரு வெற்று சரத்தை ("") வழங்க உங்கள் சூத்திரத்திற்கு அறிவுறுத்துங்கள்:

கீழே இரண்டு முழுமையான சூத்திர எடுத்துக்காட்டுகள்:

எல்லா எக்செல் பதிப்புகளுக்கும்:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

எக்செல் 2016 மற்றும் எக்செல் 2013க்கு:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

இன்டெக்ஸ் மேட்ச் உடன் இருந்தால் - இஃப் கண்டிஷனுடன் vlookup ஐ விட்டுவிடுங்கள்

எக்செல் இல் செங்குத்துத் தேடலைச் செய்வதற்கான ஒரே வழி VLOOKUP செயல்பாடு அல்ல என்பதை அனுபவம் வாய்ந்த எக்செல் பயனர்கள் அறிவார்கள். இந்த நோக்கத்திற்காக INDEX MATCH கலவையும் பயன்படுத்தப்படலாம், மேலும் இது மிகவும் சக்தி வாய்ந்தது மற்றும் பல்துறை திறன் கொண்டது. இன்டெக்ஸ் மேட்ச் சரியாக அதே வழியில் IF உடன் இணைந்து செயல்பட முடியும் என்பது நல்ல செய்திVlookup.

உதாரணமாக, A நெடுவரிசையில் ஆர்டர் எண்கள் மற்றும் B நெடுவரிசையில் விற்பனையாளர் பெயர்கள் உள்ளன. குறிப்பிட்ட விற்பனையாளருக்கான ஆர்டர் எண்ணைப் பெறுவதற்கான சூத்திரத்தை நீங்கள் தேடுகிறீர்கள்.

Vlookup இருக்க முடியாது வலமிருந்து இடமாகத் தேட முடியாது என்பதால் இந்த வழக்கில் பயன்படுத்தப்பட்டது. தேடுதல் நெடுவரிசையில் தேடல் மதிப்பு இருக்கும் வரை, குறியீட்டு பொருத்தம் தடையின்றி வேலை செய்யும். இல்லையெனில், #N/A பிழை காண்பிக்கப்படும். உங்கள் சொந்த உரையுடன் நிலையான பிழைக் குறிப்பை மாற்ற, IF ISNA க்குள் nest Index Match:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Excel 2016 மற்றும் 2016 இல், IF ISNA க்குப் பதிலாக IFNA ஐப் பயன்படுத்தி சூத்திரத்தை மேலும் உருவாக்கலாம் compact:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

இதே முறையில், நீங்கள் மற்ற If சூத்திரங்களில் Index Matchஐப் பயன்படுத்தலாம்.

இப்படித்தான் நீங்கள் பயன்படுத்துகிறீர்கள். எக்செல் இல் Vlookup மற்றும் IF அறிக்கை ஒன்றாக. இந்த டுடோரியலில் விவாதிக்கப்பட்ட சூத்திரங்களை உன்னிப்பாகப் பார்க்க, கீழே உள்ள எங்கள் மாதிரி பணிப்புத்தகத்தைப் பதிவிறக்க உங்களை வரவேற்கிறோம். படித்ததற்கு நன்றி, அடுத்த வாரம் எங்கள் வலைப்பதிவில் உங்களைப் பார்ப்போம் என்று நம்புகிறேன்!

பதிவிறக்கப் பயிற்சிப் புத்தகம்

Excel IF Vlookup - formula examples (.xlsx கோப்பு)