Lahajedwali hutoa jukwaa bora la kudhibiti majedwali ya data. Lakini je, kuna utendakazi wowote rahisi wa Majedwali ya Google kwa hesabu za kila siku? Pata maelezo hapa chini.

Kitendaji cha SUM cha Majedwali ya Google

Ninaamini utendakazi unaohitajika zaidi katika majedwali ni kutafuta jumla ya thamani tofauti. Jambo la kwanza linalokuja akilini ni kuongeza kila seli moja inayokuvutia:

=E2+E4+E8+E13

Lakini fomula hii itatumia muda mwingi ikiwa kuna visanduku vingi vya kuzingatiwa.

Njia sahihi ya kuongeza visanduku ni kutumia chaguo maalum la kukokotoa la Majedwali ya Google - SUM - ambalo huorodhesha visanduku vyote kiotomatiki kwa kutumia koma:

=SUM(E2,E4,E8,E13)

Ikiwa fungu la visanduku lina visanduku vilivyo karibu. , onyesha visanduku vyake vya kwanza na vya mwisho hata kama kuna visanduku tupu mahali fulani. Kwa hivyo, utaepuka kuorodhesha kila kisanduku katika fomula ya SUM ya Majedwali ya Google.

Kidokezo. Njia nyingine ya kuongeza SUM ni kuchagua safu wima yenye nambari na uchague SUM chini ya ikoni ya Mfumo :

Matokeo yatakuwa kuingizwa kwenye seli chini ya safu iliyochaguliwa.

Kidokezo. Zana zetu za Nguvu zina kipengele cha AutoSum. Mbofyo mmoja - na seli yako inayotumika itarejesha jumla ya thamani kutoka kwenye safu wima nzima hapo juu.

Acha nifanye kazi iwe ngumu. Ninataka kuongeza nambari kutoka safu tofauti za data kwenye laha nyingi, kwa mfano, A4:A8 kutoka Jedwali1 na B4:B7 kutoka Jedwali2 . Na ninataka kuzijumlishakisanduku kimoja:

=SUM('Sheet1'!A4:A8,'Sheet2'!B4:B7)

Kama unavyoona, nimeongeza laha moja zaidi kwenye fomula ya SUM ya Majedwali ya Google na kutenganisha safu mbili tofauti kwa koma.

Asilimia ya fomula

Huwa nasikia watu wakiuliza kuhusu kupata asilimia ya jumla tofauti. Kwa kawaida hii huhesabiwa kwa asilimia ya fomula ya Majedwali ya Google kama hii:

Sawa pia hufanya kazi wakati wowote unapohitaji kuangalia ni sehemu gani hii au nambari hiyo inawakilisha jumla:

Kidokezo. Asilimia kuu ya jumla, jumla & kiasi kwa asilimia, ongezeko lake & kupungua kwa mafunzo haya.

Katika jedwali langu ambapo ninaweka rekodi za mauzo yote kwa siku 10 zilizopita, ninaweza kukokotoa asilimia ya kila mauzo kutoka kwa jumla ya mauzo.

Kwanza, naenda kwa E12 na kupata jumla ya mauzo:

=SUM(E2:E11)

Kisha, ninaangalia ni sehemu gani ya mauzo ya siku ya kwanza yanajumuisha jumla katika F2:

=E2/$E$12

Ninapendekeza ufanye marekebisho machache pia:

1. Geuza E2 hadi marejeleo kamili - $E$12 - ili kuhakikisha kuwa unagawanya mauzo ya kila siku kwa jumla sawa.
2. Tumia umbizo la nambari ya asilimia kwenye visanduku vilivyo katika safu wima F.
3. Nakili fomula kutoka F2 hadi visanduku vyote vilivyo hapa chini - hadi F11.

Kidokezo. Ili kunakili fomula, tumia mojawapo ya njia nilizotaja hapo awali.

Kidokezo. Ili kuhakikisha kuwa hesabu zako ni sahihi, weka iliyo hapa chini kwa F12:

=SUM(F2:F11 )

Ikirudishwa 100% -kila kitu kiko sawa.

