Opplæringen viser hvordan du sammenligner tekststrenger i Excel for å skille mellom store og små bokstaver og nøyaktig samsvar. Du vil lære en rekke formler for å sammenligne to celler etter deres verdier, strenglengde eller antall forekomster av et bestemt tegn, samt hvordan du sammenligner flere celler.

Når du bruker Excel for dataanalyse, er nøyaktighet den viktigste bekymringen. Feil informasjon fører til tapte tidsfrister, feilvurderte trender, feil beslutninger og tapte inntekter.

Selv om Excel-formler alltid er helt sanne, kan resultatene deres være feil fordi noen feilaktige data har trengt inn i systemet. I dette tilfellet er den eneste løsningen å sjekke data for nøyaktighet. Det er ingen stor sak å sammenligne to celler manuelt, men det er nesten umulig å se forskjellene mellom hundrevis og tusenvis av tekststrenger.

Denne opplæringen vil lære deg hvordan du automatiserer den kjedelige og feilutsatte oppgaven med celle sammenligning og hvilke formler som er best å bruke i hvert enkelt tilfelle.

Hvordan sammenligne to celler i Excel

Det er to forskjellige måter å sammenligne strenger i Excel avhengig av om du søker sammenligning mellom små og store bokstaver.

Stilling uten store og små bokstaver for å sammenligne 2 celler

For å sammenligne to celler i Excel uten store og små bokstaver, bruk en enkel formel som denne:

=A1=B1

Hvor A1 og B1 er cellene du sammenligner. Resultatet av formelen er boolske verdier TRUEog FALSE.

Hvis du vil skrive ut dine egne tekster for treff og forskjeller, bygg inn setningen ovenfor i den logiske testen av HVIS-funksjonen. For eksempel:

=IF(A1=B1, "Equal", "Not equal")

Som du ser i skjermbildet nedenfor, sammenligner begge formlene tekststrenger, datoer og tall like godt:

Stillingssensitiv formel for å sammenligne strenger i Excel

I noen situasjoner kan det være viktig ikke bare å sammenligne tekstverdier for to celler, men også å sammenligne store og små bokstaver. Størrelsessensitiv tekstsammenligning kan gjøres ved å bruke Excel EXACT-funksjonen:

Hvor tekst1 og tekst2 er de to cellene du sammenligner.

Forutsatt at strengene dine er i cellene A2 og B2, går formelen som følger:

=EXACT(A2, B2)

Som resultatet får du TRUE for tekststrenger som samsvarer nøyaktig inkludert store og små bokstaver for hvert tegn, FALSE ellers.

Hvis du vil at EXACT-funksjonen skal levere noen andre resultater, kan du bygge den inn i en IF-formel og skrive inn din egen tekst for value_if_true og value_if_false argumenter:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Følgende skjermbilde viser resultatene av den store og små bokstavssensitive strengsammenligningen i Excel:

Hvordan sammenligne flere celler i Excel

For å sammenligne mer enn 2 celler på rad, bruk formlene diskutert i eksemplene ovenfor i kombinasjon med OG-operatoren. De fullstendige detaljene følger nedenfor.

Stillingsuavhengig formel for å sammenlignemer enn 2 celler

Avhengig av hvordan du vil vise resultatene, bruk en av følgende formler:

=AND(A2=B2, A2=C2)

eller

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

AND-formelen returnerer TRUE hvis alle cellene inneholder samme verdi, FALSE hvis noen verdi er forskjellig. IF-formelen gir ut etikettene du skriver inn i den, " Like " og " Ikke lik " i dette eksemplet.

Som vist i skjermbildet nedenfor, formel fungerer perfekt med alle datatyper - tekst, datoer og numeriske verdier:

Stillingssensitiv formel for å sammenligne tekst i flere celler

For å sammenligne flere strenger til hverandre for å se om de samsvarer nøyaktig, bruk følgende formler:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Eller

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Som i forrige eksempel, den første formelen gir TRUE og FALSE-verdier, mens den andre viser dine egne tekster for samsvar og forskjeller:

Sammenlign et celleområde med en prøvecelle

Følgende eksempler viser hvordan du kan verifisere at alle celler i et gitt område inneholder samme tekst som i en prøvecelle.

Stillingsuavhengig formel for å sammenligne celler med en prøvetekst

Hvis store og små bokstaver spiller ingen rolle, du kan bruke følgende formel for å sammenligne celler med en prøve:

I den logiske testen av HVIS-funksjonen sammenligner du to tall:

• Totalt antall celleri et spesifisert område (antall rader multiplisert med antall kolonner), og
• Antall celler som inneholder samme verdi som i prøvecellen (returnert av COUNTIF-funksjonen).

