Sigblaaie bied 'n wonderlike platform om datatabelle te bestuur. Maar is daar enige maklike Google Sheets-funksies vir daaglikse berekeninge? Vind uit hieronder.

Google Sheets SUM-funksie

Ek glo die mees vereiste bewerking in tabelle is om die totale som van verskillende waardes te vind. Die eerste ding wat by jou opkom, is om elke enkele sel van belang by te voeg:

=E2+E4+E8+E13

Maar hierdie formule sal uiters tydrowend raak as daar te veel selle is om in ag te neem.

Die regte manier om selle by te voeg, is om 'n spesiale Google Sheets-funksie – SUM – te gebruik wat alle selle outomaties lys deur kommas te gebruik:

=SUM(E2,E4,E8,E13)

As die reeks uit aangrensende selle bestaan , dui eenvoudig sy eerste en laaste selle aan, selfs al is daar leë selle iewers tussen. Jy sal dus vermy om elke sel in Google Blaaie SUM-formule op te noem.

Wenk. Nog 'n manier om SOM by te voeg, is om die kolom met getalle te kies en SOM onder die Formules -ikoon te kies:

Die resultaat sal in 'n sel reg onder die geselekteerde reeks ingevoeg word.

Wenk. Ons kraggereedskap het 'n AutoSum-funksie. Een klik – en jou aktiewe sel sal die som van waardes uit die hele kolom hierbo terugstuur.

Laat ek die taak kompliseer. Ek wil nommers van verskillende datareekse op veelvuldige velle byvoeg, byvoorbeeld A4:A8 vanaf Blad1 en B4:B7 vanaf Blad2 . En ek wil hulle opsom'n enkele sel:

=SUM('Sheet1'!A4:A8,'Sheet2'!B4:B7)

Soos jy kan sien, het ek net nog een blad by Google Blaaie SUM-formule gevoeg en twee verskillende reekse met 'n komma geskei.

Persentasieformules

Ek hoor dikwels mense vra oor die vind van die persentasie van verskillende totale. Dit word gewoonlik deur die Google Blaaie-persentasieformule soos volg bereken:

Dieselfde werk ook wanneer jy moet kyk watter deel hierdie of daardie getal van die totaal verteenwoordig:

Wenk. Meester persentasie van 'n totaal, totaal & amp; bedrag deur persent, sy verhoging & amp; afname in hierdie tutoriaal.

In my tabel waar ek rekord hou van alle verkope vir die afgelope 10 dae, kan ek die persentasie van elke verkope uit die totale verkope bereken.

Eers gaan ek na E12 en vind totale verkope:

=SUM(E2:E11)

Dan kyk ek watter deel die eerste dagverkope van die totaal in F2 uitmaak:

=E2/$E$12

Ek beveel aan om ook 'n paar aanpassings te maak:

1. Draai E2 na 'n absolute verwysing – $E$12 – om seker te maak jy verdeel elke dag se uitverkoping met dieselfde totaal.
2. Pas die persentasiegetalformaat toe op selle in kolom F.
3. Kopieer die formule van F2 na alle selle hieronder – tot en met F11.

Wenk. Om die formule te kopieer, gebruik een van die maniere wat ek vroeër genoem het.

Wenk. Om seker te maak jou berekeninge is korrek, voer die onderstaande een in na F12:

=SUM(F2:F11 )

As dit 100% gee –alles is korrek.

Hoekom beveel ek aan om die persentasieformaat te gebruik?

Wel, aan die een kant, om te verhoed dat elke resultaat met 100 vermenigvuldig word as jy wil kry persente. Aan die ander kant, om te verhoed dat die resultate na 100 verdeel word as jy dit vir enige verdere nie-persent wiskundige bewerkings wil gebruik.

Hier is wat ek bedoel:

Ek gebruik die persentasiegetalformaat in selle C4, B10 en B15. Alle Google Blaaie-formules wat na hierdie selle verwys, is baie makliker. Ek hoef nie deur 100 te deel of die persentasiesimbool (%) by formules in C10 en C15 by te voeg nie.

Dieselfde kan nie oor C8, C9 en C14 gesê word nie. Ek moet hierdie ekstra aanpassings maak om die korrekte resultaat te kry.

Skikkingsformules

Om met hope data in Google Sheets te werk, word geneste funksies en ander meer ingewikkelde berekeninge as 'n reël gebruik. Skikkingsformules is ook daar in Google Blaaie vir daardie doel.

Ek het byvoorbeeld 'n tabel van verkope per kliënt. Ek is nuuskierig om die maksimum verkope van melksjokolade aan Smith te vind om te kyk of ek hom volgende keer 'n ekstra afslag kan gee. Ek gebruik die volgende skikkingsformule in E18:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith")*($C$2:$C$13="Milk Chocolate"),$E$2:$E$13,"")))

Let wel. Om enige skikkingsformule in Google Blaaie te voltooi, druk Ctrl+Shift+Enter eerder as net Enter.

Ek het $259 as gevolg.

My eerste skikkingsformule in E16 gee die maksimum aankoop wat Smith gemaak het terug – $366:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith"),$E$2:$E$13)))