Kwa nini ninapendekeza kutumia umbizo la asilimia?

Vema, kwa upande mmoja, ili kuepuka kuzidisha kila matokeo kwa 100 ikiwa ungependa kupata asilimia. Kwa upande mwingine, ili kuepuka kugawanya matokeo hadi 100 ikiwa ungependa kuyatumia kwa shughuli zozote za hesabu zisizo za asilimia.

Hivi ndivyo ninamaanisha:

Ninatumia umbizo la nambari ya asilimia katika visanduku C4, B10, na B15. Fomula zote za Majedwali ya Google zinazorejelea visanduku hivi ni rahisi zaidi. Sihitaji kugawanya kwa 100 au kuongeza alama ya asilimia (%) kwa fomula katika C10 na C15.

Hatuwezi kusema sawa kuhusu C8, C9, na C14. Lazima nifanye marekebisho haya ya ziada ili kupata matokeo sahihi.

Fomula za mkusanyiko

Ili kufanya kazi na data nyingi katika Majedwali ya Google, chaguo za kukokotoa zilizowekwa na hesabu zingine ngumu zaidi hutumiwa kama sheria. Fomula za safu zipo katika Majedwali ya Google kwa madhumuni hayo pia.

Kwa mfano, nina jedwali la mauzo kwa kila mteja. Nina hamu ya kupata mauzo ya juu zaidi ya chokoleti ya maziwa hadi Smith ili kuangalia kama ninaweza kumpa punguzo la ziada wakati ujao. Ninatumia fomula ya safu inayofuata katika E18:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith")*($C$2:$C$13="Milk Chocolate"),$E$2:$E$13,"")))

Kumbuka. Ili kukamilisha fomula yoyote katika Majedwali ya Google, bonyeza Ctrl+Shift+Enter badala ya Enter tu.

Nimepata $259 kwa sababu hiyo.

Fomula yangu ya safu ya kwanza katika E16 hurejesha ununuzi wa juu zaidi uliofanywa na Smith – $366:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith"),$E$2:$E$13)))

E17 onyesha kiwango cha juu zaidipesa zinazotumika kununua chokoleti ya maziwa - $518:

=ArrayFormula(MAX(IF(($C$2:$C$13="Milk Chocolate"),$E$2:$E$13)))

Sasa, nitabadilisha thamani zote zinazotumiwa katika fomula za Majedwali ya Google na marejeleo yake ya seli:

Je, umeona ni nini kimebadilika?

=ArrayFormula(MAX(IF(($B$2:$B$13=B18)*($C$2:$C$13=C18),$E$2:$E$13,"")))

Haya ndiyo niliyokuwa nayo hapo awali:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith")*($C$2:$C$13="Milk Chocolate"),$E$2:$E$13,"")))

Vivyo hivyo, kucheza mauzauza ukiwa na thamani katika visanduku unavyorejelea unaweza kupata matokeo tofauti kwa haraka kulingana na hali tofauti bila kubadilisha fomula yenyewe.

Mchanganyiko wa Majedwali ya Google kwa matumizi ya kila siku

Hebu tuangalie chaguo za kukokotoa chache zaidi na mifano ya fomula zinazofaa kwa matumizi ya kila siku.

Mfano 1

Tuseme data yako imeandikwa kwa sehemu kama nambari na kwa sehemu kama maandishi: euro 300 , jumla - dola 400 . Lakini unahitaji kutoa nambari pekee.

Najua tu chaguo la kukokotoa kwa hilo:

Inavuta maandishi kwa barakoa kwa msemo wa kawaida.

• maandishi - inaweza kuwa marejeleo ya seli au maandishi yoyote katika manukuu maradufu.
• maneno_ya_kawaida - barakoa yako ya maandishi. Pia katika nukuu mbili. Inakuruhusu kuunda karibu mpango wowote wa maandishi unaowezekana.

Maandishi katika kesi yangu ni kisanduku chenye data ( A2 ). Na mimi hutumia usemi huu wa kawaida: [0-9]+

Inamaanisha kuwa ninatafuta idadi yoyote ( + ) ya nambari kutoka 0 hadi 9 ( [0-9] ) imeandikwa moja baada ya nyingine:

Ikiwa nambari zina sehemu, usemi wa kawaida utaonekana hivi:

"[0-9]*\.[0-9]+[0-9]+" kwanambari zilizo na nafasi mbili za desimali

"[0-9]*\.[0-9]+" kwa nambari zilizo na sehemu moja ya desimali

Kumbuka. Majedwali ya Google huona thamani zilizotolewa kama maandishi. Unahitaji kuzibadilisha ziwe nambari zilizo na chaguo la kukokotoa la VALUE au kwa zana yetu ya Kubadilisha.

Mfano wa 2 - unganisha maandishi kwa fomula

Mfumo ndani ya maandishi husaidia kupata safu mlalo inayoonekana vizuri yenye jumla fulani. – nambari zilizo na maelezo yake mafupi.

Nitaunda safu mlalo kama hizo katika mstari wa 14 na 15. Kwa kuanzia, ninaunganisha visanduku katika safu mlalo hizo kupitia Umbiza > Unganisha seli kisha uhesabu jumla ya safu wima E:

=SUM(E2:E13)

Kisha nikaweka maandishi ambayo ningependa kuwa nayo kama maelezo ya kunukuu mara mbili na kuyachanganya na fomula. kwa kutumia ampersand:

="Total chocolate sales: "&SUM(E2:E13)&" dollars"

Ili kutengeneza nambari zangu kuwa desimali, mimi hutumia kitendakazi cha TEXT na kuweka umbizo: "#,## 0"

Njia nyingine ni kutumia utendakazi wa Majedwali ya Google CONCATENATE, kama nilivyotumia katika A15:

=CONCATENATE("Total discount for customers: ",TEXT(SUM(F2:F13),"#.##")," dollars")

Mfano 3

Je! unapakia data kutoka mahali fulani na nambari zote zinaonekana na nafasi, kama 8 544 badala ya 8544 ? Majedwali ya Google yatarudisha haya kama maandishi, unajua.

Hivi ndivyo unavyoweza kubadilisha thamani hizi kuwa maandishi kuwa "nambari za kawaida":

=VALUE(SUBSTITUTE("8 544"," ",""))

au

=VALUE(SUBSTITUTE(A2," ",""))

ambapo A2 ina 8 544 .

Inafanya kazi vipi? Kitendaji cha SUBSTITUTE kinachukua nafasi ya nafasi zote kwenye maandishi (angalia hoja ya pili - kuna nafasi katika nukuu mbili) na "tupu".string" (hoja ya tatu). Kisha, VALUE hubadilisha maandishi kuwa nambari.

Mfano 4

Kuna baadhi ya vitendakazi vya Majedwali ya Google vinavyosaidia kubadilisha maandishi katika lahajedwali zako, kwa mfano, kubadilisha hali. kwa kesi ya sentensi. Ikiwa una kitu cha kushangaza kama soURcE dAtA , unaweza kupata data ya chanzo badala yake:

Hebu nielezee hiyo kwa undani. Ninachukua herufi ya kwanza katika kisanduku:

=LEFT(A1,1)

na kuibadilisha hadi herufi kubwa:

=UPPER(LEFT(A1,1))

Kisha ninaichukua maandishi yaliyobaki:

=RIGHT(A1,LEN(A1)-1)

na ulazimishe kuwa herufi ndogo:

=LOWER(RIGHT(A1,LEN(A1)-1))

Mwisho, ninaleta vipande vyote vya fomula pamoja na ampersand. :

=UPPER(LEFT(A1,1))&LOWER(RIGHT(A1,LEN(A1)-1))

Kidokezo. Unaweza kubadilisha kati ya matukio kwa kubofya ukitumia matumizi sambamba kutoka kwa Zana zetu za Nishati.

Bila shaka, kuna mengi zaidi ya Majedwali ya Google. Usifanye' usiogope fomula tofauti changamano - jaribu tu na ujaribu. Baada ya yote, vifaa hivi vinaturuhusu kutatua kazi nyingi tofauti. Bahati nzuri! :)