Oʻquv qoʻllanmada Excel 365ʼda qatorlarni siz koʻrsatgan har qanday ajratuvchi boʻyicha ajratish uchun yangi TEXTSPLIT funksiyasidan qanday foydalanish koʻrsatilgan.

Ajratish kerak boʻlganda turli vaziyatlar boʻlishi mumkin. Exceldagi hujayralar. Oldingi versiyalarda biz allaqachon ustunlarga matn va Flashni to'ldirish kabi vazifani bajarish uchun bir qator asboblar bilan jihozlangan edik. Endi bizda buning uchun TEXTSPLIT maxsus funksiyasi ham mavjud boʻlib, u siz koʻrsatgan parametrlar asosida qatorni ustunlar va/yoki qatorlar boʻylab bir nechta kataklarga ajratishi mumkin.

Excel TEXTSPLIT funksiyasi

Excel'dagi TEXTSPLIT funksiyasi matn satrlarini ustunlar va/yoki satrlar bo'yicha ma'lum ajratuvchi bilan ajratadi. Natijada bir nechta katakchalarga avtomatik ravishda to‘kilib ketadigan dinamik massiv hosil bo‘ladi.

Funksiya 6 ta argumentni oladi, ulardan faqat birinchi ikkitasi talab qilinadi.

TEXTSPLIT(matn, chiziq_delimiter, [satr_delimiter], [bo'sh_etmaslik], [match_rejimi], [pad_with])

matn (majburiy) - bo'linadigan matn. Satr yoki yacheyka havolasi sifatida taqdim etilishi mumkin.

col_delimiter (majburiy) - matnni ustunlar boʻylab qayerga boʻlish kerakligini koʻrsatuvchi belgi(lar). Agar o'tkazib yuborilsa, satr_ajragich belgilanishi kerak.

satr_ajragich (ixtiyoriy) - matnni satrlar bo'ylab qayerga bo'lish kerakligini ko'rsatadigan belgi(lar).

ignore_empty (ixtiyoriy) - bo'sh qiymatlarni e'tiborsiz qoldirish yoki qilmaslikni belgilaydi:

• FALSE (standart) -oraliq qiymatsiz ketma-ket ajratuvchilar uchun bo'sh katakchalar yarating.
• TRUE - bo'sh qiymatlarni e'tiborsiz qoldiring, ya'ni ikki yoki undan ortiq ketma-ket ajratuvchilar uchun bo'sh katakchalar yaratmang.

match_mode (ixtiyoriy) - ajratuvchi uchun katta-kichik harf sezgirligini aniqlaydi. Sukut bo'yicha yoqilgan.

• 0 (standart) - katta-kichik harflarni sezgir
• 1 - katta-kichik harflarni sezmaydi

pad_with (ixtiyoriy ) - ikki o'lchovli massivlarda etishmayotgan qiymatlar o'rniga foydalanish uchun qiymat. Sukut boʻyicha #Yoʻq xato.

Masalan, A2 formatidagi matn qatorini vergul va boʻsh joydan ajratuvchi sifatida bir nechta katakchalarga boʻlish uchun formula quyidagicha:

=TEXTSPLIT(A2, ", ")

TEXTSPLIT mavjudligi

TEXTSPLIT funksiyasi faqat Microsoft 365 (Windows va Mac) uchun Excel va Internet uchun Excel-da mavjud.

Maslahatlar:

• TEXTSPLIT funksiyasi mavjud bo'lmagan Excel versiyalarida (Excel 365 dan tashqari) siz hujayralarni bo'lish uchun Matnni Ustunlarga o'tkazish ustasidan foydalanishingiz mumkin.
• Teskari vazifani bajarish, ya'ni tarkibiga qo'shilish uchun. ma'lum bir ajratuvchi yordamida bir nechta katakchalarni bittaga birlashtiring, TEXTJOIN funksiyasidan foydalaniladi.

Excel'da katakchani bo'lish uchun asosiy TEXTSPLIT formulasi

Yangi boshlanuvchilar uchun TEXTSPLITdan qanday foydalanishni ko'rib chiqamiz. Matn qatorini ma'lum bir cheklovchiga bo'lish uchun eng oddiy formuladan foydalaning.

Hujayrani gorizontal ravishda ustunlar bo'ylab ajratish

Ma'lum bir katak tarkibini bir nechta ustunlarga bo'lish uchunbirinchi ( matn ) argument uchun asl qatorni va ikkinchi ( col_delimiter ) argument uchun boʻlinish sodir boʻlishi kerak boʻlgan nuqtani belgilovchi ajratuvchini oʻz ichiga olgan katakka havola.

Masalan, A2 dagi satrni gorizontal ravishda vergul bilan ajratish uchun quyidagi formula bo'ladi:

=TEXTSPLIT(A2, ",")

Ajratish uchun biz qo'sh tirnoq ichiga olingan verguldan foydalanamiz ("") .

Natijada vergul bilan ajratilgan har bir element alohida ustunga o'tadi:

Yacheykani vertikal ravishda qatorlar bo'ylab ajratish

Matnni bir nechta satrlarga bo'lish uchun uchinchi argument ( satr_delimiter ) chegaralovchini joylashtirgan joy. Bu holda ikkinchi argument ( col_delimiter ) o'tkazib yuboriladi.

Masalan, A2 dagi qiymatlarni turli qatorlarga ajratish uchun formula:

=TEXTSPLIT(A2, ,",")

E'tibor bering, ikkala holatda ham formula faqat bitta katakka (C2) kiritiladi. Qo'shni hujayralarda qaytarilgan qiymatlar avtomatik ravishda to'kiladi. Olingan massiv (to'kilmasin diapazoni deb ataladi) ko'k chegara bilan ajratib ko'rsatiladi, bu uning ichidagi hamma narsa yuqori chap katakdagi formula bo'yicha hisoblanganligini bildiradi.

Matnni pastki qatorga bo'lish

In ko'p hollarda manba qatoridagi qiymatlar belgilar ketma-ketligi bilan ajratiladi, vergul va bo'sh joy odatiy misoldir. Ushbu stsenariyni boshqarish uchun ajratuvchi uchun pastki qatordan foydalaning.

Masalan, A2 formatidagi matnni bir nechta ustunlarga ajratish uchunvergul va bo'sh joy qo'yib, col_delimiter uchun ", " qatoridan foydalaning.

=TEXTSPLIT(A2, ", ")

Ushbu formula B2 ga o'tadi va keyin uni shuncha ko'pdan nusxa ko'chirasiz kerak bo'lganda hujayralar.

Stringni bir vaqtning o'zida ustunlar va satrlarga bo'lish

Matn qatorini bir vaqtning o'zida qator va ustunlarga bo'lish uchun TEXTSPLIT formulangizda ikkala chegaralovchini belgilang.

Masalan, A2 formatidagi matn qatorini ustunlar va satrlarga bo'lish uchun biz quyidagilarni beramiz:

• Teng belgisi ("=") col_delimiter
• Vergul va a satr_ajragich

uchun bo'sh joy (", ") To'liq formula quyidagi shaklni oladi:

=TEXTSPLIT(A2, "=", ", ")

Natija 2-D 2 ustun va 3 qatordan iborat massiv:

Yacheykalarni bir nechta ajratuvchilar bilan ajratish

Manba qatorida bir nechta yoki nomuvofiq chegaralovchilarni boshqarish uchun {"x","y" kabi massiv doimiysidan foydalaning. ,"z"} ajratuvchi argument uchun.

Quyidagi skrinshotda A2 formatidagi matn vergul (",") va nuqta-vergul (";") bilan bo'sh va bo'sh joysiz ajratilgan. Ajratuvchining barcha 4 ta varianti boʻyicha qatorni vertikal ravishda qatorlarga boʻlish uchun formula:

=TEXTSPLIT(A2, , {",",", ",";","; "})

Yoki faqat vergul ("") va nuqtali vergul ("; ") massivda, so'ngra TRIM funksiyasi yordamida qo'shimcha bo'shliqlarni olib tashlang:

=TRIM(TEXTSPLIT(A2, , {",",";"}))

Bo'sh qiymatlarni e'tiborsiz qoldirib, matnni bo'lish

Agar qatorda bo'lsa Ikki yoki undan ortiq ketma-ket ajratuvchilar orasida qiymat bo'lmasa, siz bunday bo'sh joylarga e'tibor bermaslikni tanlashingiz mumkinqadriyatlar yoki yo'q. Ushbu xatti-harakatlar to'rtinchi ignore_empty parametri tomonidan boshqariladi, bu sukut bo'yicha FALSE hisoblanadi.

Sukut bo'yicha TEXTSPLIT funksiyasi bo'sh qiymatlarni e'tiborsiz qoldirmaydi. Standart xatti-harakatlar quyida keltirilgan misoldagi kabi tuzilgan ma'lumotlar uchun yaxshi ishlaydi.

Ushbu namunaviy jadvalda ba'zi qatorlarda ballar yo'q. ignore_empty argumenti o'tkazib yuborilgan yoki FALSE ga o'rnatilgan TEXTSPLIT formulasi bu ishni mukammal tarzda boshqaradi va har bir bo'sh qiymat uchun bo'sh katak yaratadi.

=TEXTSPLIT(A2, ", ")

Yoki

=TEXTSPLIT(A2, ", ", FALSE)

Natijada barcha qiymatlar tegishli ustunlarda paydo bo'ladi.

Agar satrlaringiz bir xil ma'lumotlarni o'z ichiga olgan bo'lsa, bo'sh qiymatlarni e'tiborsiz qoldirish uchun sabab bo'lishi mumkin. Buning uchun ignore_empty argumentini TRUE yoki 1 ga o'rnating.

Masalan, har bir ko'nikmani bo'sh joysiz alohida katakchaga joylashtirgan quyidagi t qatorlarni ajratish uchun formula quyidagicha:

=TEXTSPLIT(A2, ", ", ,TRUE)

Bu holda, ketma-ket ajratuvchilar orasidagi etishmayotgan qiymatlar butunlay e'tiborga olinmaydi:

Hujayra katta-kichik harf sezgir yoki katta-kichik harf sezgir emas

Registrni boshqarish uchun- chegaralovchining sezgirligi, beshinchi argumentdan foydalaning, match_mode .

Sukut bo'yicha, match_mode 0 ga o'rnatilgan bo'lib, TEXTSPLIT katta-kichik harflarni sezgir qiladi .

Ushbu misolda raqamlar kichik "x" va katta "X" harflari bilan ajratilgan.

Birlamchi katta-kichik harf sezgirligiga ega formula faqat "x" kichik harfini qabul qiladi. " kabiajratuvchi:

=TEXTSPLIT(A2, " x ")

Natijalarda oldingi va keyingi boʻshliqlar paydo boʻlishiga yoʻl qoʻymaslik uchun ajratuvchi “ x” harfining ikkala tomonida boʻsh joy mavjudligiga eʼtibor bering.

Harf sezgirligini oʻchirish uchun siz match_mode uchun 1 raqamini kiritasiz, bu esa TEXTSPLIT formulasini harf kattaligiga eʼtibor bermaslikka majbur qiladi:

=TEXTSPLIT(A2, " x ", , ,1)

Endi, hammasi satrlar chegaralovchi tomonidan toʻgʻri ajratilgan:

2D massivida yoʻqolgan qiymatlar

TEXTSPLIT funksiyasining oxirgi argumenti pad_with , bitta yoki manba qatorida ko'proq qiymatlar yo'q. Bunday satr ustunlar va satrlarga bo'linganda, sukut bo'yicha Excel ikki o'lchovli massiv tuzilishini buzmaslik uchun etishmayotgan qiymatlar o'rniga #N/A xatolarini qaytaradi.

Quyidagi satrda, "Baho" dan keyin "=" ( col_delimiter ) mavjud emas. Olingan massivning yaxlitligini saqlash uchun TEXTSPLIT "Score" yonidagi #N/A ni chiqaradi.

Natijani foydalanuvchilar uchun qulayroq qilish uchun #N/A xatosini xohlagan qiymat bilan almashtirishingiz mumkin. Shunchaki, pad_with argumentiga kerakli qiymatni kiriting.

Bizning holatlarimizda bu chiziqcha ("-") bo'lishi mumkin:

=TEXTSPLIT(A2, "=", ", ", , ,"-")

Yoki bo‘sh satr (""):

=TEXTSPLIT(A2, "=", ", ", , ,"")

Endi siz TEXTSPLIT funksiyasining har bir argumentidan amaliy foydalanishni o‘rgandingiz, keling, sizga yordam beradigan bir nechta ilg‘or misollarni muhokama qilaylik. Excel elektron jadvallaridagi ahamiyatsiz muammolarni hal qiling.

Sanalarni ajratishkun, oy va yilga

Sanani alohida birliklarga bo'lish uchun avval sanani matnga aylantirish kerak, chunki TEXTSPLIT funksiyasi matn satrlari bilan ishlaydi, Excel sanalari esa raqamlardir.

Eng osoni. Raqamli qiymatni matnga aylantirish usuli TEXT funksiyasidan foydalanishdir. Sana uchun mos format kodini taqdim etganingizga ishonch hosil qiling.

Bizning holatimizda formula quyidagicha:

=TEXT(A2, "m/d/yyyy")

Keyingi qadam yuqoridagi funksiyani ichiga joylashtirishdir. TEXTSPLIT ning 1-argumentini tanlang va ustunlar yoki satrlarga bo'linayotganingizga qarab 2 yoki 3-argument uchun mos ajratuvchini kiriting. Ushbu misolda sana birliklari qiyshiq chiziq bilan ajratilgan, shuning uchun biz col_delimiter argumenti uchun "/" dan foydalanamiz:

=TEXTSPLIT(TEXT(A2, "m/d/yyyy"), "/")

Hujayralarni bo'lish va ma'lum belgilarni olib tashlash

Tasavvur qiling: siz uzun satrni bo'laklarga bo'ldingiz, lekin natijada paydo bo'lgan massiv hali ham ba'zi keraksiz belgilarni o'z ichiga oladi, masalan, quyidagi skrinshotdagi qavslar:

=TEXTSPLIT(A2, " ", "; ")

O'chirish uchun bir vaqtning o'zida ochilish va yopish qavslaridan tashqari ikkita SUBSTITUTE funksiyasini bir-biriga joylashtiring (har biri bitta qavsni bo'sh satr bilan almashtiradi) va ichki SUBSTITUTEning matn argumenti uchun TEXTSPLIT formulasidan foydalaning:

=SUBSTITUTE(SUBSTITUTE(TEXTSPLIT(A2, " ", "; "), "(", ""), ")", "")

Maslahat. Agar oxirgi massivda juda ko'p qo'shimcha belgilar bo'lsa, ularni ushbu maqolada tasvirlangan usullardan biri yordamida tozalashingiz mumkin: Excelda keraksiz belgilarni qanday olib tashlash mumkin.

Ma'lum qiymatlarni o'tkazib yuboradigan satrlarni ajratish

Agar siz quyidagi satrlarni 4 ta ustunga ajratmoqchi bo'lsangiz: Ism , Familiya , Baho , va Natija . Muammo shundaki, ba'zi satrlarda "janob" sarlavhasi mavjud. yoki "Xonim", shuning uchun natijalar noto'g'ri:

Yechim aniq emas, lekin juda oddiy :)

Mavjud bo'sh joy bo'lgan chegaralovchilarga qo'shimcha ravishda (" ") va vergul va bo'sh joy (", "), siz col_delimiter massiv doimiysiga "Janob" va "Xonim" qatorlarini qo'shasiz, shunda funktsiya sarlavhalarni o'zidan ajratish uchun foydalanadi. matn. Bo'sh qiymatlarni e'tiborsiz qoldirish uchun siz ignore_empty argumentini TRUE qilib o'rnatasiz.

=TEXTSPLIT(A2, {" ",", ","Mr. ","Ms. "}, ,TRUE)

Endi, natijalar mutlaqo mukammal!

TEXTSPLIT muqobillari

TEXTSPLIT funksiyasi qoʻllab-quvvatlanmaydigan Excel versiyalarida siz SEARCH/FIND funksiyasining CHAP, OʻNG va MID bilan turli kombinatsiyalaridan foydalanib qatorlarni ajratishingiz mumkin. Jumladan:

• Buyuk harflarni sezmaydigan QIDIRUV yoki katta-kichik harflarni sezgir FIND qatordagi ajratuvchining oʻrnini aniqlaydi va
• CHAP, OʻNG va MID funksiyalari pastki qatorni ajratadi. , chegaralovchining ikki nusxasidan keyin yoki orasida.

Bizning holimizda vergul va boʻsh joy bilan ajratilgan qiymatlarni ajratish uchun formulalar quyidagicha ketadi.

Ismni chiqarish uchun:

=LEFT(A2, SEARCH(",", A2, 1) -1)

Ballni olish uchun:

=MID(A2, SEARCH(",", A2) + 2, SEARCH(",", A2, SEARCH(",",A2)+1) - SEARCH(",", A2) - 2)

Olish uchunnatija:

=RIGHT(A2, LEN(A2) - SEARCH(",",  A2, SEARCH(",",  A2) + 1)-1)

Formullar mantig'ini batafsil tushuntirish uchun qatorlarni belgi yoki niqob bo'yicha qanday ajratish mumkin bo'limiga qarang.

Iltimos, shuni yodda tutingki, dinamik massivdan farqli o'laroq TEXTSPLIT funktsiyasi, bu formulalar an'anaviy bir formulali bir hujayrali yondashuvga amal qiladi. Siz formulani birinchi katakchaga kiritasiz va uni quyidagi katakchalarga nusxalash uchun ustun bo‘ylab pastga tortasiz.

Quyidagi skrinshotda natijalar ko‘rsatilgan:

Excel 365 da hujayralarni shu tarzda ajratish mumkin. TEXTSPLIT yoki oldingi versiyalarda muqobil echimlar yordamida. O'qiganingiz uchun tashakkur va kelgusi hafta blogimizda ko'rishga umid qilaman!

Yuklab olish uchun mashq kitobi

Stringlarni ajratish uchun TEXTSPLIT funksiyasi – formula misollari (.xlsx fayli)