De handleiding laat zien hoe V LOOKUP en IF-functie samen tot v-lookup met if-conditie in Excel. U leert ook hoe u IF ISNA VLOOKUP-formules kunt gebruiken om #N/A-fouten te vervangen door uw eigen tekst, nul of lege cel.

Hoewel de functies VLOOKUP en IF op zichzelf nuttig zijn, leveren ze samen nog meer waardevolle ervaringen op. Deze handleiding veronderstelt dat u de syntaxis van de twee functies goed kent, anders kunt u uw kennis misschien opfrissen door de bovenstaande links te volgen.

Vlookup met If-instructie: geef True/False, Yes/No, enz. terug.

Een van de meest voorkomende scenario's wanneer u If en Vlookup samen combineert, is om de door Vlookup geretourneerde waarde te vergelijken met een voorbeeldwaarde en te retourneren Ja / Nee of Waar / Onwaar als resultaat.

In de meeste gevallen zou de volgende algemene formule goed werken:

Vertaald in gewoon Engels instrueert de formule Excel om Echt als Vlookup waar is (d.w.z. gelijk aan de opgegeven waarde). Als Vlookup onwaar is (niet gelijk aan de opgegeven waarde), retourneert de formule Valse .

Hieronder vindt u enkele praktische toepassingen van deze IF Vlookup-formule.

Voorbeeld 1. Een specifieke waarde opzoeken

Stel, u hebt een lijst van artikelen in kolom A en de hoeveelheid in kolom B. U maakt een dashboard voor uw gebruikers en hebt een formule nodig die de hoeveelheid van een artikel in E1 controleert en de gebruiker informeert of het artikel in voorraad is of uitverkocht.

U trekt de hoeveelheid met een gewone Vlookup met exact gelijke formule als deze:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Schrijf vervolgens een IF-instructie die het resultaat van Vlookup vergelijkt met nul, en "Nee" teruggeeft als het gelijk is aan 0, en "Ja" in alle andere gevallen:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"Nee","Ja")

In plaats van Ja/Nee kunt u terugkeren WAAR/NIET WAAR of Op voorraad/uitverkocht of elke andere twee keuzes. Bijvoorbeeld:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Uitverkocht","Op voorraad")

U kunt de door Vlookup geretourneerde waarde ook vergelijken met monster tekst In dit geval moet u een tekststring tussen aanhalingstekens plaatsen, zoals dit:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="voorbeeldtekst",TRUE,FALSE)

Voorbeeld 2. Vlookup resultaat vergelijken met een andere cel

Een ander typisch voorbeeld van Vlookup met If-voorwaarde in Excel is het vergelijken van de Vlookup-uitvoer met een waarde in een andere cel. Wij kunnen bijvoorbeeld controleren of deze groter of gelijk is aan een getal in cel G2:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Ja!","Nee")

En hier is onze If-formule met Vlookup in actie:

Op vergelijkbare wijze kunt u elke andere logische operator gebruiken in combinatie met een celverwijzing in uw Excel Als Vlookup-formule.

Voorbeeld 3. Vlookup-waarden in een kortere lijst

Om elke cel in de doelkolom te vergelijken met een andere lijst en te retourneren Echt of Ja als er een overeenkomst is gevonden, Valse of Geen gebruik anders deze algemene IF ISNA VLOOKUP-formule:

Als Vlookup resulteert in de #N/A-fout, geeft de formule "Nee" terug, wat betekent dat de opzoekwaarde niet wordt gevonden in de opzoeklijst. Als de overeenkomst wordt gevonden, wordt "Ja" teruggegeven. Bijvoorbeeld:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Nee","Ja")

Als uw bedrijfslogica de tegenovergestelde resultaten vereist, verwisselt u gewoon "Ja" en "Nee" om de logica van de formule om te keren:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Ja","Nee")

Excel Als Vlookup-formule om verschillende berekeningen uit te voeren

Naast het weergeven van uw eigen tekstberichten kan de functie Als met Vlookup verschillende berekeningen uitvoeren op basis van de criteria die u opgeeft.

In ons voorbeeld berekenen we de commissie van een specifieke verkoper (F1) afhankelijk van zijn effectiviteit: 20% commissie voor degenen die $200 en meer verdienden, 10% voor alle anderen.

Hiervoor controleert u of de door Vlookup geretourneerde waarde groter of gelijk is aan 200, en zo ja, vermenigvuldigt u deze met 20%, en anders met 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Waarbij A2:A10 namen van verkopers zijn en C2:C10 verkopen.

IF ISNA VLOOKUP om #N/A fouten te verbergen

