Opplæringen viser hvordan du bruker IF sammen med OG-funksjonen i Excel for å sjekke flere forhold i én formel.

Noen ting i verden er endelige. Andre er uendelige, og IF-funksjonen ser ut til å være en av slike ting. På bloggen vår har vi allerede en håndfull Excel IF-veiledninger og oppdager fortsatt nye bruksområder hver dag. I dag skal vi se på hvordan du kan bruke IF sammen med OG-funksjonen for å evaluere to eller flere forhold samtidig.

IF AND-setning i Excel

For å bygge IF AND-setningen, må du åpenbart kombinere IF- og AND-funksjonene i én formel. Slik gjør du:

Oversatt til vanlig engelsk, lyder formelen som følger: IF condition 1 er sann OG betingelse 2 er sann, gjør én ting, ellers gjør noe annet.

Som et eksempel, la oss lage en formel som sjekker om B2 er "levert" og C2 ikke er tom, og avhengig av resultatene , gjør ett av følgende:

• Hvis begge betingelsene er SANN, merk ordren som "Stengt".
• Hvis en av betingelsene er FALSE eller begge er FALSE, returnerer du en tom streng ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

Skjermbildet nedenfor viser HVIS OG-funksjonen i Excel:

Hvis du vil returnere en verdi i tilfelle den logiske testen evalueres til FALSE, oppgi denne verdien i verdi_hvis_falsk argument. For eksempel:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Den modifiserte formelen gir ut "Stengt" hvis kolonne B er "levert" og C har en hvilken som helst dato (ikke-tom). I alle andre tilfeller returnerer den "Åpen":

Merk. Når du bruker en HVIS OG-formel i Excel for å evaluere tekstbetingelser, må du huske på at små og store bokstaver behandles som samme tegn. Hvis du leter etter en HVIS OG-formel som skiller mellom store og små bokstaver, pakk inn ett eller flere argumenter for OG inn i EKSAKT-funksjonen slik det gjøres i det koblede eksemplet.

Nå som du kjenner syntaksen til Excel IF AND-setningen, la meg vise deg hva slags oppgaver den kan løse.

Excel IF: større enn AND mindre enn

I forrige eksempel testet vi to forhold i to forskjellige celler. Men noen ganger må du kanskje kjøre to eller flere tester på samme celle. Et typisk eksempel er å sjekke om en celleverdi er mellom to tall . Excel IF AND-funksjonen kan også enkelt gjøre det!

La oss si at du har noen salgstall i kolonne B og du blir bedt om å flagge beløp som er større enn $50, men mindre enn $100. For å få det gjort, sett inn denne formelen i C2 og kopier den ned i kolonnen:

=IF(AND(B2>50, B2<100), "x", "")

Hvis du må inkludere grensen verdier (50 og 100), bruk operatoren mindre enn eller lik (<=) og større enn eller lik (>=):

=IF(AND(B2>=50, B2<=100), "x", "")

For å behandle noe annetgrenseverdier uten å endre formelen, skriv inn minimums- og maksimumstallene i to separate celler og referer til disse cellene i formelen din. For at formelen skal fungere riktig i alle radene, pass på å bruke absolutte referanser for grensecellene ($F$1 og $F$2 i vårt tilfelle):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Ved å bruke en lignende formel kan du sjekke om en dato faller innenfor et spesifisert område .

La oss for eksempel flagge datoer mellom 10 -sep-2018 og 30-sep-2018, inkludert. En liten hindring er at datoer ikke kan leveres direkte til de logiske testene. For at Excel skal forstå datoene, bør de være vedlagt i DATOVERDI-funksjonen, slik:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Eller bare skriv inn Fra og Til datoer i to celler ($F$1 og $F$2 i dette eksemplet) og "trekk" dem fra disse cellene ved å bruke den allerede kjente HVIS OG-formelen:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

For mer informasjon, se Excel IF-setning mellom to tall eller datoer.

HVIS dette OG det, så regn ut noe

Bortsett fra å returnere forhåndsdefinerte verdier, Excel IF OG-funksjonen kan også utføre forskjellige beregninger avhengig av om de spesifiserte betingelsene er SANN eller FALSK.

For å demonstrere tilnærmingen vil vi beregne en bonus på 5 % for "Lukket" salg med beløpet større enn eller likt til $100.

Forutsatt at beløpet er i kolonne B og ordrestatus i kolonne C,formelen går som følger:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Formelen ovenfor tildeler null til resten av ordrene ( verdi_hvis_falsk = 0) . Hvis du er villig til å gi en liten stimulerende bonus, for eksempel 3 %, til bestillinger som ikke oppfyller betingelsene, ta med den tilsvarende ligningen i verdi_hvis_falsk -argumentet:

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Flere IF AND-setninger i Excel

