Tutorial menunjukkan cara menggabungkan fungsi V LOOKUP dan IF bersama-sama kepada carian-v dengan keadaan if dalam Excel. Anda juga akan mempelajari cara menggunakan formula IF ISNA VLOOKUP untuk menggantikan ralat #N/A dengan teks, sifar atau sel kosong anda sendiri.

Walaupun fungsi VLOOKUP dan IF berguna sendiri, bersama-sama mereka menyampaikan pengalaman yang lebih berharga. Tutorial ini membayangkan bahawa anda mengingati sintaks kedua-dua fungsi dengan baik, jika tidak, anda mungkin mahu menyempurnakan pengetahuan anda dengan mengikuti pautan di atas.

Vlookup dengan pernyataan If: return True/ Palsu, Ya/Tidak, dsb.

Salah satu senario yang paling biasa apabila anda menggabungkan If dan Vlookup bersama-sama ialah membandingkan nilai yang dikembalikan oleh Vlookup dengan nilai sampel dan mengembalikan Ya / Tidak atau Betul / Salah sebagai hasilnya.

Dalam kebanyakan kes, formula generik berikut akan berfungsi dengan baik:

Diterjemahkan dalam bahasa Inggeris biasa, formula mengarahkan Excel untuk mengembalikan True jika Vlookup adalah benar (iaitu sama dengan nilai yang ditentukan). Jika Vlookup adalah palsu (tidak sama dengan nilai yang ditentukan), formula mengembalikan False .

Di bawah anda akan menemui beberapa kegunaan sebenar formula IF Vlookup ini.

Contoh 1. Cari nilai tertentu

Katakanlah, anda mempunyai senarai item dalam lajur A dan kuantiti dalam lajur B. Anda sedang membuat papan pemuka untuk pengguna anda dan memerlukan formulayang akan menyemak kuantiti untuk item dalam E1 dan memaklumkan pengguna sama ada item itu ada dalam stok atau habis dijual.

Anda menarik kuantiti dengan Vlookup biasa dengan formula padanan tepat seperti ini:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Kemudian, tulis pernyataan IF yang membandingkan hasil Vlookup dengan sifar dan kembalikan "Tidak" jika ia sama dengan 0, "Ya" sebaliknya:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

Daripada Ya/Tidak , anda boleh mengembalikan BETUL/SALAH atau Dalam Stok/Habis atau mana-mana dua lagi pilihan. Contohnya:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

Anda juga boleh membandingkan nilai yang dikembalikan oleh Vlookup dengan sampel teks . Dalam kes ini, pastikan anda menyertakan rentetan teks dalam tanda petikan, seperti ini:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

Contoh 2. Bandingkan hasil Vlookup dengan sel lain

Satu lagi contoh tipikal Vlookup dengan keadaan If dalam Excel sedang membandingkan output Vlookup dengan nilai dalam sel lain. Sebagai contoh, kita boleh menyemak sama ada ia lebih besar daripada atau sama dengan nombor dalam sel G2:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

Dan berikut ialah formula If kami dengan Vlookup dalam tindakan:

Dengan cara yang sama, anda boleh menggunakan mana-mana pengendali logik lain bersama-sama dengan rujukan sel dalam formula Excel If Vlookup anda.

Contoh 3. Nilai Vlookup dalam senarai yang lebih pendek

Untuk membandingkan setiap sel dalam lajur sasaran dengan senarai lain dan mengembalikan Benar atau Ya jika padanan ditemui, Salah atau Tidak jika tidak, gunakan formula IF ISNA VLOOKUP generik ini:

Jika Vlookup menghasilkan ralat #N/A, formula mengembalikan "Tidak", bermakna nilai carian tidak ditemui dalam senarai carian. Jika perlawanan ditemui, "Ya" dikembalikan. Contohnya:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

Jika logik perniagaan anda memerlukan hasil yang bertentangan, cuma tukar "Ya" dan "Tidak" untuk membalikkan logik formula:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Formula Excel If Vlookup untuk melakukan pengiraan berbeza

Selain memaparkan mesej teks anda sendiri, If function dengan Vlookup boleh melakukan pengiraan yang berbeza berdasarkan kriteria yang anda tentukan.

Mengambil contoh lebih lanjut, mari kita kira komisen penjual tertentu (F1) bergantung pada keberkesanannya: 20% komisen untuk mereka yang membuat $200 dan lebih, 10% untuk orang lain .

Untuk ini, anda menyemak sama ada nilai yang dikembalikan oleh Vlookup adalah lebih besar daripada atau sama dengan 200, dan jika ya, darabkannya dengan 20%, jika tidak dengan 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Di mana A2:A10 ialah nama penjual dan C2:C10 ialah jualan.

JIKA ISNA VLOOKUP untuk menyembunyikan #N/A ralat

Jika fungsi VLOOKUP tidak dapat mencari nilai yang ditentukan, ia akan mengeluarkan ralat #N/A. Untuk menangkap ralat itu dan menggantikannya dengan teks anda sendiri, benamkan formula Vlookup dalam ujian logik fungsi IF, seperti ini:

