Nag-aalok ang mga spreadsheet ng mahusay na platform upang pamahalaan ang mga talahanayan ng data. Ngunit mayroon bang anumang madaling paggana ng Google Sheets para sa pang-araw-araw na pagkalkula? Alamin sa ibaba.

Google Sheets SUM function

Naniniwala ako na ang pinakakinakailangang operasyon sa mga talahanayan ay upang mahanap ang kabuuang kabuuan ng iba't ibang mga halaga. Ang unang bagay na papasok sa isip ay idagdag ang bawat solong cell ng interes:

=E2+E4+E8+E13

Ngunit ang formula na ito ay magiging lubhang matagal kung mayroong masyadong maraming mga cell na dapat isaalang-alang.

Ang wastong paraan upang magdagdag ng mga cell ay ang paggamit ng isang espesyal na function ng Google Sheets – SUM – na awtomatikong naglilista ng lahat ng mga cell gamit ang mga kuwit:

=SUM(E2,E4,E8,E13)

Kung ang hanay ay binubuo ng mga katabing cell , ipahiwatig lamang ang una at huling mga cell nito kahit na may mga blangko sa pagitan. Kaya, maiiwasan mo ang pag-enumerate ng bawat cell sa Google Sheets SUM formula.

Tip. Ang isa pang paraan upang magdagdag ng SUM ay ang piliin ang column na may mga numero at piliin ang SUM sa ilalim ng icon na Formulas :

Ang resulta ay ipasok sa isang cell sa ibaba mismo ng napiling hanay.

Tip. Ang aming Power Tools ay may tampok na AutoSum. Isang pag-click – at ibabalik ng iyong aktibong cell ang kabuuan ng mga halaga mula sa buong column sa itaas.

Hayaan akong gawing kumplikado ang gawain. Gusto kong magdagdag ng mga numero mula sa iba't ibang hanay ng data sa maraming sheet, halimbawa, A4:A8 mula sa Sheet1 at B4:B7 mula sa Sheet2 . At gusto kong isama ang mga itoisang cell:

=SUM('Sheet1'!A4:A8,'Sheet2'!B4:B7)

Tulad ng nakikita mo, nagdagdag lang ako ng isa pang sheet sa Google Sheets SUM formula at pinaghiwalay ang dalawang magkaibang hanay sa pamamagitan ng kuwit.

Mga formula ng porsyento

Madalas kong marinig ang mga taong nagtatanong tungkol sa paghahanap ng porsyento ng iba't ibang kabuuan. Karaniwan itong kinakalkula ng Google Sheets percentage formula tulad nito:

Ginagana din ito sa tuwing kailangan mong tingnan kung anong bahagi nito o ang numerong iyon ang kumakatawan sa kabuuan:

Tip. Master na porsyento ng kabuuan, kabuuang & halaga ayon sa porsyento, ang pagtaas nito & bumaba sa tutorial na ito.

Sa aking talahanayan kung saan nag-iingat ako ng mga talaan ng lahat ng mga benta sa nakalipas na 10 araw, maaari kong kalkulahin ang porsyento ng bawat benta mula sa kabuuang mga benta.

Una, pupunta ako sa E12 at hanapin ang kabuuang benta:

=SUM(E2:E11)

Pagkatapos, tinitingnan ko kung anong bahagi ng unang araw na benta ang bumubuo sa kabuuan sa F2:

=E2/$E$12

Inirerekomenda kong gumawa din ng ilang pagsasaayos:

1. I-on ang E2 sa isang ganap na sanggunian – $E$12 – upang matiyak na hahatiin mo ang bawat araw na benta sa parehong kabuuan.
2. Ilapat ang format ng porsyento ng numero sa mga cell sa column F.
3. Kopyahin ang formula mula sa F2 sa lahat ng mga cell sa ibaba – hanggang F11.

Tip. Upang kopyahin ang formula, gamitin ang isa sa mga paraan na nabanggit ko kanina.

Tip. Upang matiyak na tama ang iyong mga kalkulasyon, ilagay ang nasa ibaba sa F12:

=SUM(F2:F11 )

Kung ito ay bumalik ng 100% –tama ang lahat.

Bakit ko inirerekomenda ang paggamit ng format na porsyento?

Buweno, sa isang banda, upang maiwasan ang pagpaparami ng bawat resulta ng 100 kung gusto mong makakuha porsyento. Sa kabilang banda, upang maiwasang hatiin ang mga resulta sa 100 kung gusto mong gamitin ang mga ito para sa anumang karagdagang hindi-porsiyento na mga operasyon sa matematika.

Narito ang ibig kong sabihin:

Ginagamit ko ang format ng numero ng porsyento sa mga cell C4, B10, at B15. Ang lahat ng mga formula ng Google Sheets na tumutukoy sa mga cell na ito ay mas madali. Hindi ko kailangang hatiin sa 100 o idagdag ang simbolo ng porsyento (%) sa mga formula sa C10 at C15.

Hindi rin masasabi ang parehong tungkol sa C8, C9, at C14. Dapat kong gawin ang mga karagdagang pagsasaayos na ito upang makuha ang tamang resulta.

Mga array formula

Para gumana sa maraming data sa Google Sheets, ginagamit ang mga nested function at iba pang mas kumplikadong kalkulasyon bilang panuntunan. Ang mga array formula ay naroon din sa Google Sheets para sa layuning iyon.

Halimbawa, mayroon akong talaan ng mga benta bawat kliyente. Curious akong hanapin ang maximum sale ng milk chocolate kay Smith para tingnan kung mabibigyan ko siya ng dagdag na diskwento sa susunod. Ginagamit ko ang susunod na array formula sa E18:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith")*($C$2:$C$13="Milk Chocolate"),$E$2:$E$13,"")))

Tandaan. Upang tapusin ang anumang array formula sa Google Sheets, pindutin ang Ctrl+Shift+Enter sa halip na Enter lang.

Mayroon akong $259 bilang resulta.

Ibinabalik ng aking unang array formula sa E16 ang maximum na pagbiling ginawa ni Smith – $366:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith"),$E$2:$E$13)))

E17 ipakita ang maximumperang ginastos para sa milk chocolate – $518:

=ArrayFormula(MAX(IF(($C$2:$C$13="Milk Chocolate"),$E$2:$E$13)))

Ngayon, papalitan ko ang lahat ng value na ginamit sa mga formula ng Google Sheets ng kanilang mga cell reference:

Napansin mo ba kung ano ang nagbago?

=ArrayFormula(MAX(IF(($B$2:$B$13=B18)*($C$2:$C$13=C18),$E$2:$E$13,"")))

Narito ang mayroon ako noon:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith")*($C$2:$C$13="Milk Chocolate"),$E$2:$E$13,"")))

Ganito lang, juggling na may mga value sa mga cell na iyong tinutukoy ay mabilis kang makakakuha ng iba't ibang resulta batay sa iba't ibang kundisyon nang hindi binabago ang mismong formula.

Mga formula ng Google Sheets para sa pang-araw-araw na paggamit

Tingnan natin ang ilan pang mga function at mga halimbawa ng formula na madaling gamitin para sa pang-araw-araw na paggamit.

Halimbawa 1

Ipagpalagay na ang iyong data ay isinulat nang bahagya bilang mga numero at bahagyang bilang text: 300 euros , kabuuan – 400 dolyar . Ngunit kailangan mo lang mag-extract ng mga numero.

May alam akong function para doon:

Hinihila nito ang text sa pamamagitan ng mask na may regular na expression.

• text – maaari itong maging cell reference o anumang text na may double quotes.
• regular_expression – ang iyong text mask. Gayundin sa double quotes. Hinahayaan ka nitong lumikha ng halos anumang text scheme na posible.

Ang text sa aking kaso ay isang cell na may data ( A2 ). At ginagamit ko ang regular na expression na ito: [0-9]+

Ibig sabihin ay naghahanap ako ng anumang dami ( + ) ng mga numero mula 0 hanggang 9 ( [0-9] ) nakasulat nang sunud-sunod:

Kung may mga fraction ang mga numero, magiging ganito ang hitsura ng regular na expression:

"[0-9]*\.[0-9]+[0-9]+" para samga numerong may dalawang decimal na lugar

"[0-9]*\.[0-9]+" para sa mga numerong may isang decimal na lugar

Tandaan. Nakikita ng Google Sheets ang mga nakuhang value bilang text. Kailangan mong i-convert ang mga ito sa mga numero na may function na VALUE o gamit ang aming Convert tool.

Halimbawa 2 – pagsama-samahin ang text gamit ang isang formula

Ang mga formula sa loob ng text ay tumutulong sa pagkuha ng maayos na hitsura na row na may ilang kabuuan – mga numero na may maiikling paglalarawan ng mga ito.

Gumagawa ako ng mga ganoong row sa mga linya 14 at 15. Upang magsimula, pinagsasama ko ang mga cell sa mga row na iyon sa pamamagitan ng Format > Pagsamahin ang mga cell at pagkatapos ay bilangin ang kabuuan para sa column E:

=SUM(E2:E13)

Pagkatapos ay inilagay ko ang text na gusto kong magkaroon bilang isang paglalarawan upang i-double quotes at pagsamahin ito sa formula gamit ang isang ampersand:

="Total chocolate sales: "&SUM(E2:E13)&" dollars"

Upang gawing mga desimal ang aking mga numero, ginagamit ko ang TEXT function at itinakda ang format: "#,## 0"

Ang isa pang paraan ay ang paggamit ng Google Sheets CONCATENATE function, tulad ng ginamit ko sa A15:

=CONCATENATE("Total discount for customers: ",TEXT(SUM(F2:F13),"#.##")," dollars")

Halimbawa 3

Paano kung ina-upload mo ang data mula sa kung saan at lumilitaw ang lahat ng numero na may mga puwang, tulad ng 8 544 sa halip na 8544 ? Ibabalik ito ng Google Sheets bilang text, alam mo na.

Narito kung paano gawing "normal na mga numero" ang mga value na ito na nakasulat bilang text:

=VALUE(SUBSTITUTE("8 544"," ",""))

o

=VALUE(SUBSTITUTE(A2," ",""))

kung saan naglalaman ang A2 ng 8 544 .

Paano ito gumagana? Pinapalitan ng SUBSTITUTE function ang lahat ng puwang sa text (suriin ang pangalawang argumento – mayroong puwang sa double-quotes) na may "emptystring" (ang ikatlong argumento). Pagkatapos, ang VALUE ay nagko-convert ng text sa mga numero.

Halimbawa 4

May ilang mga function ng Google Sheets na tumutulong sa pagmamanipula ng text sa iyong mga spreadsheet, halimbawa, baguhin ang case sa sentence case. Kung mayroon kang kakaiba tulad ng soURcE dAtA , maaari kang makakuha ng Source data sa halip:

Hayaan akong ipaliwanag na detalyado. Kinukuha ko ang unang character sa isang cell:

=LEFT(A1,1)

at inilipat ito sa upper case:

=UPPER(LEFT(A1,1))

Pagkatapos ay kinuha ko ang natitirang text:

=RIGHT(A1,LEN(A1)-1)

at pilitin ito sa lower case:

=LOWER(RIGHT(A1,LEN(A1)-1))

Panghuli, dinadala ko ang lahat ng piraso ng formula kasama ng ampersand :

=UPPER(LEFT(A1,1))&LOWER(RIGHT(A1,LEN(A1)-1))

Tip. Maaari kang magpalipat-lipat sa mga kaso sa isang pag-click gamit ang kaukulang utility mula sa aming Power Tools.

Siyempre, marami pang maiaalok ang Google Sheets. Huwag' huwag matakot sa iba't ibang kumplikadong mga formula – subukan lang at mag-eksperimento. Pagkatapos ng lahat, ang mga toolset na ito ay nagbibigay-daan sa amin upang malutas ang maraming iba't ibang mga gawain. Good luck! :)