Tutorial menunjukkan cara menggunakan formula VLOOKUP dalam Excel untuk membandingkan dua lajur untuk mengembalikan nilai biasa (padanan) atau mencari data yang hilang (perbezaan).

Apabila anda mempunyai data dalam dua senarai yang berbeza, anda mungkin sering perlu membandingkannya untuk melihat maklumat yang tiada dalam salah satu senarai atau data yang terdapat dalam kedua-duanya. Perbandingan boleh dilakukan dalam pelbagai cara - kaedah mana yang hendak digunakan bergantung pada perkara yang anda inginkan daripadanya.

Cara membandingkan dua lajur dalam Excel menggunakan VLOOKUP

Apabila anda mempunyai dua lajur data dan ingin mengetahui titik data dari satu senarai yang wujud dalam senarai yang lain, anda boleh menggunakan fungsi VLOOKUP untuk membandingkan senarai bagi nilai biasa.

Untuk membina formula VLOOKUP dalam senarai tersebut. bentuk asas, inilah yang anda perlu lakukan:

• Untuk lookup_value (argumen pertama), gunakan sel paling atas daripada Senarai 1.
• Untuk table_array (argumen ke-2), bekalkan keseluruhan Senarai 2.
• Untuk col_index_num (argumen ke-3), gunakan 1 kerana terdapat hanya satu lajur dalam tatasusunan.
• Untuk julat_carian (argumen ke-4), tetapkan FALSE - padanan tepat.

Andaikan anda mempunyai nama peserta dalam lajur A (Senarai 1) dan nama mereka yang telah melepasi pusingan kelayakan di ruangan B (Senarai 2). Anda ingin membandingkan 2 senarai ini untuk menentukan peserta dari Kumpulan A yang pergi ke acara utama. Untuk melakukan ini, gunakan yang berikutformula.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

Formula pergi ke sel E2, dan kemudian anda menyeretnya ke bawah melalui seberapa banyak sel kerana terdapat item dalam Senarai 1.

Sila ambil perhatian bahawa table_array dikunci dengan rujukan mutlak ($C$2:$C$9) supaya ia kekal malar apabila anda menyalin formula ke sel di bawah.

Seperti yang anda lihat, nama-nama atlet yang layak muncul dalam lajur E. Bagi peserta yang tinggal, ralat #N/A muncul menunjukkan bahawa nama mereka tidak tersedia dalam Senarai 2.

Menyamar #N/ Ralat

Formula VLOOKUP yang dibincangkan di atas dengan sempurna memenuhi objektif utamanya - mengembalikan nilai sepunya dan mengenal pasti titik data yang hilang. Walau bagaimanapun, ia menyampaikan sekumpulan ralat #N/A, yang mungkin mengelirukan pengguna yang tidak berpengalaman membuatkan mereka berfikir bahawa ada sesuatu yang tidak kena dengan formula.

Untuk menggantikan ralat dengan sel kosong , gunakan VLOOKUP dalam kombinasi dengan fungsi IFNA atau IFERROR dengan cara ini:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Formula kami yang lebih baik mengembalikan rentetan kosong ("") dan bukannya #N/ A. Anda juga boleh mengembalikan teks tersuai anda seperti "Tiada dalam Senarai 2", "Tidak hadir", atau "Tidak tersedia". Contohnya:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

Itulah formula asas VLOOKUP untuk membandingkan dua lajur dalam Excel. Bergantung pada tugas tertentu anda, ia boleh diubah suai seperti ditunjukkan dalam contoh selanjutnya.

Bandingkan dua lajur dalam helaian Excel yang berbeza menggunakan VLOOKUP

Dalam kehidupan sebenar, lajur yang andaperlu membandingkan tidak selalu pada helaian yang sama. Dalam set data kecil, anda boleh cuba mengesan perbezaan secara manual dengan melihat dua helaian bersebelahan.