Sememangnya, anda boleh menaip mana-mana teks yang anda suka dan bukannya "Tidak ditemui".

Andaikata, anda mempunyai senarai penjualnama dalam satu lajur dan jumlah jualan dalam lajur lain. Tugas anda adalah untuk menarik nombor yang sepadan dengan nama yang dimasukkan pengguna dalam F1. Jika nama itu tidak dijumpai, paparkan mesej yang menunjukkan demikian.

Dengan nama dalam A2:A10 dan amaun C2:C10, tugasan boleh dipenuhi dengan formula If Vlookup berikut:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

Jika nama ditemui, jumlah jualan yang sepadan dikembalikan:

Jika nilai carian tidak ditemui, Tidak dijumpai mesej muncul dan bukannya ralat #N/A:

Cara formula ini berfungsi

Logik formula adalah sangat mudah: anda menggunakan fungsi ISNA untuk menyemak Vlookup untuk ralat #N/A. Jika ralat berlaku, ISNA mengembalikan BENAR, sebaliknya FALSE. Nilai di atas pergi ke ujian logik fungsi IF, yang melakukan salah satu daripada yang berikut:

• Jika ujian logik adalah BENAR (#N/A ralat), mesej anda dipaparkan.
• Jika ujian logik adalah FALSE (nilai carian ditemui), Vlookup mengembalikan padanan seperti biasa.

IFNA VLOOKUP dalam versi Excel yang lebih baharu

Bermula dengan Excel 2013, anda boleh menggunakan fungsi IFNA dan bukannya IF ISNA untuk menangkap dan mengendalikan ralat #N/A:

Dalam contoh kami, formula akan ambil bentuk berikut:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

Petua. Jika anda ingin memerangkap semua jenis ralat, bukan sahaja #N/A, gunakan VLOOKUP dalam kombinasi dengan fungsi IFERROR. Butiran lanjut boleh didapati di sini: IFERRORVLOOKUP dalam Excel.

Excel Vlookup: jika tidak dijumpai kembalikan 0

Apabila bekerja dengan nilai berangka, anda mungkin mahu mengembalikan sifar apabila nilai carian tidak ditemui. Untuk melakukannya, gunakan formula IF ISNA VLOOKUP yang dibincangkan di atas dengan sedikit pengubahsuaian: bukannya mesej teks, berikan 0 dalam argumen value_if_true bagi fungsi IF:

Dalam jadual sampel kami, formula akan menjadi seperti berikut:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Dalam versi terkini Excel 2016 dan 2013, anda boleh menggunakan gabungan IFNA Vlookup sekali lagi:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: jika tidak ditemui kembalikan sel kosong

Ini ialah satu lagi variasi daripada pernyataan "Vlookup jika kemudian": tidak mengembalikan apa-apa apabila nilai carian tidak ditemui. Untuk melakukan ini, arahkan formula anda untuk mengembalikan rentetan kosong ("") dan bukannya ralat #N/A:

Di bawah ialah beberapa contoh formula lengkap:

Untuk semua versi Excel:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Untuk Excel 2016 dan Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

If with Index Match - left vlookup with If condition

Pengguna Excel yang berpengalaman tahu bahawa fungsi VLOOKUP bukan satu-satunya cara untuk melakukan carian menegak dalam Excel. Gabungan INDEX MATCH juga boleh digunakan untuk tujuan ini dan ia lebih berkuasa dan serba boleh. Berita baiknya ialah Padanan Indeks boleh bekerjasama dengan IF dengan cara yang sama sepertiVlookup.

Sebagai contoh, anda mempunyai nombor pesanan dalam lajur A dan nama penjual dalam lajur B. Anda sedang mencari formula untuk menarik nombor pesanan untuk penjual tertentu.

Vlookup tidak boleh digunakan dalam kes ini kerana ia tidak boleh mencari dari kanan ke kiri. Padanan Indeks akan berfungsi tanpa sebarang halangan selagi nilai carian ditemui dalam lajur carian. Jika tidak, ralat #N/A akan dipaparkan. Untuk menggantikan tatatanda ralat standard dengan teks anda sendiri, sarang Padanan Indeks di dalam IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Dalam Excel 2016 dan 2016, anda boleh menggunakan IFNA dan bukannya IF ISNA untuk menjadikan formula lebih padat:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

Dengan cara yang sama, anda boleh menggunakan Padanan Indeks dalam formula If yang lain.

Beginilah cara anda menggunakan Penyataan Vlookup dan IF bersama-sama dalam Excel. Untuk melihat dengan lebih dekat formula yang dibincangkan dalam tutorial ini, anda dialu-alukan untuk memuat turun contoh buku kerja kami di bawah. Saya mengucapkan terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!

Latihan buku kerja untuk muat turun

Excel IF Vlookup - contoh formula (.xlsx file)