Als de VLOOKUP-functie een opgegeven waarde niet kan vinden, gooit hij een #N/A-fout. Om die fout op te vangen en te vervangen door uw eigen tekst, neemt u een Vlookup-formule op in de logische test van de IF-functie, zoals dit:

U kunt natuurlijk elke gewenste tekst typen in plaats van "Niet gevonden".

Stel, u hebt een lijst met namen van verkopers in één kolom en verkoopbedragen in een andere kolom. Uw taak is om een getal te trekken dat overeenkomt met de naam die de gebruiker invoert in F1. Als de naam niet wordt gevonden, toon dan een bericht dat dit aangeeft.

Met de namen in A2:A10 en de bedragen C2:C10 kan de taak worden vervuld met de volgende If Vlookup-formule:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Niet gevonden", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

Als de naam wordt gevonden, wordt een overeenkomstig verkoopbedrag teruggestuurd:

Als de opzoekwaarde niet wordt gevonden, wordt de Niet gevonden. bericht verschijnt in plaats van de #N/A-fout:

Hoe deze formule werkt

De logica van de formule is heel eenvoudig: u gebruikt de ISNA-functie om Vlookup te controleren op #N/A-fouten. Als er een fout optreedt, geeft ISNA TRUE terug, anders FALSE. De bovenstaande waarden gaan naar de logische test van de IF-functie, die een van de volgende dingen doet:

• Indien de logische test WAAR is (#N/A fout), verschijnt uw bericht.
• Indien de logische test FALSE is (de opzoekwaarde is gevonden), retourneert Vlookup normaal een overeenkomst.

IFNA VLOOKUP in nieuwere Excel-versies

Vanaf Excel 2013 kunt u de IFNA-functie gebruiken in plaats van IF ISNA om #N/A-fouten op te vangen en af te handelen:

In ons voorbeeld krijgt de formule de volgende vorm:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Niet gevonden")

Tip: Als u allerlei soorten fouten wilt opvangen, niet alleen #N/A, gebruik dan VLOOKUP in combinatie met de IFERROR-functie. Meer details vindt u hier: IFERROR VLOOKUP in Excel.

Excel Vlookup: indien niet gevonden geef 0 terug

Wanneer u met numerieke waarden werkt, wilt u misschien een nul teruggeven wanneer de opzoekwaarde niet wordt gevonden. Gebruik daarvoor de hierboven besproken IF ISNA VLOOKUP-formule met een kleine wijziging: in plaats van een tekstbericht geeft u 0 in de waarde_indien_waar argument van de IF-functie:

In onze voorbeeldtabel gaat de formule als volgt:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

In de recente versies van Excel 2016 en 2013 kunt u de IFNA Vlookup-combinatie weer gebruiken:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: indien niet gevonden lege cel teruggeven

Dit is nog een variant van de "Vlookup if then"-verklaring: geef niets terug wanneer de lookup-waarde niet wordt gevonden. Om dit te doen, geeft u uw formule opdracht een lege tekenreeks ("") terug te geven in plaats van de #N/A-fout:

Hieronder staan een paar complete formulevoorbeelden:

Voor alle Excel-versies:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Voor Excel 2016 en Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

Indien met Index Match - linker vlookup met Indien voorwaarde

Ervaren Excel-gebruikers weten dat de VLOOKUP-functie niet de enige manier is om verticaal op te zoeken in Excel. De combinatie INDEX MATCH kan ook voor dit doel worden gebruikt en is nog krachtiger en veelzijdiger. Het goede nieuws is dat Index Match op precies dezelfde manier kan samenwerken met IF als Vlookup.

U hebt bijvoorbeeld bestelnummers in kolom A en namen van verkopers in kolom B. U zoekt een formule om het bestelnummer voor een specifieke verkoper op te halen.

Vlookup kan in dit geval niet worden gebruikt omdat het niet van rechts naar links kan zoeken. Index Match zal probleemloos werken zolang de lookup-waarde wordt gevonden in de lookup-kolom. Zo niet, dan verschijnt er een #N/A foutmelding. Om de standaard foutmelding te vervangen door uw eigen tekst, nestelt u Index Match binnen IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Niet gevonden", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))

In Excel 2016 en 2016 kunt u IFNA gebruiken in plaats van IF ISNA om de formule compacter te maken:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Niet gevonden")

Op vergelijkbare wijze kunt u Index Match gebruiken in andere Als-formules.

Dit is hoe u Vlookup en IF-instructie samen gebruikt in Excel. Om de formules die in deze tutorial worden besproken beter te bekijken, kunt u hieronder onze voorbeeldwerkmap downloaden. Ik dank u voor het lezen en hoop u volgende week op onze blog te zien!

Praktijk werkboek om te downloaden

Excel IF Vlookup - formulevoorbeelden (.xlsx bestand)