Untuk mencari dalam lembaran kerja atau buku kerja lain dengan formula, anda perlu menggunakan rujukan luaran. Amalan terbaik ialah mula menaip formula dalam helaian utama anda, kemudian beralih ke lembaran kerja lain dan pilih senarai menggunakan tetikus - rujukan julat yang sesuai akan ditambahkan pada formula secara automatik.

Andaikan Senarai 1 ialah dalam lajur A pada Helaian1 dan senarai 2 adalah dalam lajur A pada Helaian2 , anda boleh membandingkan dua lajur dan mencari padanan menggunakan formula ini:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Untuk mendapatkan maklumat lanjut, sila lihat:

• VLOOKUP daripada helaian lain
• VLOOKUP daripada buku kerja berbeza

Bandingkan dua lajur dan kembalikan nilai sepunya (padanan)

Dalam contoh sebelumnya, kami membincangkan formula VLOOKUP dalam bentuk termudahnya:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Hasil formula itu ialah senarai nilai yang wujud dalam kedua-dua lajur dan sel kosong sebagai ganti nilai yang tidak tersedia dalam lajur kedua.

Untuk mendapatkan senarai nilai biasa tanpa jurang, cuma tambah penapis automatik pada lajur yang terhasil dan tapis kosong.

Dalam Excel untuk Microsoft 365 dan Excel 2021 yang menyokong tatasusunan dinamik, anda boleh menggunakan fungsi FILTER untuk menapis kosong secara dinamik. Untuk ini, gunakan formula IFNA VLOOKUP sebagaikriteria untuk PENAPIS:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

Sila ambil perhatian bahawa dalam kes ini kami membekalkan keseluruhan Senarai 1 (A2:A14) kepada argumen lookup_value VLOOKUP. Fungsi membandingkan setiap nilai carian dengan Senarai 2 (C2:C9) dan mengembalikan tatasusunan padanan dan ralat #N/A yang mewakili nilai yang tiada. Fungsi IFNA menggantikan ralat dengan rentetan kosong dan menyajikan hasilnya kepada fungsi FILTER, yang menapis kosong ("") dan mengeluarkan tatasusunan padanan sebagai hasil akhir.

Sebagai alternatif, anda boleh menggunakan fungsi ISNA untuk menyemak hasil VLOOKUP dan menapis item yang dinilai kepada FALSE, iaitu nilai selain daripada ralat #N/A:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

Hasil yang sama boleh dicapai dengan fungsi XLOOKUP, yang menjadikan formula lebih mudah. Disebabkan oleh keupayaan XLOOKUP untuk mengendalikan ralat #N/A secara dalaman (argumen jika_tidak_ditemui pilihan), kita boleh lakukan tanpa pembungkus IFNA atau ISNA:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

Bandingkan dua lajur dan cari nilai yang hilang (perbezaan)

Untuk membandingkan 2 lajur dalam Excel untuk mencari perbezaan, anda boleh meneruskan dengan cara ini:

1. Tulis formula teras untuk mencari yang pertama nilai daripada Senarai 1 (A2) dalam Senarai 2 ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. Sarangkan formula di atas dalam fungsi ISNA untuk menyemak output VLOOKUP untuk ralat #N/A. Sekiranya berlaku ralat, ISNA menghasilkan BENAR, sebaliknya SALAH:

   ISNA(VLOOKUP(A2,$C$2:$C$9, 1, FALSE))