Som du kanskje har lagt merke til, har vi kun evaluert to kriterier i alle eksemplene ovenfor. Men det er ingenting som hindrer deg i å inkludere tre eller flere tester i IF AND-formlene dine så lenge de overholder disse generelle begrensningene for Excel:

• I Excel 2007 og høyere, opptil 255 argumenter kan brukes i en formel, med en total formellengde som ikke overstiger 8192 tegn.
• I Excel 2003 og lavere er ikke mer enn 30 argumenter tillatt, med en totallengde på ikke over 1024 tegn.

Som et eksempel på flere OG-betingelser, bør du vurdere disse:

• Beløp (B2) skal være større enn eller lik $100
• Ordrestatus (C2) er "Stengt"
• Leveringsdato (D2) er innenfor gjeldende måned

Nå trenger vi en HVIS OG-erklæring for å identifisere bestillingene der alle 3 betingelsene er SANN. Og her er den:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

Gitt at den "gjeldende måneden" i skrivende stund var oktober, gir formelen følgende resultater:

Nestet HVIS OGutsagn

Når du arbeider med store regneark, er sjansen stor for at du kan bli bedt om å sjekke noen sett med forskjellige OG-kriterier om gangen. For dette tar du en klassisk Excel nestet IF-formel og utvider dens logiske tester med AND-setninger, slik:

For å få den generelle ideen, vennligst se på følgende eksempel.

Forutsatt at du vil vurdere tjenesten din basert på forsendelseskostnaden og estimert leveringstid (ETD):

• Utmerket : forsendelseskostnad under $20 og ETD under 3 dager
• Dårlig : forsendelseskostnader over $30 og ETD over 5 dager
• Gjennomsnitt : alt i mellom

Til få det gjort, skriver du to individuelle IF AND-utsagn:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

...og legger den ene inn i den andre:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

Resultatet vil se ut som dette:

Flere formeleksempler kan finnes i Excel nestede IF AND-setninger.

Skill mellom store og små bokstaver IF AND funksjon i Excel

Som nevnt i begynnelsen av denne opplæringen, skiller ikke Excel IF AND-formler mellom store og små bokstaver fordi OG-funksjonen ikke skiller mellom store og små bokstaver av natur.

Hvis du arbeider med store og små bokstaver data og ønsker å evaluere AND-forhold under hensyntagen til store og små bokstaver, gjør hver enkelt logisk test inne i EXACT-funksjonen og nestedisse funksjonene i AND-setningen din:

For dette eksempelet skal vi flagge bestillinger fra en spesifikk kunde (f.eks. selskapet som heter Cyberspace ) med et beløp som overstiger et visst antall, for eksempel $100.

Som du kan se i skjermbildet nedenfor, ser noen firmanavn i kolonne B ut på samme utdrag som bokstaver, og likevel er de forskjellige firmaer, så vi må sjekke navnene nøyaktig . Beløpene i kolonne C er tall, og vi kjører en vanlig "større enn"-test for dem:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

For å gjøre formelen mer fleksibel, kan du angi målkundenavnet og beløpet i to separate celler og referer til disse cellene. Bare husk å låse cellereferansene med $-tegn ($G$1 og $G$2 i vårt tilfelle), slik at de ikke endres når du kopierer formelen til andre rader:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Nå kan du skrive inn hvilket som helst navn og beløp i de refererte cellene, og formelen vil flagge de tilsvarende ordrene i tabellen din:

HVIS ELLER OG formel i Excel

I Excel IF-formler er du ikke begrenset til kun å bruke én logisk funksjon. For å sjekke ulike kombinasjoner av flere forhold, står du fritt til å kombinere HVIS, OG, ELLER og andre funksjoner for å kjøre de nødvendige logiske testene. Her er et eksempel på HVIS OG ELLER-formel som tester et parELLER-betingelser innenfor OG. Og nå skal jeg vise deg hvordan du kan gjøre to eller flere OG-tester i OR-funksjonen.

Anta at du ønsker å merke bestillingene til to kunder med et beløp som er større enn et visst tall, for eksempel $100.

I Excel-språket uttrykkes våre betingelser på denne måten:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

Forutsatt at kundenavnene er i kolonne B, beløp i kolonne C, de 2 målnavnene er i G1 og G2, og målbeløpet er i G3, bruker du denne formelen for å merke de tilsvarende ordrene med "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

De samme resultatene kan oppnås med en mer kompakt syntaks:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Er du ikke sikker på at du helt forstår formelens logikk? Mer informasjon finner du i Excel HVIS med flere OG/ELLER-betingelser.

Det er slik du bruker HVIS- og OG-funksjonene sammen i Excel. Takk for at du leser og ses neste uke!

Øvningsarbeidsbok

IF AND Excel – formeleksempler (.xlsx-fil)