გაკვეთილი გვიჩვენებს, თუ როგორ გავაერთიანოთ V LOOKUP და IF ფუნქციები ერთად v-მოძებნა if პირობით Excel-ში. თქვენ ასევე შეისწავლით თუ როგორ გამოიყენოთ IF ISNA VLOOKUP ფორმულები #N/A შეცდომების ჩასანაცვლებლად საკუთარი ტექსტით, ნულოვანი ან ცარიელი უჯრედით.

მიუხედავად იმისა, რომ VLOOKUP და IF ფუნქციები თავისთავად სასარგებლოა, ერთად. ისინი აწვდიან კიდევ უფრო ძვირფას გამოცდილებას. ეს გაკვეთილი გულისხმობს, რომ კარგად გახსოვთ ორი ფუნქციის სინტაქსი, წინააღმდეგ შემთხვევაში შეიძლება დაგჭირდეთ თქვენი ცოდნის გაღრმავება ზემოაღნიშნული ბმულების მიყოლებით.

Vlooup with If განაცხადი: return True/ False, Yes/No და ა.შ.

ერთ-ერთი ყველაზე გავრცელებული სცენარი, როდესაც აერთიანებთ If-ს და Vlookup-ს, არის Vlookup-ის მიერ დაბრუნებული მნიშვნელობის შედარება ნიმუშის მნიშვნელობასთან და დაბრუნება დიახ / არა ან True / False როგორც შედეგი.

უმეტეს შემთხვევაში, შემდეგი ზოგადი ფორმულა კარგად იმუშავებს:

თარგმნილია უბრალო ინგლისურ ენაზე, ფორმულა ავალებს Excel-ს დააბრუნოს True თუ Vlookup არის true (ე.ი. ტოლია მითითებულ მნიშვნელობაზე). თუ Vlookup არის false (არ უდრის მითითებულ მნიშვნელობას), ფორმულა აბრუნებს False .

ქვემოთ ნახავთ ამ IF Vlookup ფორმულის რამდენიმე რეალურ ცხოვრებაში გამოყენებას.

მაგალითი 1. მოძებნეთ კონკრეტული მნიშვნელობა

ვთქვათ, თქვენ გაქვთ ელემენტების სია A სვეტში და რაოდენობა სვეტში B. თქვენ ქმნით საინფორმაციო დაფას თქვენი მომხმარებლებისთვის და გჭირდებათ ფორმულა.რომელიც შეამოწმებს E1 საქონლის რაოდენობას და აცნობებს მომხმარებელს, არის თუ არა საქონელი მარაგში ან გაყიდულია.

თქვენ იღებთ რაოდენობას ჩვეულებრივი Vlookup-ით ზუსტი შესატყვისი ფორმულით, როგორიცაა:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

შემდეგ, დაწერეთ IF განცხადება, რომელიც ადარებს Vlookup-ის შედეგს ნულთან და აბრუნებს "არას", თუ ის უდრის 0-ს, "დიახ" წინააღმდეგ შემთხვევაში:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

დიახ/არა -ის ნაცვლად, შეგიძლიათ დააბრუნოთ TRUE/FALSE ან საწყობში/გაყიდული ან ნებისმიერი სხვა არჩევანი. მაგალითად:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

ასევე შეგიძლიათ შეადაროთ Vlookup-ის მიერ დაბრუნებული მნიშვნელობა ნიმუშის ტექსტთან . ამ შემთხვევაში, დარწმუნდით, რომ ჩასვით ტექსტის სტრიქონი ბრჭყალებში, როგორიცაა:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

მაგალითი 2. შეადარეთ Vlookup შედეგი სხვა უჯრედთან

სხვა ტიპიური მაგალითი Vlookup with If პირობით Excel-ში არის Vlookup გამომავალი შედარება სხვა უჯრედის მნიშვნელობასთან. მაგალითად, ჩვენ შეგვიძლია შევამოწმოთ არის თუ არა ის მეტი ან ტოლი რიცხვზე G2 უჯრედში:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

და აქ არის ჩვენი If ფორმულა Vlookup-ით:

მსგავსად, შეგიძლიათ გამოიყენოთ ნებისმიერი სხვა ლოგიკური ოპერატორი უჯრედის მითითებასთან ერთად Excel If Vlookup ფორმულაში.

მაგალითი 3. Vlookup მნიშვნელობები მოკლე სიაში

