이 튜토리얼은 V LOOKUP과 IF 함수를 결합하여 Excel에서 if 조건을 사용하여 v-lookup하는 방법을 보여줍니다. 또한 IF ISNA VLOOKUP 수식을 사용하여 #N/A 오류를 자신의 텍스트, 0 또는 빈 셀로 바꾸는 방법을 배웁니다.

VLOOKUP 및 IF 함수는 함께 사용할 때 유용합니다. 그들은 훨씬 더 가치 있는 경험을 제공합니다. 이 자습서는 두 함수의 구문을 잘 기억하고 있음을 의미합니다. 그렇지 않으면 위의 링크를 따라 지식을 다듬는 것이 좋습니다.

If 문을 사용한 Vlookup: return True/ False, Yes/No 등

If와 Vlookup을 함께 결합할 때 가장 일반적인 시나리오 중 하나는 Vlookup이 반환한 값을 샘플 값과 비교하여 Yes / No 를 반환하는 것입니다. 또는 결과로 True / False .

대부분의 경우 다음과 같은 일반 수식이 잘 작동합니다.

평이한 영어로 번역된 이 수식은 Vlookup이 true(즉, 지정된 값과 같음)인 경우 True 를 반환하도록 Excel에 지시합니다. Vlookup이 false(지정된 값과 같지 않음)인 경우 수식은 False 를 반환합니다.

아래에서 이 IF Vlookup 수식의 몇 가지 실제 용도를 찾을 수 있습니다.

예제 1. 특정 값 조회

A 열에 항목 목록이 있고 B 열에 수량이 있다고 가정해 보겠습니다. 사용자를 위한 대시보드를 만들고 공식이 필요합니다.E1에서 항목의 수량을 확인하고 사용자에게 해당 항목의 재고가 있는지 또는 품절인지 알려줍니다.

다음과 같은 정확한 일치 수식을 사용하여 일반 Vlookup으로 수량을 가져옵니다.

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

그런 다음 Vlookup의 결과를 0과 비교하고 0과 같으면 "아니오"를 반환하고 그렇지 않으면 "예"를 반환하는 IF 문을 작성합니다.

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

예/아니요 대신 참/거짓 또는 재고 있음/품절 또는 다른 두 가지를 반환할 수 있습니다. 선택. 예:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

Vlookup에서 반환한 값을 sample text 와 비교할 수도 있습니다. 이 경우 다음과 같이 텍스트 문자열을 따옴표로 묶어야 합니다.

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

예 2. Vlookup 결과를 다른 셀과 비교

또 다른 일반적인 예 Excel에서 조건이 있는 Vlookup은 Vlookup 출력을 다른 셀의 값과 비교합니다. 예를 들어 G2 셀의 숫자보다 크거나 같은지 확인할 수 있습니다.

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

여기에 Vlookup이 있는 If 공식이 있습니다.

유사한 방식으로 Excel If Vlookup 수식에서 셀 참조와 함께 다른 논리 연산자를 사용할 수 있습니다.

예제 3. 더 짧은 목록의 Vlookup 값

대상 열의 각 셀을 다른 목록과 비교하고 일치 항목이 있으면 True 또는 Yes 를 반환하고 False 또는 No<를 반환합니다. 2> 그렇지 않으면 다음 일반 IF ISNA VLOOKUP 공식을 사용합니다.

Vlookup에서 #N/A 오류가 발생하면 수식에서 "No"를 반환합니다. 즉, 조회 목록에서 조회 값을 찾을 수 없습니다. 일치하는 항목이 있으면 "예"가 반환됩니다. 예를 들면 다음과 같습니다.

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

비즈니스 논리에 반대 결과가 필요한 경우 "예"와 "아니요"를 바꿔 수식의 논리를 뒤집으십시오.

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel If Vlookup 수식이 다른 계산을 수행하는 경우

자신의 문자 메시지를 표시하는 것 외에도 Vlookup이 있는 If 함수는 다른 계산을 수행할 수 있습니다. 지정한 기준을 기반으로 합니다.

더 나아가 예시를 들어 특정 판매자(F1)의 효율성에 따라 수수료를 계산해 보겠습니다. $200 이상을 버는 사람에게는 20%, 그 외 모든 사람에게는 10%의 수수료가 부과됩니다. .

이를 위해 Vlookup에서 반환한 값이 200보다 크거나 같은지 확인하고 크면 20%, 아니면 10%를 곱합니다:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

여기서 A2:A10은 판매자 이름이고 C2:C10은 판매입니다.

#N/A 오류를 숨기기 위한 ISNA VLOOKUP

VLOOKUP 함수가 지정된 값을 찾을 수 없으면 #N/A 오류가 발생합니다. 해당 오류를 파악하고 자신의 텍스트로 바꾸려면 다음과 같이 IF 함수의 논리 테스트에 Vlookup 수식을 포함합니다.

