As follas de cálculo ofrecen unha excelente plataforma para xestionar táboas de datos. Pero hai funcións fáciles de Google Sheets para os cálculos diarios? Descúbreo a continuación.

Función SUMA de Google Sheets

Creo que a operación máis necesaria nas táboas é atopar a suma total de diferentes valores. O primeiro que se me ocorre é engadir todas as celas de interese:

=E2+E4+E8+E13

Pero esta fórmula levará moito tempo se hai demasiadas celas para ter en conta.

A forma correcta de engadir celas é usar unha función especial de Follas de cálculo de Google - SUMA - que enumera todas as celas automaticamente usando comas:

=SUM(E2,E4,E8,E13)

Se o intervalo consta de celas adxacentes , simplemente indique a súa primeira e a súa última cela aínda que haxa outras en branco nalgún lugar no medio. Así, evitarás enumerar todas e cada unha das celas na fórmula SUMA de Google Sheets.

Consello. Outra forma de engadir SUMA é seleccionar a columna con números e escoller SUMA baixo a icona Fórmulas :

O resultado será inserirase nunha cela xusto debaixo do intervalo seleccionado.

Consello. As nosas ferramentas eléctricas teñen unha función AutoSum. Un clic e a túa cela activa devolverá a suma dos valores de toda a columna anterior.

Déixame complicar a tarefa. Quero engadir números de diferentes intervalos de datos en varias follas, por exemplo, A4:A8 de Folla1 e B4:B7 de Folla2 . E quero resumilosunha única cela:

=SUM('Sheet1'!A4:A8,'Sheet2'!B4:B7)

Como podes ver, acabo de engadir unha folla máis á fórmula SUMA de Google Sheets e separei dous intervalos diferentes mediante unha coma.

Fórmulas de porcentaxes

A miúdo escoito a xente preguntar sobre como atopar a porcentaxe de diferentes totais. Normalmente calcúlase coa fórmula de porcentaxes de Google Sheets como esta:

O mesmo funciona sempre que necesites comprobar que parte representa este ou aquel número do total:

Consello. Porcentaxe principal dun total, total & cantidade por cento, o seu aumento & diminución neste titorial.

Na miña táboa na que gardo rexistros de todas as vendas dos últimos 10 días, podo calcular a porcentaxe de cada venda sobre as vendas totais.

En primeiro lugar, vou a E12 e atopar as vendas totais:

=SUM(E2:E11)

Entón, comprobo que parte das vendas do primeiro día constitúen do total en F2:

=E2/$E$12

Recomendo tamén facer algúns axustes:

1. Xira E2 a unha referencia absoluta - $E$12 - para asegurarte de dividir a venda de cada día polo mesmo total.
2. Aplica o formato de número porcentual ás celas da columna F.
3. Copia a fórmula de F2 a todas as celas de abaixo, ata F11.

Consello. Para copiar a fórmula, use unha das formas que mencionei anteriormente.

Consello. Para asegurarte de que os teus cálculos son correctos, introduce o seguinte en F12:

=SUM(F2:F11 )

Se devolve o 100 % -todo é correcto.

Por que recomendo usar o formato porcentual?

Ben, por unha banda, para evitar multiplicar cada resultado por 100 se queres obter porcentaxes. Por outra banda, para evitar dividir os resultados a 100 se queres usalos para outras operacións matemáticas que non sexan porcentuais.

Isto é o que quero dicir:

Eu uso o formato de número de porcentaxe nas celas C4, B10 e B15. Todas as fórmulas de Google Sheets que fan referencia a estas celas son moito máis sinxelas. Non teño que dividir por 100 nin engadir o símbolo de porcentaxe (%) ás fórmulas en C10 e C15.

Non se pode dicir o mesmo sobre C8, C9 e C14. Debo facer estes axustes adicionais para obter o resultado correcto.

Fórmulas de matriz

Para traballar con moitos datos en Follas de cálculo de Google, utilízanse funcións aniñadas e outros cálculos máis complicados como regra. Tamén hai fórmulas de matriz en Follas de cálculo de Google para ese fin.

Por exemplo, teño unha táboa de vendas por cliente. Teño curiosidade por atopar a venda máxima de chocolate con leite a Smith para comprobar se podo facerlle un desconto extra a próxima vez. Eu uso a seguinte fórmula matricial en E18:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith")*($C$2:$C$13="Milk Chocolate"),$E$2:$E$13,"")))

Nota. Para rematar calquera fórmula matricial en Follas de cálculo de Google, preme Ctrl+Maiús+Intro en lugar de simplemente Intro.

Conseguín $259 como resultado.

A miña primeira fórmula matricial en E16 devolve a compra máxima realizada por Smith: $366:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith"),$E$2:$E$13)))

