Təlimat V LOOKUP və IF funksiyalarının Excel-də if şərti ilə v-axtarış üçün birlikdə necə birləşdiriləcəyini göstərir. Siz həmçinin #N/A səhvlərini öz mətniniz, sıfır və ya boş xana ilə əvəz etmək üçün IF ISNA VLOOKUP düsturlarından necə istifadə edəcəyinizi öyrənəcəksiniz.

VLOOKUP və IF funksiyaları birlikdə faydalıdır. daha qiymətli təcrübələr təqdim edirlər. Bu dərslik o deməkdir ki, siz iki funksiyanın sintaksisini yaxşı xatırlayırsınız, əks halda yuxarıdakı keçidlərə əməl etməklə biliklərinizi təzələmək istəyə bilərsiniz.

İf ifadəsi ilə səs-küylü axtarış: True/ Yanlış, Bəli/Xeyr və s.

Əgər və Vlookup-ı birlikdə birləşdirdiyiniz zaman ən ümumi ssenarilərdən biri Vlookup tərəfindən qaytarılan dəyəri nümunə dəyəri ilə müqayisə etmək və Bəli / Xeyr qaytarmaqdır. və ya nəticə olaraq Doğru / Yanlış .

Əksər hallarda aşağıdakı ümumi düstur yaxşı işləyəcək:

Düz ingiliscə tərcümə edilmiş düstur Excel-ə Vlookup doğrudursa (yəni göstərilən dəyərə bərabərdirsə) Doğru qaytarmağı əmr edir. Vlookup yalan olarsa (müəyyən edilmiş dəyərə bərabər deyil), düstur Yanlış qaytarır.

Aşağıda siz bu IF Vlookup düsturunun bir neçə real həyatda istifadəsini tapa bilərsiniz.

Nümunə 1. Xüsusi dəyəri axtarın

Tutaq ki, sizin A sütununda elementlərin siyahısı və B sütununda kəmiyyət var. Siz istifadəçiləriniz üçün idarə paneli yaradırsınız və düstura ehtiyacınız var.Bu, E1-dəki elementin miqdarını yoxlayacaq və istifadəçiyə məhsulun anbarda olub-olmadığını və ya satılıb-satılmadığını bildirəcək.

Məmiyyəti belə dəqiq uyğunluq düsturu ilə adi Vlookup ilə götürürsünüz:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Sonra Vlookup-ın nəticəsini sıfırla müqayisə edən IF ifadəsi yazın və 0-a bərabər olarsa "Xeyr", əks halda "Bəli" qaytarır:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

Bəli/Xeyr əvəzinə siz DOĞRU/YANLIŞ və ya Stokda var/Satılıb və ya hər hansı digər ikisini qaytara bilərsiniz seçimlər. Məsələn:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

Siz həmçinin Vlookup tərəfindən qaytarılan dəyəri nümunə ilə mətn müqayisə edə bilərsiniz. Bu halda, mətn sətirini dırnaq işarələrinə daxil etməyinizə əmin olun, məsələn:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

Nümunə 2. Vlookup nəticəsini başqa xana ilə müqayisə edin

Digər tipik nümunə Excel-də If şərti ilə Vlookup Vlookup çıxışını başqa xanadakı dəyərlə müqayisə edir. Məsələn, G2 xanasındakı rəqəmdən böyük və ya ona bərabər olub olmadığını yoxlaya bilərik:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

Və burada Vlookup işlək vəziyyətdə olan If düsturumuz var:

Oxşar şəkildə siz Excel If Vlookup düsturunuzda xana istinadı ilə birlikdə hər hansı digər məntiqi operatordan istifadə edə bilərsiniz.

Misal 3. Daha qısa siyahıda Vlookup dəyərləri

Hədəf sütunun hər bir xanasını başqa siyahı ilə müqayisə etmək və uyğunluq aşkar edilərsə, Doğru və ya Bəli qaytarmaq üçün Yanlış və ya Xeyr əks halda bu ümumi IF ISNA VLOOKUP düsturundan istifadə edin:

Vlookup #N/A xətası ilə nəticələnərsə, formula "Xeyr"i qaytarır, yəni axtarış dəyəri axtarış siyahısında tapılmır. Uyğunluq aşkar edilərsə, "Bəli" qaytarılır. Məsələn:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

Əgər biznes məntiqiniz əks nəticələr tələb edirsə, formulun məntiqini dəyişmək üçün sadəcə olaraq "Bəli" və "Xeyr"i dəyişdirin:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel If Vlookup formula müxtəlif hesablamalar yerinə yetirmək üçün

Öz mətn mesajlarınızı göstərməklə yanaşı, Vlookup ilə If funksiyası müxtəlif hesablamalar həyata keçirə bilər göstərdiyiniz meyarlara əsasən.

Nümunəmizi daha da irəli apararaq, onların effektivliyindən asılı olaraq konkret satıcının komissiyasını (F1) hesablayaq: $200 və daha çox qazananlar üçün 20% komissiya, hər kəs üçün 10% .

Bunun üçün Vlookup tərəfindən qaytarılan dəyərin 200-dən böyük və ya ona bərabər olub olmadığını yoxlayırsınız və əgər belədirsə, onu 20%-ə, əks halda 10%-ə vurun:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

A2:A10 satıcı adları və C2:C10 satışlardır.

ƏGƏR #N/A xətalarını gizlətmək üçün İSNA VLOOKUP

