De tutorial lit sjen hoe't jo V LOOKUP en IF-funksje kombinearje kinne nei v-lookup mei if condition yn Excel. Jo sille ek leare hoe't jo IF ISNA VLOOKUP formules brûke om #N/A flaters te ferfangen troch jo eigen tekst, nul of lege sel.

Wylst de VLOOKUP en IF funksjes op har eigen nuttich binne, tegearre se leverje noch mear weardefolle ûnderfiningen. Dizze tutorial hâldt yn dat jo de syntaksis fan 'e twa funksjes goed ûnthâlde, oars kinne jo jo kennis opknappe troch de boppesteande keppelings te folgjen.

Vlookup mei If statement: return True/ False, Ja/Nee, ensfh.

Ien fan 'e meast foarkommende senario's as jo If en Vlookup tegearre kombinearje is om de wearde weromjûn troch Vlookup te fergelykjen mei in samplewearde en werom Ja / Nee of Wier / False as resultaat.

Yn de measte gefallen soe de folgjende generyske formule goed wurkje:

Oerset yn gewoan Ingelsk, de formule ynstruearret Excel om True werom te jaan as Vlookup wier is (dus lyk oan de opjûne wearde). As Vlookup is falsk (net lyk oan de oantsjutte wearde), de formule jout False .

Hjirûnder fine jo in pear echte gebrûk fan dizze IF Vlookup formule.

Foarbyld 1. Sykje in spesifike wearde op

Lit ús sizze, jo hawwe in list mei items yn kolom A en kwantiteit yn kolom B. Jo meitsje in dashboard foar jo brûkers en hawwe in formule nedichdat soe de kwantiteit foar in item yn E1 kontrolearje en de brûker ynformearje oft it item op foarried is of útferkocht.

Jo lûke de kwantiteit mei in gewoane Vlookup mei formule foar eksakte match lykas dizze:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Skriuw dan in IF-ferklearring dy't it resultaat fan Vlookup fergeliket mei nul, en "Nee" jout as it gelyk is oan 0, "Ja" oars:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

Yn stee fan Ja/Nee kinne jo TRUE/FALSE of In Stock/Outferkocht of in oare twa weromjaan karren. Bygelyks:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

Jo kinne de wearde dy't weromjûn wurdt troch Vlookup ek fergelykje mei sample tekst . Wês yn dit gefal der wis fan dat jo in tekststring tusken oanhalingstekens befetsje, lykas dit:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

Foarbyld 2. Fergelykje Vlookup-resultaat mei in oare sel

In oar typysk foarbyld fan Vlookup mei As betingst yn Excel fergeliket de Vlookup-útfier mei in wearde yn in oare sel. Wy kinne bygelyks kontrolearje as it grutter is as of gelyk oan in nûmer yn sel G2:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

En hjir is ús If-formule mei Vlookup yn aksje:

Op in fergelykbere manier kinne jo elke oare logyske operator brûke tegearre mei in selferwizing yn jo Excel If Vlookup-formule.

Foarbyld 3. Vlookup-wearden yn in koartere list

Om elke sel yn 'e doelkolom te fergelykjen mei in oare list en Wier of Ja werom te jaan as in oerienkomst fûn wurdt, False of Nee oars, brûk dizze generyske IF ISNA VLOOKUP formule:

As Vlookup resultearret yn de #N/A flater, jout de formule "Nee", wat betsjut dat de opsykwearde net fûn wurdt yn de opsyklist. As de wedstriid fûn wurdt, wurdt "Ja" weromjûn. Bygelyks:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

As jo ​​bedriuwslogika de tsjinoerstelde resultaten fereasket, wikselje dan gewoan "Ja" en "Nee" om de logika fan 'e formule te kearen:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel If Vlookup-formule om ferskate berekkeningen út te fieren

Njonken it werjaan fan jo eigen tekstberjochten, kin If-funksje mei Vlookup ferskate berekkeningen útfiere basearre op de kritearia dy't jo oantsjutte.

Nim ús foarbyld fierder, litte wy de kommisje fan in spesifike ferkeaper (F1) berekkenje ôfhinklik fan har effektiviteit: 20% kommisje foar dyjingen dy't $ 200 en mear makken, 10% foar elkenien oars .

Dêrfoar kontrolearje jo as de wearde weromjûn troch Vlookup grutter is as of gelyk oan 200, en as dat sa is, fermannichfâldigje it mei 20%, oars mei 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Wêr't A2:A10 ferkeapersnammen binne en C2:C10 ferkeap binne.

IF ISNA VLOOKUP om #N/A flaters te ferbergjen

As de VLOOKUP-funksje gjin spesifisearre wearde kin fine, smyt it in #N/A-flater. Om dy flater te fangen en te ferfangen troch jo eigen tekst, ynbêde in Vlookup-formule yn 'e logyske test fan 'e IF-funksje, lykas dit:

Natuerlik kinne jo elke tekst ynfiere dy't jo wolle yn plak fan "Net fûn".

Stel, jo hawwe in list mei ferkeapernammen yn ien kolom en ferkeap bedraggen yn in oare kolom. Jo taak is om in nûmer te lûken dat oerienkomt mei de namme dy't de brûker ynfiert yn F1. As de namme net fûn is, lit dan in berjocht sjen dat dat oanjout.

Mei de nammen yn A2:A10 en bedraggen C2:C10 kin de taak folbrocht wurde mei de folgjende If Vlookup-formule:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

As de namme fûn wurdt, wurdt in oerienkommende ferkeapbedrach weromjûn:

As de opsykwearde net fûn wurdt, wurdt de Net fûn berjocht ferskynt ynstee fan de #N/A flater:

Hoe't dizze formule wurket

De logika fan 'e formule is heul ienfâldich: jo brûke de ISNA-funksje om Vlookup te kontrolearjen op #N/A flaters. As der in flater optreedt, jout ISNA TRUE, oars FALSE. De boppesteande wearden geane nei de logyske test fan de IF-funksje, dy't ien fan de folgjende docht:

• As de logyske test TRUE is (#N/A flater), wurdt jo berjocht werjûn.
• As de logyske test FALSE is (opsykwearde wurdt fûn), jout Vlookup normaal in wedstriid werom.

IFNA VLOOKUP yn nijere Excel-ferzjes

Begjin mei Excel 2013, kinne jo kin de IFNA-funksje brûke ynstee fan IF ISNA om #N/A-flaters op te fangen en te behanneljen:

Yn ús foarbyld soe de formule nim de folgjende foarm oan:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

Tip. As jo ​​​​alle soarten flaters wolle trape, net allinich #N/A, brûk dan VLOOKUP yn kombinaasje mei de IFERROR-funksje. Mear details kinne fûn wurde hjir: IFERRORVLOOKUP yn Excel.

Excel Vlookup: as net fûn werom 0

As jo ​​wurkje mei numerike wearden, kinne jo in nul weromjaan as de opsykwearde net fûn is. Om it dien te hawwen, brûk de IF ISNA VLOOKUP-formule dy't hjirboppe besprutsen is mei in bytsje modifikaasje: ynstee fan in tekstberjocht, leverje 0 yn it value_if_true argumint fan de IF-funksje:

Yn ús foarbyldtabel soe de formule as folgjend gean:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Yn de resinte ferzjes fan Excel 2016 en 2013, kinne jo de IFNA Vlookup-kombinaasje wer brûke:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: as net fûn werom lege sel

Dit is noch ien fariant fan de "Vlookup if then" statement: jout neat as de opsykwearde net fûn is. Om dit te dwaan, ynstruearje jo formule om in lege tekenrige ("") werom te jaan ynstee fan de #N/A-flater:

Hjirûnder binne in pear folsleine formulefoarbylden:

Foar alle Excel-ferzjes:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Foar Excel 2016 en Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

As mei Index Match - links vlookup mei If condition

Erfarne Excel-brûkers witte dat de VLOOKUP-funksje net de ienige manier is om fertikale opsykjen yn Excel te dwaan. De INDEX MATCH-kombinaasje kin ek brûkt wurde foar dit doel en it is noch machtiger en alsidiger. It goede nijs is dat Index Match kin gearwurkje mei IF op krekt deselde wize asVlookup.

Jo hawwe bygelyks bestelnûmers yn kolom A en ferkeapersnammen yn kolom B. Jo sykje in formule om it bestelnûmer foar in spesifike ferkeaper te lûken.

Vlookup kin net wêze brûkt yn dit gefal omdat it kin net sykje fan rjochts nei lofts. Index Match sil wurkje sûnder in hitch sa lang as de opsykwearde wurdt fûn yn de opsykkolom. As net, sil in #N/A flater ferskine. Om de standert flaternotaasje te ferfangen troch jo eigen tekst, nêst Index Match binnen IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Yn Excel 2016 en 2016 kinne jo IFNA brûke ynstee fan IF ISNA om de formule mear te meitsjen compact:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

Op deselde manier kinne jo Index Match brûke yn oare If-formules.

Dit is hoe't jo brûke Vlookup en IF-ferklearring tegearre yn Excel. Om de formules dy't yn dizze tutorial besprutsen binne tichterby te besjen, binne jo wolkom om ús foarbyldwurkboek hjirûnder te downloaden. Ik tankje jo foar it lêzen en hoopje jo nije wike op ús blog te sjen!

Oefeningswurkboek foar download

Excel IF Vlookup - formulefoarbylden (.xlsx-bestân)