Opplæringen gir en kort introduksjon til ADRESSE-funksjonens syntaks og viser hvordan du bruker den til å returnere en Excel-celleadresse og mer.

For å lage en cellereferanse i Excel, må du kan skrive kolonne- og radkoordinatene manuelt. Alternativt kan du få en Excel-celleadresse fra rad- og kolonnenumrene som er oppgitt til ADRESSE-funksjonen. Nesten meningsløst i seg selv, i kombinasjon med andre funksjoner kan denne teknikken være den eneste løsningen i situasjoner der det ikke er mulig å referere til en celle direkte.

Excel ADRESSE-funksjon - syntaks og grunnleggende bruk

ADRESSE-funksjonen er designet for å få en celleadresse i Excel basert på de angitte rad- og kolonnenumrene. En celleadresse returneres som en tekststreng, ikke en faktisk referanse.

Funksjonen er tilgjengelig i alle versjoner av Excel for Microsoft 365 - Excel 2007.

Syntaksen til ADRESSE-funksjonen er som følger:

De to første argumentene kreves:

radnummer - raden nummer som skal brukes i cellereferansen.

kolonne_nummer - kolonnenummeret for å bygge cellereferansen.

De tre siste argumentene, som spesifiserer cellereferanseformatet, er valgfritt:

abs_num - referansetypen, absolutt eller relativ. Det kan ta hvilket som helst av tallene nedenfor; standarden er absolutt.

• 1 eller utelatt -absolutt cellereferanse som $A$1
• 2 - blandet referanse: relativ kolonne og absolutt rad som A$1
• 3 - blandet referanse: absolutt kolonne og relativ rad som $A1
• 4 - relativ cellereferanse som A1

a1 - referansestilen, A1 eller R1C1. Hvis den utelates, brukes standard A1-stil.

• 1 eller TRUE eller utelatt - returnerer celleadressen i A1-referansestilen der kolonner er bokstaver og rader er tall.
• 0 eller FALSE - returnerer celleadressen i R1C1-referansestilen der rader og kolonner er representert med tall.

arktekst - navnet på regnearket som skal inkluderes i den eksterne referansen. Arknavnet skal leveres som en tekststreng og omsluttes av anførselstegn, f.eks. "Ark2". Hvis det utelates, brukes ikke noe regnearknavn, og adressen er standard til gjeldende ark.

For eksempel:

=ADDRESS(1,1) - returnerer adressen til den første cellen (dvs. cellen i skjæringspunktet mellom den første raden og den første kolonnen) som en absolutt cellereferanse $A$1.

=ADDRESS(1,1,4) - returnerer adressen til den første cellen som en relativ cellereferanse A1.

I følgende tabell finner du noen flere referansetyper som kan returneres av ADRESSE-formler.

Hvordan bruke ADRESSE-funksjonen i Excel - formeleksempler

Eksemplene nedenfor viser hvordan du bruker ADRESSE-funksjonen i større formler for å oppnå mer vanskelige oppgaver.

Returner en celleverdi i en gitt rad og kolonne

Hvis målet ditt er å få en verdi fra en bestemt celle basert på rad- og kolonnenumrene, bruk ADRESSE-moroa aksjon sammen med INDIREKTE:

ADRESSE-funksjonen sender ut celleadressen som tekst. INDIREKTE-funksjonen gjør den teksten til en normal referanse og returnerer verdien fra den tilsvarende cellen.

For å få en celleverdi basert på radnummeret i E1 og kolonnenummeret i E2, bruk for eksempel denne formelen :

=INDIRECT(ADDRESS(E1,E2))

Få adressenav en celle med den høyeste eller laveste verdien

I dette eksemplet finner vi først de høyeste og laveste verdiene i området B2:B7 ved å bruke MAX- og MIN-funksjonene og sende disse verdiene inn i spesielle celler:

Celle E2: =MAX(B2:B7)

Celle F2: =MIN(B2:B7)

