"Birleştirmek" genellikle bir şeyi bir dizi veya zincir halinde birbirine bağlamak anlamına gelir. Bu işlem, birden fazla Google E-Tablolar hücresindeki metni birleştirmeniz gerektiğinde kullanılır. Bu makale, birleştirme bulmacasını çözmenize yardımcı olacak en popüler ve kolay çözümleri bir araya getirmektedir.

Veri kümeniz ne kadar büyük olursa olsun, Google E-Tablolar'da birden fazla hücreyi bir araya getirme göreviyle karşılaşabilirsiniz. Ve hiç şüphem yok ki, yalnızca tüm değerleri kaybetmekle kalmayıp, aynı zamanda bazı virgüller, boşluklar veya diğer karakterler eklemek, hatta bu kayıtları başka metinlerle ayırmak isteyeceksiniz.

Elektronik tablolar bu görev için çeşitli araçlar sunar.

Google E-Tablolar CONCAT işlevi

CONCAT işlevi, Google E-Tablolar CONCATENATE işlevinin basitleştirilmiş bir sürümüdür:

Bu işlevle hücreleri birleştirmek için gerekli değerleri listelemeniz gerekir:

• değer1 - değer2'nin eklenmesi gereken bir kayıt.
• değer2 - birleştirilecek değer.

İki metin veya sayısal birimden bir dize elde etmek için formül, her kayıt çift tırnak içinde olacak şekilde aşağıdaki gibi görünecektir:

=CONCAT("2019:", "Aslan Kral")

Gerçekte, verileriniz büyük olasılıkla zaten hücrelerdedir. Her bir sayıyı veya metni bir bağımsız değişken olarak yazmak yerine doğrudan bu hücrelere başvurabilirsiniz. Dolayısıyla, gerçek veri formülü şu şekilde olacaktır:

=CONCAT(A2,B2)

İpucu: Formülünüzü tüm sütuna kopyalamak için, formülün bulunduğu hücreyi seçin ve hücrenin sağ alt köşesindeki küçük kareye çift tıklayın. Tüm sütun, tablonun sonuna kadar otomatik olarak formülle doldurulacaktır.

Gördüğünüz gibi, işlev çok basit, ancak önemli özellikleri var zayıf noktalar :

• Google E-Tablolar'da bir seferde yalnızca iki hücreyi birleştirir.
• sütunları, satırları veya diğer büyük veri aralıklarını birleştiremez, yalnızca tek hücreleri alır. Birden fazla hücreyi birleştirmeye çalışırsanız, ya bir hata alırsınız ya da aşağıdaki gibi yalnızca ilk iki değer birleştirilir:

  =CONCAT(A2:A11,B2:B11)

  

CONCAT alternatifi: birleştirme operatörü ampersand (&)

Formüllerde çeşitli amaçlar için birçok farklı işleç vardır. Birleştirme de bir istisna değildir. Formüllerde CONCAT işlevi yerine bir ve işareti karakteri (&) kullanmak size aynı sonucu sağlayacaktır:

=A2&B2

Ancak bu birleştirme operatörünün daha esnek olduğunu pek bilmiyorsunuz. İşte yapabilecekleri:

1. Bir seferde ikiden fazla değeri birleştirin:

   =A2&B2&C2

   

2. Google E-Tablolar'da sadece hücreleri birleştirmekle kalmayın, aynı zamanda çeşitli karakterlerle ayırın:

   =A2&" "&B2&"; "&C2

   

Bu seçeneklerle hala istediğiniz sonucu elde edemiyorsanız, deneyebileceğiniz bir işlev daha var.

Google E-Tablolar'da CONCATENATE nasıl kullanılır?

Google E-Tablolar CONCATENATE işlevinin, birkaç kaydı bir araya getirme söz konusu olduğunda kullanılacak ilk işlev olduğuna inanıyorum.

Google E-Tablolar'da metin dizelerini ve sayıları BİRLEŞTİRME

Formül kalıbı aşağıdaki bağımsız değişkenlerden oluşur:

• string1 diğer değerleri eklemek istediğiniz ilk dizedir. Bu bağımsız değişken gereklidir.
• string2, ... eklemek isteyebileceğiniz diğer tüm dizeleri ifade eder. Bu bağımsız değişken isteğe bağlıdır.

Not: Sonuç kaydı, formülde görünme sırasına göre dizelerden oluşacaktır.

Formülü verilerime uyarlarsam şunu elde ederim:

=CONCATENATE(A2,B2,C2)

Veya, fonksiyon aralıkları kabul ettiğinden:

=CONCATENATE(A2:D2)

Google Sheets CONCATENATE'in ilk avantajını hemen fark edebilirsiniz: hem metin hem de sayı içeren iki hücreyi kolayca birleştirir.

Google E-Tablolar: Dizeleri ayırıcılarla birleştirme

Google E-Tablolar'da hücreleri birleştirmek işin yarısıdır. Ancak sonucun güzel ve okunabilir görünmesi için bazı ekstra karakterler eklemeniz gerekir.

