على الرغم من استخدام عدد الكلمات والحروف في جداول بيانات Google في حالات نادرة ، إلا أنها لا تزال الوظيفة التي يتوقع البعض منا رؤيتها مباشرة في القائمة. ولكن بخلاف محرر مستندات Google ، بالنسبة لجداول بيانات Google ، فإن وظيفة LEN هي التي تقوم بذلك.

على الرغم من وجود العديد من الطرق المختلفة لحساب الأحرف في جداول البيانات ، فإن منشور المدونة اليوم سيغطي وظيفة LEN باعتبارها الغرض الرئيسي في الجداول هو - حسنًا ، العد :) ومع ذلك ، نادرًا ما يتم استخدامه بمفرده. أدناه سوف تتعلم كيفية استخدام Google Sheets LEN بشكل صحيح والعثور على الصيغ الأكثر طلبًا لحساب الأحرف في جداول البيانات.

وظيفة أوراق Google LEN - الاستخدام وبناء الجملة

الرئيسي والغرض الوحيد من وظيفة LEN في جداول بيانات Google هو الحصول على طول السلسلة. إنه بسيط للغاية لدرجة أنه لا يتطلب سوى وسيطة واحدة:

• يمكن أن يأخذ النص نفسه بين علامتي اقتباس:

  =LEN("Yggdrasil")

• أو مرجع لخلية مع نص الاهتمام:

  =LEN(A2)

دعونا نرى ما إذا كانت هناك أي خصائص مميزة في استخدام الوظيفة في جداول البيانات.

الحرف العد في جداول بيانات Google

سأبدأ بأبسط عملية: قم بحساب عدد الأحرف في جداول بيانات Google بالطريقة الأكثر شيوعًا - عن طريق الرجوع إلى خلية بالنص باستخدام وظيفة LEN.

أنا أدخل الصيغة إلى B2 وانسخها أسفل العمود بأكمله لحساب عدد الأحرف في كل صف:

=LEN(A2)

ملاحظة. وظيفة LENيحسب جميع الأحرف: الأحرف ، والأرقام ، والمسافات ، وعلامات الترقيم ، وما إلى ذلك.

قد تعتقد أنه بطريقة مماثلة يمكنك حساب عدد الأحرف لنطاق الخلايا بالكامل ، مثل هذا: LEN(A2:A6) . ولكن ، مثل على الرغم من كونها غريبة ، فهي لا تعمل بهذه الطريقة.

لإجمالي الأحرف في عدة خلايا ، يجب عليك التفاف LEN في SUMPRODUCT - الوظيفة التي تقوم بإحصاء الأرقام من النطاقات التي تم إدخالها. في حالتي ، يتم إرجاع النطاق بواسطة دالة LEN:

=SUMPRODUCT(LEN(A2:A6))

بالطبع ، يمكنك دمج دالة SUM بدلاً من ذلك. لكن SUM في Google Sheets لا يعالج المصفوفات من الوظائف الأخرى. لجعلها تعمل ، سيتعين عليك إضافة وظيفة أخرى - ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

كيفية حساب الأحرف بدون مسافات في Google Sheets

كما أشرت أعلاه ، Google Sheets تحسب الدالة LEN كل حرف تشاهده بما في ذلك المسافات.

ولكن ماذا لو تمت إضافة مسافات إضافية عن طريق الخطأ ولا تريد اعتبارها للنتيجة؟

لحالات مثل هذا ، هناك وظيفة TRIM في جداول بيانات Google. يقوم بفحص النص بحثًا عن مسافات بادئة ولاحقة ومتكررة بين السطور. عندما يقترن TRIM بـ LEN ، فإن الأخير لا يحسب كل تلك المسافات الفردية.

إليك مثال. لقد أضفت مسافات في مواضع مختلفة في العمود A. كما ترى ، عندما تقوم بمفردها ، تقوم Google Sheets LEN بحسابها جميعًا:

=LEN(A2)

ولكن بمجرد دمج TRIM ، كل شيء إضافي المساحاتتم التجاهل:

=LEN(TRIM(A2))

يمكنك الذهاب أبعد من ذلك وجعل الصيغة تتجاهل حتى تلك المسافات المفردة بين الكلمات. ستساعد وظيفة الاستبدال. على الرغم من أن الغرض الرئيسي منه هو استبدال حرف بآخر ، إلا أن هناك حيلة لجعله يقلل المسافات تمامًا:> هو النطاق الذي تعمل معه: العمود A ، أو A2 على وجه الدقة.

الآن حاول تجميع كل هذه العناصر في جداول بيانات Google LEN وسترى ذلك لم يتم أخذ أي مسافة في الاعتبار:

=LEN(SUBSTITUTE(A2, " ", ""))

Google Sheets: حساب أحرف معينة

يتم استخدام نفس ترادف Google Sheets LEN و SUBSTITUTE كلما احتجت إلى حساب أحرف معينة أو الأحرف أو الأرقام.

في الأمثلة الخاصة بي ، سأكتشف عدد مرات ظهور الحرف 's'. وهذه المرة ، سأبدأ بصيغة جاهزة:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

دعونا نقسمها إلى أجزاء لفهم كيفية ذلكيعمل:

1. SUBSTITUTE (A2، "s"، "") يبحث عن الحرف في A2 ويستبدل جميع التكرارات بـ "لا شيء" ، أو سلسلة فارغة ( "").
2. LEN (SUBSTITUTE (A2، "s"، "") يحسب عدد جميع الأحرف ماعدا 's في A2.
3. LEN (A2) يحسب جميع الأحرف في A2.
4. أخيرًا ، تطرح واحدًا من الآخر.

يظهر اختلاف النتيجة عدد الأحرف الموجودة في الخلية:

ملاحظة. قد تتساءل لماذا تقول B1 أن هناك 1 's' فقط في A2 بينما يمكنك رؤية 3؟

الشيء هو ، وظيفة SUBSTITUTE حساسة لحالة الأحرف. لقد طلبت منه أن يأخذ جميع مثيلات 's' بأحرف صغيرة وهكذا فعلت.

لجعله يتجاهل حالة النص ويعالج الأحرف في كل من الحالات الصغيرة والكبيرة ، سيتعين عليك استدعاء وظيفة أخرى في جداول بيانات Google للحصول على مساعدة: LOWER.

نصيحة. اطلع على طرق أخرى لتغيير حالة النص في جداول بيانات Google.

الأمر بسيط مثل Google Sheets LEN و TRIM لأن كل ما يتطلبه هو النص:

=LOWER(text)

وكل ما يفعله هو قلب سلسلة النص بالكامل int س الأحرف الصغيرة. هذه الحيلة هي بالضبط ما تحتاجه لجعل جداول بيانات Google تحسب أحرفًا معينة بغض النظر عن حالة النص:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

نصيحة. وكما في السابق ، لحساب إجمالي عدد الأحرف المحددة في النطاق ، قم بلف LEN في SUMPRODUCT:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

عد الكلمات في جداول بيانات Google

عندما يكون هناك هي كلمات متعددة في الخلايا ، فمن المحتمل أنك ستحتاج إلى الحصول على رقمها بدلاً منطول سلسلة أوراق Google.

وعلى الرغم من وجود طرق متعددة للقيام بذلك ، سأذكر اليوم كيف تؤدي Google Sheets LEN المهمة.

تذكر الصيغة التي استخدمتها لحساب أحرف معينة في أوراق جوجل؟ في الواقع ، سيكون مفيدًا هنا أيضًا. لأنني لن أحسب الكلمات حرفيا. بدلاً من ذلك ، سأحسب عدد المسافات بين الكلمات ثم أضف 1. إلقاء نظرة:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN (A2) تحسب عدد كل الأحرف في الخلية.
2. LEN (SUBSTITUTE ((A2)، ""، "")) يزيل كل المسافات من السلسلة النصية ويحتسب الأحرف المتبقية.
3. ثم تطرح واحدة من الأخرى ، والفرق الذي تحصل عليه هو عدد المسافات في الخلية.
4. نظرًا لأن الكلمات دائمًا تفوق عدد المسافات في جملة واحدة ، فأنت تضيف 1 في النهاية.

جداول بيانات Google: عد كلمات معينة

أخيرًا ، أود مشاركة صيغة جداول بيانات Google التي يمكنك استخدامها لحساب كلمات معينة.

هنا لدي أغنية The Mock Turtle من مغامرات أليس في بلاد العجائب:

أريد أن أعرف عدد مرات ظهور كلمة "will" في كل صف. أعتقد أنك لن تتفاجأ إذا أخبرتك أن الصيغة التي أحتاجها تتكون من نفس الوظائف كما في السابق: أوراق Google LEN و SUBSTITUTE و LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

قد تكون الصيغة تبدو مخيفًا ولكن يمكنني أن أؤكد لك أنه من السهل فهمها ، لذا تحمل معي :)

1. نظرًا لأن حالة النص لايهمني ، أستخدم LOWER (A2) لتحويل كل شيء إلى أحرف صغيرة.
2. ثم ينتقل SUBSTITUTE (LOWER (A2)، "will"، ""))) - يتخلص من جميع تكرارات "will" عن طريق استبدالها بسلاسل فارغة ("").
3. بعد ذلك ، أطرح عدد الأحرف بدون كلمة "will" من إجمالي طول السلسلة . الرقم الذي أحصل عليه يحسب جميع الأحرف في جميع تكرارات "الإرادة" في كل صف.

   وبالتالي ، إذا ظهرت كلمة "will" مرة واحدة ، فسيكون الرقم 4 حيث يوجد 4 أحرف في الكلمة. إذا ظهر مرتين ، يكون الرقم 8 وهكذا.

4. أخيرًا ، أقسم هذا الرقم على طول الكلمة المفردة "will".

نصيحة. ومرة أخرى ، إذا كنت تفضل الحصول على العدد الإجمالي لجميع مظاهر كلمة "will" ، فما عليك سوى إرفاق الصيغة بأكملها بواسطة SUMPRODUCT:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

كما ترى ، يتم حل جميع حالات عدد الأحرف هذه من خلال الأنماط نفسها من الوظائف نفسها لجداول بيانات Google: LEN و SUBSTITUTE و LOWER و SUMPRODUCT.

إذا كانت بعض الصيغ لا تزال تربكك أو إذا لم تكن كذلك تأكد من كيفية تطبيق كل شيء على مهمتك الخاصة ، لا تخجل واسأل في قسم التعليقات أدناه!