E17 mostra o máximodiñeiro gastado en chocolate con leite: 518 $:

=ArrayFormula(MAX(IF(($C$2:$C$13="Milk Chocolate"),$E$2:$E$13)))

Agora, vou substituír todos os valores utilizados nas fórmulas de Follas de cálculo de Google polas súas referencias de cela:

Observaches o que cambiou?

=ArrayFormula(MAX(IF(($B$2:$B$13=B18)*($C$2:$C$13=C18),$E$2:$E$13,"")))

Aquí está o que tiña antes:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith")*($C$2:$C$13="Milk Chocolate"),$E$2:$E$13,"")))

Así, malabares cos valores das celas ás que fai referencia, pode obter rapidamente resultados diferentes en función de diferentes condicións sen cambiar a propia fórmula.

Fórmulas de Follas de cálculo de Google para uso diario

Vexamos algunhas funcións máis e exemplos de fórmulas útiles para o uso diario.

Exemplo 1

Supoñamos que os teus datos se escriben en parte como números e en parte como texto: 300 euros , total – 400 dólares . Pero só precisa extraer números.

Coñezo só unha función para iso:

Extrae o texto por máscara cunha expresión regular.

• texto : pode ser unha referencia de cela ou calquera texto entre comiñas dobres.
• expresión_regular : a máscara de texto. Tamén entre comiñas dobres. Permíteche crear case calquera esquema de texto posible.

O texto no meu caso é unha cela cun dato ( A2 ). E uso esta expresión regular: [0-9]+

Significa que estou buscando calquera cantidade ( + ) de números do 0 ao 9 ( [0-9] ) escritos un despois do outro:

Se os números teñen fraccións, a expresión regular terá o seguinte aspecto:

"[0-9]*\.[0-9]+[0-9]+" paranúmeros con dúas cifras decimais

"[0-9]*\.[0-9]+" para números cun decimal

Nota. Follas de cálculo de Google ve os valores extraídos como texto. Debes convertelos en números coa función VALOR ou coa nosa ferramenta Converter.

Exemplo 2: concatenar texto cunha fórmula

As fórmulas dentro do texto axudan a obter unha fila de aspecto ordenado con algúns totais – números coas súas breves descricións.

Vou crear filas deste tipo nas liñas 14 e 15. Para comezar, fusiono celas nesas filas mediante Formato > Combina celas e despois conta a suma da columna E:

=SUM(E2:E13)

Entón poño o texto que me gustaría ter como descrición entre comiñas dobres e combinoo coa fórmula usando un ampersand:

="Total chocolate sales: "&SUM(E2:E13)&" dollars"

Para facer os meus números decimais, utilizo a función TEXT e establezo o formato: "#,## 0"

Outra forma é usar a función CONCATENAR de Google Sheets, como usei en A15:

=CONCATENATE("Total discount for customers: ",TEXT(SUM(F2:F13),"#.##")," dollars")

Exemplo 3

E se cargas os datos dalgún lugar e todos os números aparecen con espazos, como 8 544 en lugar de 8544 ? Follas de cálculo de Google devolverá estes como texto, xa sabes.

Aquí móstrase como converter estes valores escritos como texto en "números normais":

=VALUE(SUBSTITUTE("8 544"," ",""))

ou

=VALUE(SUBSTITUTE(A2," ",""))

onde A2 contén 8 544 .

Como funciona? A función SUBSTITUTE substitúe todos os espazos do texto (marque o segundo argumento: hai espazo entre comiñas dobres) cun "baleirocadea" (o terceiro argumento). A continuación, VALUE converte o texto en números.

Exemplo 4

Hai algunhas funcións de Follas de cálculo de Google que axudan a manipular o texto das follas de cálculo, por exemplo, cambiar as maiúsculas e minúsculas. Se tes algo estraño como datos da fonte , podes obter datos da fonte no seu lugar:

Déixame explicar iso en detalle. Tomo o primeiro carácter dunha cela:

=LEFT(A1,1)

e cambioo a maiúscula:

=UPPER(LEFT(A1,1))

Entón tomo o texto restante:

=RIGHT(A1,LEN(A1)-1)

e fórzao en minúsculas:

=LOWER(RIGHT(A1,LEN(A1)-1))

Por último, reúno todas as pezas da fórmula cun ampersand :

=UPPER(LEFT(A1,1))&LOWER(RIGHT(A1,LEN(A1)-1))

Consello. Podes cambiar entre casos cun clic coa utilidade correspondente das nosas ferramentas eléctricas.

Por suposto, Google Sheets ten moito máis que ofrecer. Non teñas medo de diferentes fórmulas complexas: só proba e experimenta. Despois de todo, estes conxuntos de ferramentas permítennos resolver moitas tarefas diferentes. Moita sorte! :)