Formülü olduğu gibi tutarsanız, her şeyi birbirine yapıştıracaktır: BonnieJacksonCA , BonnieJacksonIN Ancak Google E-Tablolar CONCATENATE karakterleri de bağımsız değişken olarak alır.

Bu nedenle, okunabilirlik için bazı ayırıcılar eklemek üzere, bunları formülde çift tırnak içinde belirtin:

=CONCATENATE(A2," ",B2,", ",C2)

Burada A2 & B2'yi boşlukla birleştirmek ve B2'yi C2'den virgül ve boşlukla ayırmak istiyorum:

Fonksiyonda bu şekilde hemen hemen her karakteri kullanmakta özgürsünüz, ancak satır sonu farklı bir yaklaşım gerektirir.

İpucu: Birleştirdiğiniz sütunların bazılarında boş hücreler varsa, ilginizi çekebilecek bir işlev daha vardır. TEXTJOIN, Google E-Tablolar'da yalnızca hücreleri birleştirmekle kalmaz, boşlukları da yok sayar:

=TEXTJOIN(" ",TRUE,A2:C2)

Şöyle çalışıyor:

1. İstenen sınırlayıcıyı ilk bağımsız değişken olarak belirtin - uzay (" ") benim için.
2. Koy DOĞRU boş hücreleri atlamak için ikinci bir bağımsız değişken olarak veya YANLIŞ bunları sonuca dahil etmek için.
3. Birleştirilecek aralığı girin.

Google E-Tablolar'da satır sonu ile birleştirme

Çoğu sınırlayıcıyı işleve nasıl gireceğiniz açık olsa da, satır sonunu aynı şekilde yazamazsınız. Ancak neyse ki Google birçok farklı kart oynamanıza izin veriyor.

Özel karakterleri elde etmeye yardımcı olan bir fonksiyon vardır - buna CHAR denir. Gördüğünüz gibi, her karakterin Unicode tablosunda bir yeri vardır. Karakterin sıra numarasını bu tablodan fonksiyona beslemeniz yeterlidir ve ikincisi karakterin kendisini döndürecektir.

İşte satır sonu elde etmek için bir formül:

=CHAR(10)

Google E-Tablolar'da satır sonu ile birleştirmek için formüle ekleyin:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Google E-Tablolar'da tarih ve saati birleştirme

Yukarıdaki yöntemlerden birini kullanarak Google E-Tablolar'da tarih ve saati birleştirmeye çalışırsanız, bu işe yaramaz. E-tablonuz sayılar döndürür:

Google E-Tablolar'da tarih ve saati doğru şekilde birleştirmek için METİN işlevini kullanın:

• nerede sayı istediğiniz formatta almak istediğiniz herhangi bir sayı, tarih veya saattir
• ve Biçim sonuç olarak görmek istediğiniz modeldir.

İpucu: Örneğimde, tarih ve saat içeren hücrelere başvuracağım, ancak formülde doğrudan tarih/saat birimlerini ve hatta TARİH veya ZAMAN gibi işlevleri kullanmakta özgürsünüz.

1. Tarih biçimini şu şekilde değiştirmek için ilk METİN formülünü kullanıyorum 7/9/2019 için 9 Temmuz 2019 :

   =TEXT(B2, "D MMM YYYY")

2. İkinci TEXT zamanı döndürür:

   =TEXT(C2, "HH:MM:SS")

   Ayrıca bakınız: Aralığı tek sütuna dönüştürmek için Excel TOCOL işlevi
3. Bunları CONCATENATE içinde kullanarak, Google E-Tablolar tarih ve saati istenen biçimde diğer karakterlerle veya metinle birleştirmeme olanak tanıyor:

   =CONCATENATE(TEXT(B2, "D MMM YYYY"),", ",TEXT(C2, "HH:MM:SS"))

Google E-Tablolar'da sütunları birleştirme

Küçük ayarlamalarla, bahsettiğim tüm yollar Google E-Tablolar'da sütunları birleştirebilir.

Örnek 1. Google E-Tablolar CONCAT

Google E-Tablolar'da tüm sütunları CONCAT ile birleştirmek için, sonucu içermesi gereken tüm aralığı seçin (benim durumumda C2:C11) ve formülünüzü ARRAYFORMULA'ya sararak girin:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Not: CONCATENATE işlevini kullanabilirsiniz, ancak birden fazla hücreyi ve veri aralığını kolayca birleştirdiği için tek bir hücredeki tüm kayıtları birleştirecektir.

Örnek 2. Birleştirme operatörü

Google E-Tablolar'da ve işaretini kullanarak sütunları birleştirmek için dizi formülleri oluşturun ve aynı zamanda ayırıcılar ekleyin:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Bu iyi görünüyor, ancak bazı önemli eksilere dikkat çekmek zorundayım.

Çok fazla sütununuz varsa, özellikle de yanlışlıkla herhangi bir karakteri atlarsanız/çoğaltırsanız/karıştırırsanız, hepsini numaralandırmak baş ağrıtıcı olabilir.

