Mục lục
Hướng dẫn này giải thích cú pháp và cách sử dụng hàm NĂM trong Excel, đồng thời cung cấp các ví dụ về công thức để trích xuất năm từ ngày, chuyển đổi ngày thành tháng và năm, tính tuổi từ ngày sinh và xác định năm nhuận.
Trong một vài bài đăng gần đây, chúng ta đã khám phá các cách khác nhau để tính toán ngày và giờ trong Excel và học được nhiều hàm hữu ích như WEEKDAY, WEEKNUM, MONTH và DAY. Hôm nay, chúng ta sẽ tập trung vào một đơn vị thời gian lớn hơn và nói về cách tính năm trong trang tính Excel của bạn.
Trong hướng dẫn này, bạn sẽ tìm hiểu:
Hàm YEAR trong Excel
Hàm YEAR trong Excel trả về một năm có bốn chữ số tương ứng với một ngày nhất định dưới dạng một số nguyên từ 1900 đến 9999.
Cú pháp của hàm YEAR trong Excel rất đơn giản có thể là:
YEAR(serial_number)Trong đó serial_number là bất kỳ ngày hợp lệ nào trong năm mà bạn muốn tìm.
Công thức NĂM trong Excel
Để tạo công thức NĂM trong Excel, bạn có thể cung cấp ngày nguồn theo nhiều cách.
Sử dụng hàm DATE
Công thức cách đáng tin cậy nhất để cung cấp ngày trong Excel là sử dụng hàm DATE.
Ví dụ: công thức sau trả về năm cho ngày 28 tháng 4 năm 2015:
=YEAR(DATE(2015, 4, 28))
As một số sê-ri đại diện cho ngày
Trong hệ thống Excel nội bộ, ngày được lưu trữ dưới dạng số sê-ri bắt đầu từ ngày 1 tháng 1 năm 1900, được lưu trữ dưới dạng số 1. Để biết thêmthông tin về cách ngày được lưu trữ trong Excel, vui lòng xem định dạng ngày của Excel.
Ngày 28 tháng 4 năm 2015 được lưu trữ là 42122, vì vậy bạn có thể nhập số này trực tiếp vào công thức:
=YEAR(42122)
Mặc dù có thể chấp nhận được nhưng phương pháp này không được khuyến nghị vì cách đánh số ngày có thể khác nhau giữa các hệ thống khác nhau.
Là một tham chiếu ô
Giả sử bạn có một ngày hợp lệ trong một số ô, bạn có thể chỉ cần tham khảo ô đó. Ví dụ:
=YEAR(A1)
Là kết quả của một số công thức khác
Ví dụ: bạn có thể sử dụng hàm TODAY() để trích xuất năm từ ngày hiện tại:
=YEAR(TODAY())
Dưới dạng văn bản
Trong trường hợp đơn giản, công thức NĂM thậm chí có thể hiểu ngày được nhập dưới dạng văn bản, như sau:
=YEAR("28-Apr-2015")
Khi sử dụng phương pháp này, vui lòng kiểm tra kỹ xem bạn có nhập ngày ở định dạng mà Excel hiểu được không. Ngoài ra, hãy nhớ rằng Microsoft không đảm bảo kết quả chính xác khi ngày được cung cấp dưới dạng giá trị văn bản.
Ảnh chụp màn hình sau đây minh họa tất cả các công thức NĂM ở trên đang hoạt động, tất cả đều trả về 2015 như bạn mong đợi :)
Cách chuyển đổi ngày thành năm trong Excel
Khi bạn làm việc với thông tin ngày tháng trong Excel, trang tính của bạn thường hiển thị đầy đủ ngày, bao gồm tháng, ngày và năm . Tuy nhiên, đối với các mốc quan trọng và các sự kiện quan trọng như ra mắt sản phẩm hoặc mua lại tài sản, bạn có thể chỉ muốn xem năm mà không cần nhập lại hoặc sửa đổidữ liệu gốc. Dưới đây, bạn sẽ tìm thấy 3 cách nhanh chóng để thực hiện việc này.
Ví dụ 1. Trích xuất một năm từ ngày tháng bằng cách sử dụng hàm YEAR
Thực tế là bạn đã biết cách sử dụng hàm YEAR trong Excel để chuyển đổi một ngày thành một năm. Ảnh chụp màn hình ở trên minh họa một loạt các công thức và bạn có thể xem thêm một vài ví dụ trong ảnh chụp màn hình bên dưới. Lưu ý rằng hàm NĂM hoàn toàn hiểu ngày tháng ở tất cả các định dạng có thể:
Ví dụ 2. Chuyển đổi ngày thành tháng và năm trong Excel
Để chuyển đổi một ngày nhất định sang năm và tháng, bạn có thể sử dụng hàm TEXT để trích xuất từng đơn vị riêng lẻ, sau đó ghép các hàm đó trong một công thức.
Trong hàm TEXT, bạn có thể sử dụng các mã khác nhau cho tháng và năm, chẳng hạn như:
- "mmm" - tên tháng viết tắt, như tháng 1 - tháng 12.
- "mmmm" - tên tháng đầy đủ, như tháng 1 - tháng 12.
- "yy" - Năm có 2 chữ số
- "yyyy" - Năm có 4 chữ số
Để đầu ra dễ đọc hơn, bạn có thể phân tách các mã bằng dấu phẩy, dấu gạch nối hoặc bất kỳ ký tự nào khác, như trong các công thức Ngày thành tháng và năm sau:
=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")
Hoặc
=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")
Trong đó B2 là ô chứa ngày tháng.
Ví dụ 3. Hiển thị ngày tháng dưới dạng năm
Nếu việc lưu trữ ngày tháng trong sổ làm việc của bạn không thực sự quan trọng, bạn có thể làm cho Excel chỉ hiển thị các năm với ut thay đổi ngày ban đầu. Nói cách khác, bạn có thể cóngày đầy đủ được lưu trữ trong các ô, nhưng chỉ có năm được hiển thị.
Trong trường hợp này, không cần công thức. Bạn chỉ cần mở hộp thoại Định dạng ô bằng cách nhấn Ctrl + 1 , chọn danh mục Tùy chỉnh trên tab Số và nhập một trong các mã bên dưới vào Loại hộp:
- yy - để hiển thị năm có 2 chữ số, như 00 - 99.
- yyyy - để hiển thị năm có 4 chữ số, như 1900 - 9999 .
Hãy nhớ rằng phương pháp này không thay đổi ngày ban đầu , nó chỉ thay đổi cách hiển thị ngày trong trang tính của bạn. Nếu bạn tham chiếu đến các ô như vậy trong công thức của mình, Microsoft Excel sẽ thực hiện phép tính ngày thay vì phép tính năm.
Bạn có thể tìm thêm chi tiết về cách thay đổi định dạng ngày trong hướng dẫn này: Cách thay đổi định dạng ngày trong Excel.
Cách tính tuổi từ ngày sinh trong Excel
Có một số cách tính tuổi từ ngày sinh trong Excel - sử dụng hàm DATEDIF, YEARFRAC hoặc INT kết hợp với TODAY(). Hàm TODAY cung cấp ngày để tính tuổi, đảm bảo rằng công thức của bạn sẽ luôn trả về đúng tuổi.
Tính tuổi từ ngày sinh theo năm
Cách truyền thống để tính tuổi của một người tính bằng năm là trừ ngày sinh từ ngày hiện tại. Cách tiếp cận này hoạt động tốt trong cuộc sống hàng ngày, nhưng một công thức tính tuổi Excel tương tự không hoàn toàn đúng:
INT((TODAY()- DOB)/365)Trong đó DOB là ngày sinh.
Phần đầu của công thức (TODAY()-B2) tính toán chênh lệch là ngày và bạn chia nó cho 365 để có số năm. Trong hầu hết các trường hợp, kết quả của phương trình này là một số thập phân và bạn có hàm INT làm tròn nó xuống số nguyên gần nhất.
Giả sử ngày sinh nằm trong ô B2, công thức hoàn chỉnh sẽ như sau :
=INT((TODAY()-B2)/365)
Như đã đề cập ở trên, công thức tính tuổi này không phải lúc nào cũng hoàn hảo và đây là lý do tại sao. Mỗi năm thứ 4 là một năm nhuận có 366 ngày, trong khi công thức chia số ngày cho 365. Vì vậy, nếu ai đó sinh vào ngày 29 tháng 2 và hôm nay là ngày 28 tháng 2, thì công thức tính tuổi này sẽ khiến người đó già đi một ngày.
Chia cho 365,25 thay vì 365 cũng không hoàn hảo, chẳng hạn như khi tính tuổi của một đứa trẻ chưa sống qua năm nhuận.
Với những điều trên, bạn sẽ tốt hơn nên lưu cách tính tuổi này cho cuộc sống bình thường và sử dụng một trong các công thức sau để tính tuổi từ ngày sinh trong Excel.
DATEDIF( DOB, TODAY(), "y") ROUNDDOWN (YEARFRAC( DOB, TODAY(), 1), 0)Giải thích chi tiết về các công thức trên được cung cấp trong Cách tính tuổi trong Excel. Và ảnh chụp màn hình sau đây minh họa một công thức tính tuổi thực tế đang hoạt động:
=DATEDIF(B2, TODAY(), "y")
Tính tuổi chính xác từngày sinh (theo năm, tháng và ngày)
Để tính tuổi chính xác theo năm, tháng và ngày, hãy viết ba hàm DATEDIF với các đơn vị sau trong đối số cuối cùng:
- Y - để tính số năm hoàn chỉnh.
- YM - để lấy chênh lệch giữa các tháng, bỏ qua năm.
- MD - để lấy chênh lệch giữa ngày, bỏ qua năm và tháng .
Sau đó, ghép 3 hàm DATEDIF trong một công thức duy nhất, phân tách các số do từng hàm trả về bằng dấu phẩy và xác định ý nghĩa của từng số.
Giả sử ngày của sinh nằm trong ô B2, công thức hoàn chỉnh như sau:
=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
Công thức tính tuổi này có thể rất hữu ích, chẳng hạn như để bác sĩ hiển thị tuổi chính xác của bệnh nhân hoặc để một nhân viên nhân sự để biết tuổi chính xác của tất cả nhân viên:
Để biết thêm ví dụ về công thức chẳng hạn như tính tuổi vào một ngày cụ thể hoặc trong một năm nhất định, vui lòng xem phần sau hướng dẫn: Cách tính tuổi trong Excel.
Cách lấy số ngày trong năm (1-365)
Ví dụ này minh họa cách bạn có thể lấy số của một ngày nhất định trong một năm, trong khoảng từ 1 đến 365 (1-366 trong năm nhuận) với ngày 1 tháng 1 được coi là ngày 1.
Đối với điều này, hãy sử dụng hàm YEAR cùng với DATE theo cách sau:
=A2-DATE(YEAR(A2), 1, 0)
Trong đó A2 là ô chứa ngày.
Và bây giờ, hãy xem công thức thực sự có tác dụng gì. CácHàm YEAR truy xuất năm của ngày trong ô A2 và chuyển nó tới hàm DATE(năm, tháng, ngày) , hàm này trả về số thứ tự đại diện cho một ngày nhất định.
Vì vậy, trong công thức của chúng tôi, year được trích xuất từ ngày ban đầu (A2), month là 1 (tháng 1) và day là 0. Trên thực tế, ngày 0 buộc Excel phải trả về ngày 31 tháng 12 của năm trước , vì chúng tôi muốn ngày 1 tháng 1 được coi là ngày đầu tiên. Và sau đó, bạn trừ số sê-ri được trả về bởi công thức DATE từ ngày ban đầu (cũng được lưu dưới dạng số sê-ri trong Excel) và sự khác biệt là ngày trong năm mà bạn đang tìm kiếm. Ví dụ: ngày 5 tháng 1 năm 2015 được lưu trữ là 42009 và ngày 31 tháng 12 năm 2014 là 42004, vì vậy 42009 - 42004 = 5.
Nếu khái niệm về ngày 0 có vẻ không đúng với bạn, bạn có thể sử dụng cách sau thay vào đó là công thức:
=A2-DATE(YEAR(A2), 1, 1)+1
Cách tính số ngày còn lại trong năm
Để tính số ngày còn lại trong năm, chúng ta sẽ sử dụng Chức năng DATE và NĂM một lần nữa. Công thức này dựa trên cách tiếp cận tương tự như Ví dụ 3 ở trên, vì vậy bạn sẽ không gặp bất kỳ khó khăn nào khi hiểu logic của nó:
=DATE(YEAR(A2),12,31)-A2
Nếu bạn muốn biết còn lại bao nhiêu ngày cho đến cuối năm dựa trên ngày hiện tại, bạn sử dụng hàm TODAY() của Excel như sau:
=DATE(2015, 12, 31)-TODAY()
Trong đó 2015 là năm hiện tại .
Tính toánnăm nhuận trong Excel
Như các bạn đã biết, gần như cứ 4 năm lại có thêm một ngày 29/2 và được gọi là năm nhuận. Trong trang tính Microsoft Excel, bạn có thể xác định xem một ngày nhất định thuộc năm nhuận hay năm thường theo nhiều cách khác nhau. Tôi sẽ chỉ trình bày một vài công thức mà theo tôi là dễ hiểu nhất.
Công thức 1. Kiểm tra xem tháng 2 có 29 ngày không
Đây là một phép thử rất rõ ràng. Vì tháng 2 có 29 ngày trong các năm nhuận nên chúng ta tính số ngày trong tháng 2 của một năm nhất định và so sánh với số 29. Ví dụ:
=DAY(DATE(2015,3,1)-1)=29
Trong công thức này, Hàm DATE(2015,3,1) trả về ngày đầu tiên của tháng 3 trong năm 2015, từ đó chúng ta trừ đi 1. Hàm DAY trích xuất số ngày từ ngày này và chúng ta so sánh số đó với 29. Nếu các số khớp nhau, công thức trả về TRUE, ngược lại là FALSE.
Nếu bạn đã có một danh sách các ngày trong trang tính Excel của mình và bạn muốn biết ngày nào là năm nhuận thì hãy kết hợp hàm YEAR trong công thức để trích xuất một năm từ ngày:
=DAY(DATE(YEAR(A2),3,1)-1)=29
Trong đó A2 là ô chứa ngày.
Kết quả trả về của công thức như sau:
Ngoài ra, bạn có thể sử dụng hàm EOMONTH để trả về ngày cuối cùng trong tháng 2 và so sánh số đó với 29:
=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29
Để làm cho công thức trở nên thân thiện hơn với người dùng , sử dụng hàm IF và có nótrả về, nói "Năm nhuận" và "Năm thường" thay vì TRUE và FALSE:
=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")
=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")
Công thức 2 .Kiểm tra xem năm có 366 ngày không
Đây là một phép thử hiển nhiên khác mà hầu như không cần bất kỳ lời giải thích nào. Chúng ta sử dụng một hàm DATE để trả về ngày 1 tháng 1 của năm tiếp theo, một hàm DATE khác để trả về ngày 1 tháng 1 năm nay, trừ giá trị sau khỏi giá trị cũ và kiểm tra xem chênh lệch có bằng 366 không:
=DATE(2016,1,1) - DATE(2015,1,1)=366
Để tính một năm dựa trên ngày được nhập vào một số ô, bạn sử dụng hàm NĂM của Excel giống hệt như cách chúng ta đã làm trong ví dụ trước:
=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366
Trong đó A2 là một ô chứa ngày.
Và đương nhiên, bạn có thể đặt công thức NGÀY / NĂM ở trên trong hàm IF để hàm này trả về giá trị có ý nghĩa hơn các giá trị Boolean của TRUE và FALSE:
=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")
Như đã đề cập, đây không phải là những cách khả thi duy nhất để tính năm nhuận trong Excel. Nếu tò mò muốn biết các giải pháp khác, bạn có thể kiểm tra phương pháp do Microsoft đề xuất. Như thường lệ, những người của Microsoft không tìm kiếm những cách dễ dàng, phải không?
Hy vọng rằng bài viết này đã giúp bạn tìm ra các phép tính năm trong Excel. Tôi cảm ơn bạn đã đọc và mong được gặp bạn vào tuần tới.