სამიზნე სვეტის თითოეული უჯრედის სხვა სიასთან შესადარებლად და დასაბრუნებლად True ან Yes , თუ შესატყვისი ნაპოვნია, False ან No წინააღმდეგ შემთხვევაში, გამოიყენეთ ეს ზოგადი IF ISNA VLOOKUP ფორმულა:

თუ Vlookup-ი იწვევს #N/A შეცდომას, ფორმულა აბრუნებს "არა", რაც ნიშნავს, რომ საძიებო მნიშვნელობა არ არის ნაპოვნი საძიებო სიაში. თუ მატჩი ნაპოვნია, "დიახ" უბრუნდება. მაგალითად:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

თუ თქვენი ბიზნეს ლოგიკა მოითხოვს საპირისპირო შედეგებს, უბრალოდ შეცვალეთ "დიახ" და "არა" ფორმულის ლოგიკის შესაცვლელად:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

თქვენ მიერ მითითებულ კრიტერიუმებზე დაყრდნობით.

ჩვენი მაგალითის შემდგომ, მოდით გამოვთვალოთ კონკრეტული გამყიდველის საკომისიო (F1) მათი ეფექტურობის მიხედვით: 20% საკომისიო მათთვის, ვინც გამოიმუშავა $200 და მეტი, 10% ყველა დანარჩენისთვის. .

ამისთვის, თქვენ ამოწმებთ Vlookup-ის მიერ დაბრუნებული მნიშვნელობა მეტია თუ ტოლი 200-ზე და თუ არის, გაამრავლეთ 20%-ზე, წინააღმდეგ შემთხვევაში 10%-ით:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

სადაც A2:A10 არის გამყიდველის სახელები და C2:C10 არის გაყიდვები.

IF ISNA VLOOKUP #N/A შეცდომების დასამალად

თუ VLOOKUP ფუნქცია ვერ პოულობს მითითებულ მნიშვნელობას, ის აგდებს #N/A შეცდომას. ამ შეცდომის დასაფიქსირებლად და საკუთარი ტექსტით ჩასანაცვლებლად, ჩადეთ Vlookup ფორმულა IF ფუნქციის ლოგიკურ ტესტში, როგორიცაა:

ბუნებრივია, თქვენ შეგიძლიათ აკრიფოთ ნებისმიერი ტექსტი, რომელიც მოგწონთ "არ მოიძებნა" ნაცვლად.

ვვარაუდობთ, რომ თქვენ გაქვთ გამყიდველის სია.სახელები ერთ სვეტში და გაყიდვების თანხები მეორე სვეტში. თქვენი ამოცანაა მოიყვანოთ ნომერი, რომელიც შეესაბამება იმ სახელს, რომელსაც მომხმარებელი შეაქვს F1-ში. თუ სახელი ვერ მოიძებნა, აჩვენეთ შეტყობინება ამის მითითებით.

A2:A10 სახელებით და C2:C10 თანხებით, დავალება შეიძლება შესრულდეს შემდეგი If Vlookup ფორმულით:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

თუ სახელი მოიძებნა, შესაბამისი გაყიდვის თანხა ბრუნდება:

თუ საძიებო მნიშვნელობა ვერ მოიძებნა, არ მოიძებნა<#N/A შეცდომის ნაცვლად ჩნდება 2> შეტყობინება:

როგორ მუშაობს ეს ფორმულა

ფორმულის ლოგიკა ძალიან მარტივია: იყენებთ ISNA ფუნქციას Vlookup #N/A შეცდომების შესამოწმებლად. თუ შეცდომა მოხდა, ISNA აბრუნებს TRUE-ს, წინააღმდეგ შემთხვევაში FALSE-ს. ზემოაღნიშნული მნიშვნელობები გადადის IF ფუნქციის ლოგიკურ ტესტზე, რომელიც აკეთებს ერთ-ერთ შემდეგს:

• თუ ლოგიკური ტესტი არის TRUE (#N/A შეცდომა), გამოჩნდება თქვენი შეტყობინება.
• თუ ლოგიკური ტესტი არის FALSE (მოძიების მნიშვნელობა ნაპოვნია), Vlookup ნორმალურად აბრუნებს შესაბამისობას.

IFNA VLOOKUP Excel-ის ახალ ვერსიებში

Excel 2013-ით დაწყებული, თქვენ შეუძლია გამოიყენოს IFNA ფუნქცია IF ISNA-ის ნაცვლად #N/A შეცდომების დასაჭერად და დასამუშავებლად:

ჩვენს მაგალითში, ფორმულა მიიღეთ შემდეგი ფორმა:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

რჩევა. თუ გსურთ შეცვალოთ ყველა სახის შეცდომა, არა მხოლოდ #N/A, გამოიყენეთ VLOOKUP IFERROR ფუნქციასთან ერთად. დამატებითი დეტალები შეგიძლიათ იხილოთ აქ: IFERRORVLOOKUP Excel-ში.

Excel Vlookup: თუ ვერ იქნა ნაპოვნი, დააბრუნებს 0

ციფრულ მნიშვნელობებთან მუშაობისას, შეიძლება დაგჭირდეთ ნულის დაბრუნება, როდესაც საძიებო მნიშვნელობა ვერ მოიძებნება. ამის შესასრულებლად გამოიყენეთ ზემოთ განხილული IF ISNA VLOOKUP ფორმულა მცირედი შეცვლით: ტექსტური შეტყობინების ნაცვლად მიაწოდეთ 0 IF ფუნქციის value_if_true არგუმენტში:

ჩვენს სანიმუშო ცხრილში, ფორმულა ასე იქნება:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 და 2013 წლების უახლესი ვერსიები, შეგიძლიათ კვლავ გამოიყენოთ IFNA Vlookup კომბინაცია:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: თუ ვერ მოიძებნა დააბრუნეთ ცარიელი უჯრედი

ეს არის კიდევ ერთი ვარიაცია "Vlookup if then" განცხადებაში: არაფერი დააბრუნეთ, როდესაც საძიებო მნიშვნელობა ვერ მოიძებნა. ამისათვის დაავალეთ თქვენს ფორმულას დააბრუნოს ცარიელი სტრიქონი ("") #N/A შეცდომის ნაცვლად:

ქვემოთ არის რამდენიმე სრული ფორმულის მაგალითი:

Excel-ის ყველა ვერსიისთვის:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 და Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

If with Index Match - მარცხენა vlookup If პირობით

Excel-ის გამოცდილმა მომხმარებლებმა იციან, რომ VLOOKUP ფუნქცია არ არის ერთადერთი გზა Excel-ში ვერტიკალური ძიების გასაკეთებლად. INDEX MATCH კომბინაცია ასევე შეიძლება გამოყენებულ იქნას ამ მიზნით და ის კიდევ უფრო ძლიერი და მრავალმხრივია. კარგი ამბავი ის არის, რომ Index Match-ს შეუძლია IF-თან ერთად იმუშაოს ზუსტად ისევე, როგორცVlookup.

მაგალითად, თქვენ გაქვთ შეკვეთის ნომრები A სვეტში და გამყიდველის სახელები სვეტში B. თქვენ ეძებთ ფორმულას კონკრეტული გამყიდველისთვის შეკვეთის ნომრის გამოსაყვანად.

Vlookup არ შეიძლება იყოს გამოიყენება ამ შემთხვევაში, რადგან მას არ შეუძლია მოძებნოს მარჯვნიდან მარცხნივ. Index Match იმუშავებს შეფერხების გარეშე, სანამ საძიებო მნიშვნელობა მოიძებნება საძიებო სვეტში. თუ არა, გამოჩნდება #N/A შეცდომა. შეცდომის სტანდარტული აღნიშვნის საკუთარი ტექსტით ჩასანაცვლებლად, განათავსეთ Index Match IF ISNA-ში:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Excel 2016 და 2016 წლებში, შეგიძლიათ გამოიყენოთ IFNA IF ISNA-ის ნაცვლად, რათა ფორმულა უფრო მეტად გახადოთ. კომპაქტური:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

მსგავსი წესით, შეგიძლიათ გამოიყენოთ Index Match სხვა If ფორმულებში.

ასე იყენებთ Vlookup და IF განცხადება ერთად Excel-ში. ამ სახელმძღვანელოში განხილული ფორმულების უფრო დეტალურად დასათვალიერებლად, შეგიძლიათ ჩამოტვირთოთ ჩვენი სამუშაო წიგნის ნიმუში ქვემოთ. მადლობას გიხდით წაკითხვისთვის და იმედი მაქვს, რომ მომავალ კვირას გნახავთ ჩვენს ბლოგზე!

სავარჯიშო სამუშაო წიგნი ჩამოსატვირთად

Excel IF Vlookup - ფორმულების მაგალითები (.xlsx ფაილი)