Opplæringen forklarer hvordan du teller tegn i Excel. Du vil lære formlene for å få det totale antallet tegn i et område, og telle kun spesifikke tegn i en celle eller i flere celler.

Vår tidligere opplæring introduserte Excel LEN-funksjonen, som gjør det mulig å telle totalt antall tegn i en celle.

LEN-formelen er nyttig alene, men i forbindelse med andre funksjoner som SUM, SUMPRODUKT og ERSTATTING, kan den håndtere langt mer komplekse oppgaver. Videre i denne opplæringen skal vi se nærmere på noen grunnleggende og avanserte formler for å telle tegn i Excel.

Hvordan telle alle tegn i et område

Når det kommer til å telle et totalt antall tegn i flere celler, er en umiddelbar løsning du tenker på å få tegnantallet for hver celle, og deretter legge sammen disse tallene:

=LEN(A2)+LEN(A3)+LEN(A4)

Eller

=SUM(LEN(A2),LEN(A3),LEN(A4))

Formlene ovenfor kan fungere fint for et lite område. For å telle totalt antall tegn i et større område, bør vi finne på noe mer kompakt, f.eks. SUMPRODUKT-funksjonen, som multipliserer matrisene og returnerer summen av produktene.

Her er den generiske Excel-formelen for å telle tegn i et område:

Og den virkelige formelen din kan se slik ut:

=SUMPRODUCT(LEN(A1:A7))

En annen måte å telle tegn i en rekkevidde er å bruke LEN-funksjon innkombinasjon med SUM:

=SUM(LEN(A1:A7))

I motsetning til SUMPRODUCT, beregner ikke SUM-funksjonen matriser som standard, og du må trykke Ctrl + Shift + Enter for å gjøre den om til en matriseformel.

Som vist i følgende skjermbilde, returnerer SUM-formelen samme totale tegnantall:

Slik fungerer denne formlen for antall tegn for rekkevidde

Dette er en av de enkleste formlene for å telle tegn i Excel. LEN-funksjonen beregner strenglengden for hver celle i det angitte området og returnerer dem som en matrise med tall. Og så summerer SUMPRODUCT eller SUM disse tallene og returnerer det totale antall tegn.

I eksemplet ovenfor summeres en matrise med 7 tall som representerer lengdene på strengene i cellene A1 til A7:

Merk. Vær oppmerksom på at Excel LEN-funksjonen teller absolutt alle tegn i hver celle , inkludert bokstaver, tall, skilletegn, spesialsymboler og alle mellomrom (innledende, etterfølgende og mellomrom mellom ord).

Hvordan telle spesifikke tegn i en celle

Noen ganger, i stedet for å telle alle tegn i en celle, kan det hende du må telle bare forekomstene av en bestemt bokstav, tall eller spesialsymbol.

For å telle antall ganger et gitt tegn vises i en celle, bruk LEN-funksjonen sammen med ERSTATT:

For bedre å forstå formelen, tenk på følgende eksempel.

Anta at du vedlikeholder en database med leverte varer, der hver varetype har sin egen unike identifikator. Og hver celle inneholder flere elementer atskilt med komma, mellomrom eller et annet skilletegn. Oppgaven er å telle hvor mange ganger en gitt unik identifikator vises i hver celle.

Forutsatt at listen over leverte varer er i kolonne B (begynner i B2), og vi teller antall "A" forekomster, er formelen som følger:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

Slik fungerer denne formelen for Excel-tegntelling

For å forstå formelens logikk, la oss bryte den ned i mindre deler:

• Først teller du den totale strenglengden i B2:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

Som et resultat får du antallet "fjernede" tegn, som tilsvarer et totalt antall av disse tegnforekomstene i cellen.

I stedet for å spesifisere tegnet du vil telle i en formel, kan du skrive den inn i en celle og deretter referere til den cellen i en formel. På denne måten brukerne dinevil kunne telle forekomster av et hvilket som helst annet tegn de skriver inn i den cellen uten å tukle med formelen din:

Merk. Excels ERSTATTNING er en funksjon som skiller mellom store og små bokstaver, og derfor skiller formelen ovenfor også mellom store og små bokstaver. For eksempel, i skjermbildet ovenfor, inneholder celle B3 3 forekomster av "A" - to med store bokstaver og en med små bokstaver. Formelen har kun talt med store bokstaver fordi vi ga "A" til ERSTATT-funksjonen.

Stillingsuavhengig Excel-formel for å telle spesifikke tegn i en celle

Hvis du trenger et tall som ikke skiller mellom store og små bokstaver, kan du bygge inn UPPER-funksjonen i SUBSTITUTE for å konvertere det angitte tegnet til store bokstaver før du kjører erstatningen. Og husk å skrive inn store bokstaver i formelen.

For å telle "A"- og "a"-elementer i celle B2, bruk for eksempel denne formelen:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

En annen måte er å bruke nestede erstatningsfunksjoner:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

Som du kan se på skjermbildet nedenfor, teller begge formlene feilfritt forekomster av store og små bokstaver av det angitte tegnet:

I noen tilfeller må du kanskje telle mange forskjellige tegn i en tabell, men du vil kanskje ikke endre formelen hver gang. I dette tilfellet legger du en erstatningsfunksjon i en annen, skriver inn tegnet du vil telle i en celle (D1 i dette eksemplet), og konverterer cellens verdi til store bokstaver ogsmå bokstaver ved å bruke STORE og LOWER-funksjonene:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Alternativt kan du konvertere både kildecellen og cellen som inneholder tegnet enten til store eller små bokstaver. For eksempel:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

Fordelen med denne tilnærmingen er at uavhengig av om store eller små bokstaver skrives inn i den refererte cellen, vil formelen for antall store og små bokstaver returnerer riktig antall:

Tell forekomster av bestemt tekst eller delstreng i en celle

Hvis du vil telle hvor mange ganger en spesifikk kombinasjon av tegn (dvs. bestemt tekst eller understreng) vises i en gitt celle, f.eks. "A2" eller "SS", del deretter antall tegn som returneres av formlene ovenfor med lengden på delstrengen.

Stillingsensitiv formel:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Stillingløs formel:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Hvor B2 er cellen som inneholder hele tekststrengen, og C1 er teksten (delstrengen) du ønsker å telle.

For en detaljert forklaring av formelen, se Hvordan telle spesifikk tekst/ord i en celle.

Hvordan telle spesifikke tegn(er) i et område

Nå som du kjenner en Excel-formel for å telle tegn i en celle, kan det være lurt å forbedre den ytterligere for å finne ut hvor mange ganger et bestemt tegn vises i et område. For dette vil vi ta Excel LEN-formelen for å telle en spesifikk char i en celle som er diskuterti forrige eksempel, og legg den inn i SUMPRODUKT-funksjonen som kan håndtere arrays:

I dette eksemplet har formelen følgende form:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Og her er en annen formel å telle tegn i Excels utvalg:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Sammenlignet med den første formelen er den mest åpenbare forskjellen å bruke SUM i stedet for SUMPRODUCT. En annen forskjell er at det krever å trykke Ctrl + Shift + Enter fordi i motsetning til SUMPRODUCT, som er designet for å behandle matriser, kan SUM håndtere matriser bare når de brukes i en matriseformel .

Hvis du ikke Hvis du ikke vil hardkode tegnet i formelen, kan du selvfølgelig skrive det inn i en celle, si D1, og referere til den cellen i formelen for antall tegn:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Merk. I situasjoner når du teller forekomstene av en spesifikk delstreng i et område (f.eks. rekker som begynner med "KK" eller "AA"), må du dele tegnantallet på understrenglengden, ellers må hvert tegn i delstrengen telles individuelt. For eksempel:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Hvordan denne tegntellingsformelen fungerer

Som du kanskje husker, brukes ERSTATT-funksjonen til å erstatte alle forekomster av det angitte tegnet ("A" i dette eksemplet ) med en tom tekststreng ("").

Deretter leverer vi tekststrengen returnert av SUBSTITUTE til Excel LENfunksjon slik at den beregner strenglengden uten A-er. Og så trekker vi det tegntellingen fra den totale lengden på tekststrengen. Resultatet av disse beregningene er en rekke tegntellinger, med ett tegnantall per celle.

Til slutt summerer SUMPRODUCT tallene i matrisen og returnerer det totale antallet av det angitte tegnet i området.

En formel som ikke skiller mellom store og små bokstaver for å telle spesifikke tegn i en rekkevidde

Du vet allerede at SUBSTITUTE er en funksjon som skiller mellom store og små bokstaver, noe som også gjør Excel-formelen vår for tegnantall sensitiv.

For å få formelen til å ignorere store og små bokstaver, følg fremgangsmåtene som ble vist i forrige eksempel: Formel uten store og små bokstaver for å telle spesifikke tegn i en celle.

Spesielt kan du bruke en av følgende formler for å telle spesifikke tegn i et område som ignorerer store og små bokstaver:

• Bruk UPPER-funksjonen og skriv inn et tegn med store bokstaver:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• Bruk nestede ERSTATT-funksjoner:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• Bruk STOR og LOWER funksjoner, skriv inn enten en stor eller liten bokstav i en celle, og referer til den cellen i formelen din:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

Skjermbildet nedenfor viser den siste formelen i aksjon:

Tips. For å telle forekomstene av en spesifikk tekst (delstreng) i et område, bruk formelen vist i Hvordan telle spesifikk tekst/ord i et område.

Detteer hvordan du kan telle tegn i Excel ved å bruke LEN-funksjonen. Hvis du vil vite hvordan du teller ord i stedet for individuelle tegn, vil du finne noen nyttige formler i vår neste artikkel, følg med!

I mellomtiden kan du laste ned et eksempel på arbeidsbøker med formel for tegntelling diskutert i denne opplæringen, og sjekk ut en liste over relaterte ressurser på slutten av siden. Jeg takker for at du leser og håper å se deg snart!