توفر جداول البيانات نظامًا أساسيًا رائعًا لإدارة جداول البيانات. ولكن هل هناك أي وظائف سهلة لجداول بيانات Google لإجراء العمليات الحسابية اليومية؟ اكتشف أدناه.

وظيفة SUM لجداول بيانات Google

أعتقد أن أكثر العمليات المطلوبة في الجداول هي العثور على المجموع الإجمالي للقيم المختلفة. أول ما يتبادر إلى الذهن هو إضافة كل خلية واحدة ذات أهمية:

=E2+E4+E8+E13

لكن هذه الصيغة ستصبح مضيعة للوقت للغاية إذا كان هناك عدد كبير جدًا من الخلايا التي يجب أخذها في الاعتبار.

الطريقة الصحيحة لإضافة خلايا هي استخدام وظيفة جداول بيانات Google الخاصة - SUM - التي تسرد جميع الخلايا تلقائيًا باستخدام الفواصل:

=SUM(E2,E4,E8,E13)

إذا كان النطاق يتكون من خلايا متجاورة ، ما عليك سوى الإشارة إلى الخلايا الأولى والأخيرة حتى إذا كانت هناك خلايا فارغة في مكان ما بينهما. وبالتالي ، ستتجنب تعداد كل خلية في صيغة جداول بيانات Google SUM.

نصيحة. هناك طريقة أخرى لإضافة SUM وهي تحديد العمود الذي يحتوي على أرقام واختيار SUM ضمن رمز الصيغ :

يتم إدراجها في خلية أسفل النطاق المحدد مباشرةً.

نصيحة. تحتوي أدواتنا الكهربائية على ميزة "جمع تلقائي". نقرة واحدة - وستقوم الخلية النشطة بإرجاع مجموع القيم من العمود بأكمله أعلاه.

اسمحوا لي أن أعقد المهمة. أريد إضافة أرقام من نطاقات بيانات مختلفة على أوراق متعددة ، على سبيل المثال ، A4: A8 من Sheet1 و B4: B7 من الورقة 2 . وأريد تلخيصهاخلية واحدة:

=SUM('Sheet1'!A4:A8,'Sheet2'!B4:B7)

كما ترون ، لقد أضفت للتو ورقة أخرى إلى صيغة Google Sheets SUM وفصلت نطاقين مختلفين بفاصلة.

النسبة المئوية للصيغ

كثيرًا ما أسمع الناس يسألون عن إيجاد النسبة المئوية للمجموعات المختلفة. يتم حساب هذا عادةً بواسطة صيغة النسبة المئوية لجداول بيانات Google مثل:

نفس الشيء يعمل أيضًا عندما تحتاج إلى التحقق من الجزء الذي يمثله هذا الرقم أو ذاك من الإجمالي:

نصيحة. نسبة الماجستير من إجمالي وإجمالي & أمبير ؛ المبلغ بالنسبة المئوية ، زيادته & أمبير ؛ انخفاض في هذا البرنامج التعليمي.

في الجدول الخاص بي حيث احتفظ بسجلات لجميع المبيعات خلال الأيام العشرة الماضية ، يمكنني حساب النسبة المئوية لكل عملية بيع من إجمالي المبيعات.

أولاً ، أذهب إلى E12 والعثور على إجمالي المبيعات:

=SUM(E2:E11)

ثم ، تحقق من الجزء الذي تشكل مبيعات اليوم الأول من الإجمالي في F2:

=E2/$E$12

أوصي بإجراء بعض التعديلات أيضًا:

1. أدر E2 إلى مرجع مطلق - $ E $ 12 - للتأكد من تقسيم مبيعات كل يوم بنفس المجموع.
2. تطبيق تنسيق النسبة المئوية على الخلايا في العمود F.
3. انسخ الصيغة من F2 إلى جميع الخلايا أدناه - حتى F11.

نصيحة. لنسخ الصيغة ، استخدم إحدى الطرق التي ذكرتها سابقًا.

نصيحة. للتأكد من صحة حساباتك ، أدخل العملية أدناه إلى F12:

=SUM(F2:F11 )