Ayrıca, formüle daha sonra daha fazla sütun eklemeye karar verirseniz, formüldeki mevcut her bir aralığı manuel olarak düzenlemeniz gerekecektir.

Bir sonraki örnek bu sorunları çözmektedir.

Örnek 3. Google E-Tablolar Sorgusu

Google E-Tablolar SORGULAMA işlevi, Google E-Tablolar'da birkaç sütunu birleştirmek için de uygundur:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Bu garip formülün sizi aştığını düşünebilirsiniz, ancak izin verin size tüm parçalarını açıklayayım:

1. =TRANSPOSE(A2:D10) veri satırlarını sütunlara dönüştürür.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) her sütundaki kayıtları en üst hücrelerde birleştirir.

   İpucu. 9^9 formüle girdiğimde, tüm sütunlardaki tüm satırların sanki başlıklarmış gibi ilk satıra çekileceğinden emin oluyorum. 9^9 Bu ifade elektronik tablodaki tüm olası hücreleri içerdiğinden (10M hücre sınırını hatırlıyor musunuz?) ve hatırlaması kolay olduğundan :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) bu başlık satırını QUERY'den alır ve benim sahip olduğum gibi bir sütuna dönüştürür.

İşte Google E-Tablolar'da QUERY kullanarak sütunları birleştirmenin avantajları:

• dizi formülleri için yaptığınız gibi tüm sütunu seçmeniz gerekmez
• bitişik olmadıkları sürece formülde her sütundan bahsetmenize gerek yoktur. Bu durumda, formül şu şekilde görünecektir:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

Pozisyona göre metin birleştirme ve ekleme

CONCATENATE işlevini kullanarak dizelerinize eksik metin, sayı ve karakter ekleyebileceğinizi zaten biliyorsunuz.

İpucu: Bununla ilgili daha fazla formülü bu eğitimde görebilirsiniz.

Ancak birleştirilecek çok fazla kayıt varsa, fazladan karakterler formülünüzü planladığınızın çok ötesine taşıyabilir. Bu gibi durumlarda, Google E-Tablolar'daki hücreleri olduğu gibi birleştirmek veya boşluk gibi basit sınırlayıcılar kullanmak ve metni bundan sonra eklemek daha iyidir. Özel bir aracımız size yardımcı olacaktır.

Pozisyona göre metin ekle, herhangi bir karakteri ve dizeyi belirttiğiniz pozisyona göre ekler, formül gerekmez. Size nasıl çalıştığını göstereyim.

Önceki örnekte QUERY benim için isimleri ve telefon numaralarını birleştirdi. Ancak ben ülke kısaltmalarını eklemek istiyorum: (ABD/CA) ile başlayan telefon numaralarından önce +1 ve BIRLEŞIK KRALLIK önce +44 :

Google E-Tablolar'da hücreleri bölme

Google E-Tablolar'da hücreleri birleştirirseniz, büyük olasılıkla bir noktada onları tekrar bölmeniz gerekecektir. Bunu yapmanın üç yolu vardır:

1. Google E-Tablolar SPLIT işlevini kullanarak bir formül oluşturun.
2. Standart elektronik tablo aracını kullanın - Metni sütunlara bölün.
3. Veya yerleşik aracın geliştirilmiş sürümünü deneyin - Google E-Tablolar için metni sütunlara bölme:

Hücreleri herhangi bir sınırlayıcıya veya hatta ayırıcı kümelerine göre bölmenize, bunları tek olarak ele almanıza ve gerekirse bağlaçları dahil etmenize olanak tanır. Ayrıca Google E-Tablolar'daki hücreleri konuma göre bölme seçeneği de sunar.

İpucu: İçeriği bölmek yerine Google E-Tablolar hücrelerinden veri ayıklama seçeneği vardır.

Google E-Tablolar'da formüller olmadan hücreler nasıl birleştirilir

Farklı formüllerde ustalaşmak planınızın bir parçası değilse, Değerleri Birleştir eklentimizden yararlanacaksınız. Eklenti, satırlardaki, sütunlardaki veya tüm hücre aralığındaki kayıtları hızlı bir şekilde birleştirir. Seçenekleri çok nettir ve tek yapmanız gereken aralığı seçmek ve sonucun nasıl görünmesi gerektiğine karar vermektir.

1. Şunları seçebilirsiniz sütunları birleştir Google E-Tablolar'da bitişik olmayanları bile virgül ve boşluklarla ayırın ve sonucu orijinal kayıtların sağına yerleştirin:

Araç ilginizi çektiyse, bu özel sayfada veya bu kısa eğitim videosunda yaptığı her şeyi inceleyebilirsiniz:

Bu videoda Yinelenen Satırları Birleştir'i nasıl kullanacağınızı öğrenin:

Umarım şimdiye kadar hangi yöntemin sizin durumunuza en uygun olduğuna karar vermişsinizdir. Aklınızda başka yöntemler varsa, lütfen aşağıdaki yorumlar bölümünde bizimle paylaşın :)