3. Gunakan formula ISNA VLOOKUP untuk ujian logik fungsi IF. Jika ujian menilai kepada BENAR (#N/A ralat), kembalikan nilai daripada Senarai 1 dalam baris yang sama. Jika ujian menilai kepada FALSE (padanan dalam Senarai 2 ditemui), kembalikan rentetan kosong.

Formula lengkap menggunakan borang ini:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Untuk menghilangkan kekosongan, gunakan Penapis Excel seperti yang ditunjukkan dalam contoh di atas.

Dalam Excel 365 dan Excel 2021, anda boleh menapis senarai hasil secara dinamik. Untuk ini, letakkan formula ISNA VLOOKUP dalam argumen include fungsi FILTER:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Cara lain ialah dengan gunakan XLOOKUP untuk kriteria - fungsi mengembalikan rentetan kosong ("") untuk titik data yang hilang dan anda menapis nilai dalam Senarai 1 yang XLOOKUP mengembalikan rentetan kosong (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

Formula VLOOKUP untuk mengenal pasti padanan dan perbezaan antara dua lajur

Jika anda ingin menambah label teks pada senarai pertama yang menunjukkan nilai mana yang tersedia dalam senarai kedua dan yang tidak, gunakan formula VLOOKUP bersama-sama dengan IF dan ISNA/ISERROR berfungsi.

Contohnya, untuk mengenal pasti nama yang terdapat dalam kedua-dua lajur A dan D serta nama yang terdapat dalam lajur A sahaja, formulanya ialah:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")

Di sini, fungsi ISNA menangkap ralat #N/A yang dijana oleh VLOOKUP dan menghantar hasil perantaraan itu kepada fungsi IF untuknyakembalikan teks yang ditentukan untuk ralat dan teks lain untuk carian yang berjaya.

Dalam contoh ini, kami menggunakan label "Tidak layak"/"Layak", yang sesuai untuk set data sampel kami. Anda boleh menggantikannya dengan "Tiada dalam Senarai 2"/"Dalam Senarai 2", "Tidak tersedia"/"Tersedia" atau mana-mana label lain yang anda rasa sesuai.

Formula ini paling sesuai untuk dimasukkan dalam lajur bersebelahan dengan Senarai 1 dan disalin melalui seberapa banyak sel yang terdapat dalam senarai anda.

Satu lagi cara untuk mengenal pasti padanan dan perbezaan dalam 2 lajur ialah menggunakan fungsi MATCH:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

Bandingkan 2 lajur dan kembalikan nilai daripada ketiga

Apabila bekerja dengan jadual yang mengandungi data berkaitan, kadangkala anda mungkin perlu bandingkan dua lajur dalam dua jadual berbeza dan kembalikan nilai yang sepadan daripada lajur lain. Sebenarnya, ini adalah penggunaan utama fungsi VLOOKUP, tujuan ia direka bentuk.

Sebagai contoh, untuk membandingkan nama dalam lajur A dan D dalam dua jadual di bawah dan mengembalikan masa dari lajur E , formulanya ialah:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Untuk menyembunyikan ralat #N/A, gunakan penyelesaian yang terbukti - fungsi IFNA:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

Daripada kosong, anda boleh mengembalikan mana-mana teks yang anda mahukan kerana titik data yang hilang - hanya taipkannya dalam hujah terakhir. Contohnya:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")

Selain VLOOKUP, tugasan itu boleh dipenuhi dengan beberapa fungsi carian lain.

Secara peribadi, saya akan bergantung pada INDEX yang lebih fleksibelFormula MATCH:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Atau gunakan pengganti moden VLOOKUP - fungsi XLOOKUP, tersedia dalam Excel 365 dan Excel 2021:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Kepada dapatkan nama peserta yang layak daripada kumpulan A dan keputusan mereka, cuma tapis sel kosong dalam lajur B:

=FILTER(A3:B15, B3:B15"")

Alat perbandingan

Jika anda kerap membuat perbandingan fail atau data dalam Excel, alatan pintar yang disertakan dalam Suite Ultimate kami boleh menjimatkan masa anda dengan sangat baik!

Bandingkan Jadual - cara cepat untuk mencari pendua (padanan) dan nilai unik (perbezaan) dalam mana-mana dua set data seperti lajur, senarai atau jadual.

Bandingkan Dua Helaian - cari dan serlahkan perbezaan antara dua helaian kerja.

Bandingkan Berbilang Helaian - cari dan serlahkan perbezaan dalam berbilang helaian sekaligus .

Amalkan buku kerja untuk muat turun

VLOOKUP dalam Excel untuk membandingkan lajur - contoh (fail.xlsx)