إذا كانت تُرجع 100٪ -كل شيء صحيح.

لماذا أوصي باستخدام تنسيق النسبة المئوية؟

حسنًا ، من ناحية ، لتجنب ضرب كل نتيجة في 100 إذا كنت ترغب في الحصول على النسب المئوية. من ناحية أخرى ، لتجنب تقسيم النتائج على 100 إذا كنت تريد استخدامها في أي عمليات حسابية أخرى غير النسبة المئوية.

هذا ما أعنيه:

أستخدم تنسيق رقم النسبة المئوية في الخلايا C4 و B10 و B15. جميع صيغ جداول بيانات Google التي تشير إلى هذه الخلايا أسهل بكثير. لست مضطرًا للقسمة على 100 أو إضافة رمز النسبة المئوية (٪) إلى الصيغ في C10 و C15.

لا يمكن قول الشيء نفسه عن C8 و C9 و C14. يجب أن أقوم بإجراء هذه التعديلات الإضافية للحصول على النتيجة الصحيحة.

صيغ الصفيف

للعمل مع الكثير من البيانات في جداول بيانات Google ، يتم استخدام الوظائف المتداخلة وغيرها من العمليات الحسابية الأكثر تعقيدًا كقاعدة. توجد صيغ الصفيف في جداول بيانات Google لهذا الغرض أيضًا.

على سبيل المثال ، لدي جدول مبيعات لكل عميل. أشعر بالفضول للعثور على الحد الأقصى للبيع من شوكولاتة الحليب إلى سميث للتحقق مما إذا كان بإمكاني منحه خصمًا إضافيًا في المرة القادمة. أستخدم صيغة الصفيف التالية في E18:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith")*($C$2:$C$13="Milk Chocolate"),$E$2:$E$13,"")))

ملاحظة. لإنهاء أي صيغة مصفوفة في جداول بيانات Google ، اضغط على Ctrl + Shift + Enter بدلاً من مجرد إدخال.

لقد حصلت على 259 دولارًا نتيجة لذلك.

تعرض أول صيغة مصفوفة في E16 الحد الأقصى للشراء الذي قام به Smith - 366 دولارًا:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith"),$E$2:$E$13)))

E17 تظهر الحد الأقصىالأموال التي يتم إنفاقها على شوكولاتة الحليب - 518 دولارًا:

=ArrayFormula(MAX(IF(($C$2:$C$13="Milk Chocolate"),$E$2:$E$13)))

الآن ، سأستبدل جميع القيم المستخدمة في صيغ جداول بيانات Google بمراجع الخلايا الخاصة بها:

هل لاحظت ما الذي تغير؟

=ArrayFormula(MAX(IF(($B$2:$B$13=B18)*($C$2:$C$13=C18),$E$2:$E$13,"")))

هذا ما كان لدي من قبل:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith")*($C$2:$C$13="Milk Chocolate"),$E$2:$E$13,"")))

تمامًا مثل هذا ، شعوذة باستخدام القيم الموجودة في الخلايا التي تشير إليها ، يمكنك الحصول بسرعة على نتائج مختلفة بناءً على ظروف مختلفة دون تغيير الصيغة نفسها.

صيغ جداول بيانات Google للاستخدام اليومي

دعونا نلقي نظرة على بعض الوظائف الأخرى و أمثلة الصيغ مفيدة للاستخدام اليومي.

المثال 1

افترض أن بياناتك مكتوبة جزئيًا كأرقام وجزئيًا كنص: 300 يورو ، المجموع - 400 دولار . لكنك تحتاج إلى استخراج الأرقام فقط.

أعرف وظيفة فقط لذلك:

يسحب النص عن طريق القناع بتعبير عادي.

• نص - يمكن أن يكون مرجعًا للخلية أو أي نص في علامتي اقتباس مزدوجتين.
• تعبيرات عادية - قناع النص الخاص بك. أيضا في اقتباسات مزدوجة. يتيح لك إنشاء أي مخطط نصي ممكن تقريبًا.

النص في حالتي هو خلية بها بيانات ( A2 ). وأنا أستخدم هذا التعبير النمطي: [0-9] +