E17 wys die maksimumgeld spandeer vir melksjokolade – $518:

=ArrayFormula(MAX(IF(($C$2:$C$13="Milk Chocolate"),$E$2:$E$13)))

Nou gaan ek alle waardes wat in Google Blaaie-formules gebruik word vervang met hul selverwysings:

Het jy opgelet wat verander het?

=ArrayFormula(MAX(IF(($B$2:$B$13=B18)*($C$2:$C$13=C18),$E$2:$E$13,"")))

Hier is wat ek voorheen gehad het:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith")*($C$2:$C$13="Milk Chocolate"),$E$2:$E$13,"")))

Net so, jongleren met waardes in selle waarna jy verwys, kan jy vinnig verskillende resultate kry op grond van verskillende toestande sonder om die formule self te verander.

Google Blaaie-formules vir daaglikse gebruik

Kom ons kyk na nog 'n paar funksies en formules voorbeelde handig vir alledaagse gebruik.

Voorbeeld 1

Gestel jou data word deels as syfers en deels as teks geskryf: 300 euro , totaal – 400 dollar . Maar jy hoef net getalle te onttrek.

Ek ken net 'n funksie daarvoor:

Dit trek die teks per masker met 'n gereelde uitdrukking.

• teks – dit kan selverwysing of enige teks in dubbele aanhalings wees.
• reëlmatige_uitdrukking – jou teksmasker. Ook in dubbele aanhalingstekens. Dit laat jou byna enige moontlike teksskema skep.

Die teks in my geval is 'n sel met 'n data ( A2 ). En ek gebruik hierdie gereelde uitdrukking: [0-9]+

Dit beteken dat ek op soek is na enige hoeveelheid ( + ) getalle van 0 tot 9 ( [0-9] ) een na die ander geskryf:

As getalle breuke het, sal die gewone uitdrukking soos volg lyk:

"[0-9]*\.[0-9]+[0-9]+" virgetalle met twee desimale plekke

"[0-9]*\.[0-9]+" vir getalle met een desimale plek

Let wel. Google Blaaie sien die uitgehaalde waardes as teks. Jy moet dit omskakel na getalle met die VALUE-funksie of met ons Skakel-nutsding.

Voorbeeld 2 – voeg teks saam met 'n formule

Formules binne die teks help om 'n netjiese ry met 'n paar totale te kry – getalle met hul kort beskrywings.

Ek gaan sulke rye in reël 14 en 15 skep. Om mee te begin, voeg ek selle in daardie rye saam via Format > Voeg selle saam en tel dan die som vir kolom E:

=SUM(E2:E13)

Dan sit ek die teks wat ek graag as beskrywing wil hê by dubbele aanhalingstekens en kombineer dit met die formule gebruik 'n ampersand:

="Total chocolate sales: "&SUM(E2:E13)&" dollars"

Om my getalle desimale te maak, gebruik ek die TEXT-funksie en stel die formaat: "#,## 0"

'n Ander manier is om Google Sheets CONCATENATE-funksie te gebruik, soos ek in A15 gebruik het:

=CONCATENATE("Total discount for customers: ",TEXT(SUM(F2:F13),"#.##")," dollars")

Voorbeeld 3

Wat as jy laai die data van iewers af en alle getalle verskyn met spasies, soos 8 544 in plaas van 8544 ? Google Blaaie sal dit as teks terugstuur, jy weet.

Hier is hoe om hierdie waardes wat as teks geskryf is na "normale getalle" te verander:

=VALUE(SUBSTITUTE("8 544"," ",""))

of

=VALUE(SUBSTITUTE(A2," ",""))

waar A2 8 544 bevat.

Hoe werk dit? Die PLAASVERVANG-funksie vervang alle spasies in die teks (kyk die tweede argument – ​​daar is spasie in dubbele aanhalingstekens) met 'n "leegstring" (die derde argument). VALUE skakel dan teks na getalle om.

Voorbeeld 4

Daar is 'n paar Google Blaaie-funksies wat help om teks in jou sigblaaie te manipuleer, byvoorbeeld, verander die hoofletters na sinkas. As jy iets vreemd soos BRONDATA het, kan jy eerder Brondata kry:

Kom ek verduidelik dit in detail.Ek neem die eerste karakter in 'n sel:

=LEFT(A1,1)

en skakel dit oor na die hoofletter:

=UPPER(LEFT(A1,1))

Dan neem ek die oorblywende teks:

=RIGHT(A1,LEN(A1)-1)

en forseer dit in kleinletters:

=LOWER(RIGHT(A1,LEN(A1)-1))

Laastens bring ek alle stukke van die formule saam met 'n ampersand :

=UPPER(LEFT(A1,1))&LOWER(RIGHT(A1,LEN(A1)-1))

Wenk. Jy kan met 'n klik tussen gevalle wissel met die ooreenstemmende nutsmiddel van ons kragnutsgoed.

Natuurlik is daar baie meer wat Google Sheets kan bied. Moenie' nie bang wees vir verskillende komplekse formules nie – probeer net en eksperimenteer. Hierdie gereedskapstelle laat ons immers baie verskillende take oplos. Sterkte! :)