당연히 "찾을 수 없음" 대신 원하는 텍스트를 입력할 수 있습니다.

판매자 목록이 있다고 가정합니다.한 열에는 이름이 있고 다른 열에는 판매 금액이 있습니다. 당신의 임무는 사용자가 F1에 입력한 이름에 해당하는 숫자를 가져오는 것입니다. 이름을 찾을 수 없는 경우 이를 나타내는 메시지를 표시합니다.

A2:A10의 이름과 C2:C10의 금액을 사용하면 다음 If Vlookup 공식으로 작업을 수행할 수 있습니다.

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

이름을 찾은 경우 해당 판매 금액을 반환합니다.

조회 값을 찾지 못한 경우 찾을 수 없음 메시지가 #N/A 오류 대신 나타납니다.

How this formula works

The formula's logic is very simple: you use the ISNA function #N/A 오류에 대한 Vlookup을 확인합니다. 오류가 발생하면 ISNA는 TRUE를 반환하고 그렇지 않으면 FALSE를 반환합니다. 위의 값은 다음 중 하나를 수행하는 IF 함수의 논리 테스트로 이동합니다.

• 논리 테스트가 TRUE(#N/A 오류)이면 메시지가 표시됩니다.
• 논리 테스트가 FALSE(조회 값이 있음)인 경우 Vlookup은 정상적으로 일치 항목을 반환합니다.

최신 Excel 버전의 IFNA VLOOKUP

Excel 2013부터 IF ISNA 대신 IFNA 함수를 사용하여 #N/A 오류를 포착하고 처리할 수 있습니다.

이 예에서 수식은 다음 모양을 취하십시오:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

팁. #N/A뿐만 아니라 모든 종류의 오류를 트랩하려면 IFERROR 함수와 함께 VLOOKUP을 사용하세요. 자세한 내용은 IFERROR에서 확인할 수 있습니다.Excel에서 VLOOKUP.

Excel Vlookup: 찾을 수 없는 경우 0

숫자 값으로 작업할 때 조회 값을 찾을 수 없을 때 0을 반환할 수 있습니다. 이를 수행하려면 위에서 설명한 IF ISNA VLOOKUP 공식을 약간 수정하여 사용합니다. 텍스트 메시지 대신 IF 함수의 value_if_true 인수에 0을 제공합니다.

샘플 테이블에서 수식은 다음과 같습니다.

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

In the 최신 버전의 Excel 2016 및 2013에서는 IFNA Vlookup 조합을 다시 사용할 수 있습니다. "Vlookup if then" 문: 조회 값을 찾을 수 없으면 아무 것도 반환하지 않습니다. 이렇게 하려면 수식에 #N/A 오류 대신 빈 문자열("")을 반환하도록 지시합니다.

Below 다음은 몇 가지 완전한 수식 예입니다.

모든 Excel 버전의 경우:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Excel 2016 및 Excel 2013의 경우:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

If with Index Match - left vlookup with If condition

숙련된 Excel 사용자는 VLOOKUP 기능이 Excel에서 수직 조회를 수행하는 유일한 방법이 아니라는 것을 알고 있습니다. INDEX MATCH 조합도 이 용도로 사용할 수 있으며 훨씬 더 강력하고 다재다능합니다. 좋은 소식은 Index Match가 다음과 같은 방식으로 IF와 함께 작동할 수 있다는 것입니다.Vlookup.

예를 들어 A열에 주문 번호가 있고 B열에 판매자 이름이 있습니다. 특정 판매자의 주문 번호를 가져오는 공식을 찾고 있습니다.

Vlookup은 할 수 없습니다. 오른쪽에서 왼쪽으로 검색할 수 없기 때문에 이 경우에 사용됩니다. 색인 일치는 조회 열에서 조회 값이 발견되는 한 차질 없이 작동합니다. 그렇지 않은 경우 #N/A 오류가 표시됩니다. 표준 오류 표기법을 자신의 텍스트로 바꾸려면 IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

In Excel 2016 및 2016에서 IF ISNA 대신 IFNA를 사용하여 수식을 더 많이 만들 수 있습니다. compact:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

유사한 방식으로 다른 If 수식에서 Index Match를 사용할 수 있습니다.

이렇게 사용합니다. Excel에서 Vlookup 및 IF 문을 함께 사용합니다. 이 자습서에서 설명하는 수식을 자세히 살펴보려면 아래에서 샘플 통합 문서를 다운로드하세요. 읽어 주셔서 감사합니다. 다음 주에 저희 블로그에서 뵙기를 바랍니다!

다운로드용 실습 워크북

Excel IF Vlookup - 수식 예제(.xlsx 파일)