وهذا يعني أنني أبحث عن أي كمية ( + ) من الأرقام من 0 إلى 9 ( [0-9] ) مكتوبًا واحدًا تلو الآخر:

إذا كانت الأرقام تحتوي على كسور ، فسيبدو التعبير العادي كما يلي:

"[0-9]*\.[0-9]+[0-9]+" من أجلأرقام ذات منزلتين عشريتين

"[0-9]*\.[0-9]+" للأرقام ذات منزلة عشرية واحدة

ملاحظة. ترى "جداول بيانات Google" القيم المستخرجة كنص. تحتاج إلى تحويلها إلى أرقام باستخدام وظيفة VALUE أو باستخدام أداة التحويل الخاصة بنا.

مثال 2 - ربط النص بصيغة

تساعد الصيغ داخل النص في الحصول على صف أنيق مع بعض الإجماليات - أرقام بأوصافها القصيرة.

سأقوم بإنشاء مثل هذه الصفوف في السطور 14 و 15. للبدء ، أقوم بدمج الخلايا في تلك الصفوف عبر Format & gt؛ ادمج الخلايا ثم احسب مجموع العمود E:

=SUM(E2:E13)

ثم أضع النص الذي أرغب في الحصول عليه كوصف لمضاعفة علامات الاقتباس ودمجها مع الصيغة باستخدام علامة العطف:

="Total chocolate sales: "&SUM(E2:E13)&" dollars"

لجعل أرقامي أرقامًا عشرية ، أستخدم وظيفة TEXT وقم بتعيين التنسيق: "# ، ## 0 "

هناك طريقة أخرى وهي استخدام وظيفة CONCATENATE الخاصة بجداول بيانات Google ، كما استخدمتها في A15:

=CONCATENATE("Total discount for customers: ",TEXT(SUM(F2:F13),"#.##")," dollars")

مثال 3

ماذا لو تقوم بتحميل البيانات من مكان ما وتظهر جميع الأرقام بمسافات ، مثل 8 544 بدلاً من 8544 ؟ ستعرض "جداول بيانات Google" هذه القيم كنص ، كما تعلم.

إليك كيفية تحويل هذه القيم المكتوبة كنص إلى "أرقام عادية":

=VALUE(SUBSTITUTE("8 544"," ",""))

أو

=VALUE(SUBSTITUTE(A2," ",""))

حيث يحتوي A2 على 8544 .

كيف يعمل؟ تستبدل الدالة SUBSTITUTE جميع المسافات في النص (تحقق من الوسيطة الثانية - هناك مسافة بين علامتي الاقتباس) بـ "فارغstring "(الوسيطة الثالثة). بعد ذلك ، VALUE يحول النص إلى أرقام.

مثال 4

هناك بعض وظائف جداول بيانات Google التي تساعد في معالجة النص في جداول البيانات الخاصة بك ، على سبيل المثال ، قم بتغيير الحالة إلى حالة الجملة. إذا كان لديك شيء غريب مثل soURcE dAtA ، يمكنك الحصول على بيانات المصدر بدلاً من ذلك:

دعني أوضح هذا بالتفصيل. آخذ الحرف الأول في الخلية:

=LEFT(A1,1)

وتبديله إلى الحالة العلوية:

=UPPER(LEFT(A1,1))

ثم آخذ النص المتبقي:

=RIGHT(A1,LEN(A1)-1)

وإجباره في حالة الأحرف الصغيرة:

=LOWER(RIGHT(A1,LEN(A1)-1))

أخيرًا ، أحضر جميع أجزاء الصيغة مع علامة العطف :

=UPPER(LEFT(A1,1))&LOWER(RIGHT(A1,LEN(A1)-1))

نصيحة. يمكنك التبديل بين الحالات بنقرة واحدة باستخدام الأداة المساعدة المقابلة من أدواتنا القوية.

بالطبع ، هناك الكثير لتقدمه "جداول بيانات Google". كن خائفًا من الصيغ المعقدة المختلفة - فقط جرب وجرب. بعد كل شيء ، تتيح لنا مجموعة الأدوات هذه حل العديد من المهام المختلفة. حظًا سعيدًا! :)