Og så bruker vi ADDRESS i kombinasjon med MATCH-funksjonen for å få celleadressene.

Celle med maksverdi:

=ADDRESS(MATCH(E2,B:B,0), COLUMN(B2))

Celle med minverdi:

=ADDRESS(MATCH(F2,B:B,0), COLUMN(B2))

Hvis du ikke vil ha de høyeste og laveste verdiene i separate celler, kan du neste MAX/MIN-funksjonen i det første argumentet til MATCH. For eksempel:

Celle med den høyeste verdien:

=ADDRESS(MATCH(MAX(B2:B7),B:B,0), COLUMN(B2))

Celle med den laveste verdien:

=ADDRESS(MATCH(MIN(B2:B7),B:B,0), COLUMN(B2))

Hvordan disse formlene arbeid

For å finne radnummeret bruker du MATCH(oppslagsverdi, oppslagsmatrise, [samsvarstype])-funksjonen som returnerer en relativ posisjon til oppslagsverdi i oppslagsmatrise. I formelen vår er oppslagsverdien tallet som returneres av MAX- eller MIN-funksjonen, og oppslagsmatrisen er hele kolonnen. Følgelig samsvarer en relativ plassering av oppslagsverdien i matrisen nøyaktig med radnummeret på arket.

For å finne kolonnenummeret bruker du COLUM-funksjonen. Selvfølgelig er det ingenting som hindrer deg i å skrive tallet direkte i formelen, men KOLONNE sparer bryet med manuell telling i tilfelle målkolonnen er midt på arket.

Få en kolonnebokstav.fra et kolonnenummer

For å gjøre et gitt tall til en kolonnebokstav, bruk ADRESSE-funksjonen inne i SUBSTITUTE:

Som et eksempel, la oss finne kolonnebokstaven som tilsvarer tallet i A2:

=SUBSTITUTE(ADDRESS(1,A2,4),"1","")

Når vi ser på resultatene nedenfor, kan vi si at den første kolonnen på arket er A, som er åpenbart; den 10. kolonnen er J, den 50. kolonnen er AX, og den 100. kolonnen er CV:

Hvordan denne formelen fungerer

For det første, sett opp ADRESSE-funksjon for å returnere en relativ referanse til den første cellen i målkolonnen:

• For radnummeret, bruk 1.
• For kolonnenummeret, oppgi referansen til cellen som inneholder tallet A2 i vårt eksempel.
• For abs_num-argumentet, skriv inn 4.

Som resultat vil ADRESSE(1,A2,4) returnere A1.

For å bli kvitt radkoordinaten, pakk formelen ovenfor inn i ERSTATT-funksjonen og erstatt "1" med en tom streng (""). Ferdig!

Få adressen til et navngitt område

For å finne adressen til et navngitt område i Excel, må du først hente de første og siste cellereferansene, og deretter slå dem sammen . Dette fungerer litt annerledes i pre-dynamisk Excel (2019 og eldre) og Dynamic Array Excel (Office 365 og Excel 2021). Eksemplene nedenfor er for Excel 2019 - Excel 2007. Instruksjonene for Excel 365 og Excel 2021 erher.

Hvordan får du adressen til den første cellen i et område

For å returnere en referanse til den første cellen i et navngitt område, bruk denne generiske formelen:

Forutsatt at området heter "Salg", er den virkelige formelen som følger:

=ADDRESS(ROW(Sales), COLUMN(Sales))

Og returnerer adressen til den øvre venstre cellen i området:

I denne formelen returnerer ROW- og COLUMN-funksjonene en matrise med alle rad- og kolonnenumrene i rekkevidden, henholdsvis. Basert på disse tallene bygger ADRESSE-funksjonen en rekke celleadresser. Men fordi formelen legges inn i en enkelt celle, vises bare det første elementet i matrisen, som tilsvarer den første cellen i området.

Hvordan få adressen til den siste cellen i et område

For å finne adressen til den siste cellen i et navngitt område, bruk denne generiske formelen:

Anvendt på vårt område kalt "Salg", har formelen følgende form:

=ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

Og returnerer referansen til cellen nederst til høyre i området:

Denne gangen trenger vi litt mer komplekse beregninger for å regne ut raden Antall. Som i forrige eksempel gir ROW-funksjonen oss en matrise med alle radnumrene i området, {4;5;6;7} i vårt tilfelle. Vi må "forskyve" disse tallene med det totale radantallet minus 1, slik atdet første elementet i matrisen blir det siste radnummeret. For å finne det totale radantallet bruker vi ROWS-funksjonen og trekker 1 fra resultatet: (4-1=3). Deretter legger vi til 3 til hvert element i den innledende matrisen for å gjøre det nødvendige skiftet: {4;5;6;7} + 3 = {7;8;9;10}.

Solonnenummeret er beregnet på lignende måte: {2,3,4}+3-1 = {4,5,6}

Fra de ovennevnte matrisene med rad- og kolonnenummer, setter ADRESSE-funksjonen sammen en matrise med celleadresser , men returnerer bare den første som tilsvarer den siste cellen i området.

Det samme resultatet kan også oppnås ved å velge de maksimale verdiene fra matrisene til rad- og kolonnenumrene. Dette fungerer imidlertid bare i en matriseformel, som krever å trykke Ctrl + Shift + Enter for å fullføres riktig:

=ADDRESS(MAX(ROW(Sales)), MAX(COLUMN(Sales)))

Hvordan få full adresse til et navngitt område

For å returnere den fullstendige adressen til et navngitt område, trenger du bare å sette sammen de to formlene fra de forrige eksemplene og sette inn områdeoperatoren (:) i mellom.

For å få det til å fungere for prøvedatasettet vårt, erstatter vi det generiske "området" med det virkelige områdenavnet "Salg":

=ADDRESS(ROW(Sales), COLUMN(Sales)) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

Og får hele områdeadressen som en absolutt referanse $B$4:$D$7:

For å returnere områdetadresse som en relativ referanse (uten $-tegnet, som B4:D7), sett abs_num-argumentet i begge ADDRESS-funksjonene til 4:

=ADDRESS(ROW(Sales), COLUMN(Sales), 4) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1, 4)

Naturligvis samme endringer kan gjøres i individuelle formler for den første og siste cellen, og resultatet vil se ut som dette:

Hvordan få adressen til et navngitt område i Excel 365 og Excel 2021

I motsetning til den tradisjonelle oppførselen "én formel - én celle" i eldre versjoner, i nye Excel, gjør enhver formel som potensielt kan returnere flere verdier, dette automatisk. Slik oppførsel kalles søl.

For eksempel, i stedet for å returnere adressen til den første cellen, gir formelen nedenfor adressene til hver celle i et navngitt område:

=ADDRESS(ROW(Sales), COLUMN(Sales))

For kun å få adressen til den første cellen , må du aktivere implisitt kryss, som utløses som standard i Excel 2019 og eldre. For dette setter du @-symbolet (implisitt skjæringsoperator) foran områdenavnene:

=ADDRESS(@ROW(Sales), @COLUMN(Sales))

På lignende måte kan du fikse andre formler.

For å få siste celle i området:

=ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

For å få adressen til et navngitt område :

=ADDRESS(@ROW(Sales), @COLUMN(Sales)) & ":" & ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

Skjermbildet nedenfor viser resultatene:

Tips. Når du åpner et regneark med formler laget i en eldre versjon i dynamisk array Excel, settes en implisitt skjæringsoperator inn av Excel automatisk.

Slik kan dureturnere en celleadresse i Excel. For å se nærmere på alle formlene som er diskutert i denne opplæringen, er du velkommen til å laste ned vår eksempelarbeidsbok nedenfor. Jeg takker for at du leser og håper å se deg på bloggen vår neste uke!

Øvningsarbeidsbok for nedlasting

Excel ADRESSE-funksjon - formeleksempler (.xlsx-fil)