VLOOKUP funksiyası müəyyən edilmiş dəyəri tapa bilmirsə, #N/A xətası atır. Həmin xətanı tutmaq və onu öz mətninizlə əvəz etmək üçün IF funksiyasının məntiqi testinə Vlookup düsturunu daxil edin, məsələn:

Təbii ki, "Tapılmadı" əvəzinə istədiyiniz mətni yaza bilərsiniz.

Fərz edək ki, sizdə satıcı siyahısı var.bir sütunda adlar, digər sütunda satış məbləğləri. Tapşırıq istifadəçinin F1-ə daxil etdiyi ada uyğun gələn nömrəni çəkməkdir. Əgər ad tapılmazsa, bunu göstərən mesajı göstərin.

A2:A10-dakı adlar və C2:C10 məbləğləri ilə tapşırıq aşağıdakı If Vlookup düsturu ilə yerinə yetirilə bilər:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

Ad tapılarsa, müvafiq satış məbləği qaytarılır:

Axtarış dəyəri tapılmazsa, Tapılmadı<#N/A xətası əvəzinə 2> mesajı görünür:

Bu düstur necə işləyir

Düsturun məntiqi çox sadədir: siz ISNA funksiyasından istifadə edirsiniz #N/A xətaları üçün Vlookup-ı yoxlamaq. Səhv baş verərsə, ISNA TRUE, əks halda FALSE qaytarır. Yuxarıdakı dəyərlər aşağıdakılardan birini yerinə yetirən IF funksiyasının məntiqi sınağına gedir:

• Məntiqi test TRUE (#N/A xətası) olarsa, mesajınız göstərilir.
• Məntiqi test YANLIŞ-dırsa (axtarış dəyəri tapılıbsa), Vlookup normal olaraq uyğunluğu qaytarır.

İFNA VLOOKUP yeni Excel versiyalarında

Excel 2013-dən başlayaraq, siz #N/A xətalarını tutmaq və idarə etmək üçün IF ISNA əvəzinə IFNA funksiyasından istifadə edə bilər:

Bizim nümunəmizdə düstur aşağıdakı formanı götürün:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

İpucu. Yalnız #N/A deyil, bütün növ xətaları tələyə salmaq istəyirsinizsə, VLOOKUP funksiyasını IFERROR funksiyası ilə birlikdə istifadə edin. Ətraflı məlumatı burada tapa bilərsiniz: IFERRORExcel-də VLOOKUP.

Excel Vlookup: tapılmadıqda 0 qaytarın

Ədədi dəyərlərlə işləyərkən, axtarış dəyəri tapılmadıqda sıfırı qaytarmaq istəyə bilərsiniz. Bunu etmək üçün yuxarıda müzakirə olunan ƏGƏR İSNA VLOOKUP düsturundan bir az dəyişikliklə istifadə edin: mətn mesajı əvəzinə IF funksiyasının əgər_əgər_əgər_dəyər arqumentində 0 daxil edin:

Nümunə cədvəlimizdə düstur aşağıdakı kimi olacaq:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 və 2013-ün son versiyaları üçün IFNA Vlookup birləşməsindən yenidən istifadə edə bilərsiniz:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: tapılmadıqda boş xananı qaytarın

Bu, daha bir variasiyadır "Vlookup if then" ifadəsinin: axtarış dəyəri tapılmadıqda heç nə qaytarmır. Bunu etmək üçün düsturunuza #N/A xətası əvəzinə boş sətir ("") qaytarmağı əmr edin:

Aşağıda bir neçə tam düstur nümunəsidir:

Bütün Excel versiyaları üçün:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 və Excel 2013 üçün:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

Əgər İndeks Uyğunluğu ilə - Əgər şərti ilə sol vlookup

Təcrübəli Excel istifadəçiləri VLOOKUP funksiyasının Excel-də şaquli axtarışın yeganə yolu olmadığını bilirlər. INDEX MATCH kombinasiyası da bu məqsəd üçün istifadə edilə bilər və o, daha güclü və çox yönlüdür. Yaxşı xəbər budur ki, Index Match IF ilə eyni şəkildə işləyə bilərVlookup.

Məsələn, A sütununda sifariş nömrələriniz və B sütununda satıcı adlarınız var. Siz konkret satıcı üçün sifariş nömrəsini çəkmək üçün düstur axtarırsınız.

Vlookup ola bilməz. sağdan sola axtarış edə bilmədiyi üçün bu halda istifadə olunur. Axtarış dəyəri axtarış sütununda tapıldığı müddətcə İndeks Uyğunluğu problemsiz işləyəcək. Əks halda, #N/A xətası görünəcək. Standart səhv qeydini öz mətninizlə əvəz etmək üçün IF ISNA daxilində İndeks Uyğunluğunu yerləşdirin:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Excel 2016 və 2016-da düsturu daha çox etmək üçün İFNA yerinə IFNA-dan istifadə edə bilərsiniz. yığcam:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

Oxşar şəkildə, siz İndeks Uyğunluğunu digər If düsturlarında istifadə edə bilərsiniz.

Siz belə istifadə edirsiniz Vlookup və IF ifadəsi Excel-də birlikdə. Bu dərslikdə müzakirə olunan düsturlara daha yaxından baxmaq üçün aşağıdakı nümunə iş dəftərimizi yükləyə bilərsiniz. Oxuduğunuz üçün sizə təşəkkür edirəm və sizi gələn həftə bloqumuzda görməyə ümid edirəm!

Endirmək üçün məşq kitabı

Excel IF Vlookup - formula nümunələri (.xlsx faylı)