Forutsatt at eksempelteksten er i C2 og strengene som skal sammenlignes er i området A2:B6, går formelen som følger:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

For å gjøre resultatene mer bruker- vennlig, dvs. gi noe som "Alle samsvarer" og "Ikke alle samsvarer" i stedet for SANN og FALSE, bruk HVIS-funksjonen som vi gjorde i de forrige eksemplene:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Som vist på skjermbildet ovenfor, takler formelen perfekt en rekke tekststrenger, men den kan også brukes til å sammenligne tall og datoer.

Stillingsensitiv formel for å sammenligne strenger med en eksempeltekst

Hvis store og små bokstaver utgjør en forskjell, kan du sammenligne strenger med eksempelteksten ved å bruke følgende matriseformler.

Med kildeområdet i A2:B6 og eksempelteksten i C2, har formelen følgende form:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

I motsetning til vanlige Excel-formler , fullføres matriseformler ved å trykke Ctrl + Shift + Enter. Hvis den angis riktig, omslutter Excel matriseformelen i {krøllete klammer}, som vist på skjermbildet:

Hvordan sammenligne to celler etter strenglengde

Noen ganger kan det være lurt å sjekke om tekststrengene i hver rad inneholder like mange tegn. Formelen for denne oppgaven er veldig enkel. Først får du strenglengden til to celler ved å bruke LEN-funksjonen, og sammenligner deretter tallene.

Forutsatt at strengene som skal sammenlignes er i cellene A2 og B2, bruk en av følgende formler:

=LEN(A2)=LEN(B2)

Eller

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Som du allerede vet, returnerer den første formelen boolske verdier TRUE eller FALSE, mens den andre formelen gir dine egne resultater:

Som vist i skjermbildet ovenfor, fungerer formlene for tekststrenger så vel som tall.

Tips. Hvis to tilsynelatende like strenger returnerer forskjellige lengder, er problemet mest sannsynlig i ledende eller etterfølgende mellomrom i en eller begge cellene. Fjern i dette tilfellet ekstra mellomrom ved å bruke TRIM-funksjonen. Den detaljerte forklaringen og formeleksemplene finner du her: Hvordan trimme mellomrom i Excel.

Sammenlign to celler etter forekomster av et bestemt tegn

Dette er det siste eksemplet i vår Excel Compare Strings-opplæring, og det viser en løsning for en ganske spesifikk oppgave. Anta at du har 2 kolonner med tekststrenger som inneholder et tegn som er viktig for deg. Målet ditt er å sjekke om to celler i hver rad inneholder samme antall forekomster av et gitt tegn.

For å gjøre ting klarere, vurder følgendeeksempel. La oss si at du har to lister over bestillinger som er sendt (kolonne B) og mottatt (kolonne C). Hver rad inneholder bestillinger for en spesifikk vare, hvis unike identifikator er inkludert i alle ordre-ID-er og er oppført i samme rad i kolonne A (se skjermbildet nedenfor). Du vil forsikre deg om at hver rad inneholder like mange sendte og mottatte varer med den spesifikke ID-en.

For å løse dette problemet, skriv en formel med følgende logikk.

• Erstatt først den unike identifikatoren med ingenting ved å bruke ERSTATT-funksjonen:

  SUBSTITUTE(A1, character_to_count,"")

• Deretter beregner du hvor mange ganger den unike identifikatoren vises i hver celle. For dette, få strenglengden uten den unike identifikatoren og trekk den fra den totale lengden på strengen. Denne delen skal skrives for celle 1 og celle 2 individuelt, for eksempel:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  og

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Til slutt sammenligner du disse 2 tallene ved å plassere likhetstegnet (=) mellom delene ovenfor.

LEN( celle 2 ) - LEN(SUBSTITUTE( celle 2 , character_to_count , ""))

I vårt eksempel er den unike identifikatoren i A2 , og strengene som skal sammenlignes er i cellene B2 og C2. Så den komplette formelen er som følger:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Formelen returnerer TRUE hvis cellene B2 og C2 inneholder like mange forekomster av tegnet i A2,FALSK ellers. For å gjøre resultatene mer meningsfylte for brukerne dine, kan du legge inn formelen i IF-funksjonen:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Som du kan se i skjermbildet ovenfor , fungerer formelen perfekt til tross for et par ekstra komplikasjoner:

• Tegnet som skal telles (unik identifikator) kan vises hvor som helst i en tekststreng.
• Strengene inneholder et variabelt tall av tegn og forskjellige skilletegn som semikolon, komma eller mellomrom.

Slik sammenligner du strenger i Excel. For å se nærmere på formlene som er diskutert i denne opplæringen, er du velkommen til å laste ned Excel Compare Strings Worksheet. Jeg takker for at du leser og håper å se deg på bloggen vår neste uke.